Easter 2012

Story: prsm, TheKandiman
Scripting: alastrim
Prepare for release and testing: Jenalya

9 files changed, 447 insertions, 0 deletions

diff --git a/world/map/npc/008-1/george.txt b/world/map/npc/008-1/george.txt
index 3c8aff99..c4bca7f6 100644
--- a/world/map/npc/008-1/george.txt
+++ b/world/map/npc/008-1/george.txt
@@ -5,6 +5,10 @@
     if (gettime(7) == $@hw2011_year && gettime(6) == 10 && gettime(5) >= $@hw2011_start_day)
         goto L_TrickOrTreat;
 
+    if (QUEST_Easter12 == 3 && ((gettime(6) == 3 && gettime(5) >= $@easter2012_start_day) || (gettime(6) == 4 && gettime(5) < $@easter2012_reward_start_day)))
+        menu
+            "Hey George, I need to ask some questions about a crime.", L_George_Easter2012;
+
 L_Begin:
     if (getequipid(equip_head) == 617) goto L_Pirate;
     if (getequipid(equip_head) == 622) goto L_Bandana;
@@ -31,4 +35,32 @@ L_EyePatch:
 L_TrickOrTreat:
     callfunc "TrickOrTreat2011";
     goto L_Begin;
+
+L_George_Easter2012:
+    mes "[George the Pirate]";
+    mes "\"Aaarrrrh mate! That scarab armlet was a present from my grandfather, I swear! That is all I have to say...\"";
+    next;
+    menu
+        "What? What are you talking about?", -;
+    mes "[George the Pirate]";
+    mes "\"Uh? Ahh, hehe... Arrrh, what crime are ye talking about?\"";
+    next;
+    menu
+        "The Easter Bunny was kidnapped. I heard you know the person behind this crime.", -;
+    mes "[George the Pirate]";
+    mes "\"Arrrrh, I know, I know... But it's such a sad thing. My old mate Pink Boots Hank. He was a great treasure hunter, but now he is just a criminal.\"";
+    next;
+    mes "\"I remember like it was yesterday! Pink Boots Hank was not the same, he had those crazy eyes and would not stop talking about this man, or monster, or spirit, I don't know, I think his name is Galvanes or Gilbenos, I don't know.\"";
+    next;
+    mes "\What I know is from that day, he just started doing crazy things, like stealing money, present boxes, even chocolate cake!\"";
+    next;
+    menu
+        "But what about the Easter Bunny?", -;
+    mes "[George the Pirate]";
+    mes "\"Yes, yes... Hank is not a very smart guy. I remember he had a secret place, a big house in the desert. When he could find a treasure he would always run to this house and hide his things in the basement. I am sure he must be using this same place to hide the Easter Bunny.\"";
+    next;
+    menu
+        "Thank you George, I will check this information right now!", -;
+    set QUEST_Easter12, 4;
+    close;
 }
diff --git a/world/map/npc/010-2/chef.txt b/world/map/npc/010-2/chef.txt
index f5a6e8d5..393a2d35 100644
--- a/world/map/npc/010-2/chef.txt
+++ b/world/map/npc/010-2/chef.txt
@@ -9,6 +9,12 @@
 // if (gettime(6) == @month && gettime(5) >= @start_day && gettime(5) <= @end_day && QUEST_Easter11 == 8) goto L_MakeJellyBean;
 // if (gettime(6) == @month && gettime(5) >= @start_day && gettime(5) <= @end_day && QUEST_Easter11 == 9) goto L_SeeBunny;
 
+    if (!(gettime(6) == 3 && gettime(5) >= $@easter2012_start_day) && !(gettime(6) == 4 && gettime(5) <= $@easter2012_reward_end_day)) goto L_Begin;
+    if (QUEST_Easter12 == 6) goto L_Easter2012_Begin;
+    if (QUEST_Easter12 == 7) goto L_Easter2012_Wait;
+    if (QUEST_Easter12 == 8) goto L_Easter2012Foolplayers;
+    if (QUEST_Easter12 == 9) goto OnEaster2012Out;
+
 L_Begin:
     mes "[Chef]";
     mes "";
@@ -195,4 +201,143 @@ L_SeeBunny:
     next;
     goto L_Begin;
     close;
+
+L_Easter2012_Begin:
+    mes "[Chef]";
+    mes "\"Ahh, " + strcharinfo(0) + "! I really need to talk to you. Did the Easter Bunny give you a very thick and heavy pan?\"";
+    menu
+        "Yes, he did. Why?", -;
+
+    mes "[Chef]";
+    mes "\"Good to know! I am asking because now you are my only hope. I invented the ultimate culinary wonder, a recipe for the most incredibly tasty food you can imagine!\"";
+    next;
+    mes "\"But here is the problem, to complete this recipe I need a very resistent pan, because in the process I need to use a very strong acid solution based on yeti saliva!\"";
+    next;
+    mes "\"Can you believe I ruined ALL of my pans and 17 infantry helmets while trying to cook it? That is why I am asking for this favor. Could you lend me your pan? I promise I will give you a jar of the final product.\"";
+    next;
+    mes "\"Oh, and I will need to keep it with me for a while, as the ingredients need to rest in the acid solution for a long time, but you can always come here to see how it is going.\"";
+    menu
+        "Ok, but I want my pan back when it is done!", L_Accept_Cooking,
+        "No way, I won't let you fill my hat with corrosive yeti saliva!", -;
+
+    mes "[Chef]";
+    mes "\"Ahh, don't say that! Please, think about it and come back if you change your mind.\"";
+    close;
+
+L_Accept_Cooking:
+    mes "[Chef]";
+    mes "\"Great! But I can't promise anything regarding your hat. What I can promise is: IF it works, you will eat the most spetacular food of all time! I won't say what it is, but it is going to be great! What do you say, are you sure?\"";
+    menu
+        "Ahh, just take the pan and do your thing.", -,
+        "No way!", L_Close;
+    if (countitem("PanHat") < 1)
+        goto L_No_PanHat;
+    delitem "PanHat", 1;
+    set QUEST_Easter12, 7;
+    mes "\"Very good! Now I just need to put the basic ingredients inside a metal pan filled with water, yeti saliva, a little bit of salt and finally... The secret ingredient!\"";
+    next;
+    mes "The chef turns his back to you so he can hide what he is using. But you can clearly distinguish a smell of coal...";
+    mes "\"HahaHhh! And now we wait!\"";
+    close;
+
+L_Easter2012_Wait:
+    if ((gettime(6) == 4 && gettime(5) >= $@easter2012_reward_start_day))
+        goto L_Easter2012_Result;
+    mes "[Chef]";
+    mes "\"Be patient... The basic ingredients are not ready yet.\"";
+    close;
+
+L_Easter2012_Result:
+    set @temp, rand(99);
+    mes "[Chef]";
+    mes "\"Hey! I have some good news and some bad news... Which one do you want to hear first?\"";
+    menu
+        "The good one.", -,
+        "The bad one.", -,
+        "Oh no, I don't even want to hear!", L_Close;
+    if (@temp < 15) goto L_Easter2012_Lucky;
+    if (@temp >= 15) goto L_Easter2012_Unlucky;
+    close;
+
+L_Easter2012_Lucky:
+    mes "[Chef]";
+    mes "\"Wait! Did I mention bad news? I must be crazy... There is no bad news my friend! The ultimate pickled beets is now ready AND your pan is intact!\"";
+    next;
+    mes "\"Here! Take your pan back and a jar of the best pickled beets of the mana world!\"";
+    set QUEST_Easter12, 10;
+    getitem "PickledBeets", 1;
+    getitem "PanHat", 1;
+    close;
+
+L_Easter2012_Unlucky:
+    mes "[Chef]";
+    mes "\"Ahh, actually, it doesn't matter! The important thing is that the recipe was a success! I just can't believe how something can be so tasty!\"";
+    next;
+    menu
+        "Nice! Now, what about my hat?", -;
+    mes "\"Oh, that... Ehh, unfortunately, the pan is not anymore. It was completely destroyed by the time the pickled beets were ready! But don't worry, I will keep my promise and give you a jar of this culinary masterpiece!\"";
+    next;
+    menu
+        "Wait, wait... Are you saying I lost my hat?", -;
+    mes "[Chef]";
+    mes "\"Hmm, yes. But I must say I really appreciate your effort to help me! You sacrificed your cool hat in the name of the culinary arts, only a great person would do that!\"";
+    next;
+    menu
+        "But... I... My hat...", -;
+    mes "[Chef]";
+    mes "\"Here, take your pickled beets!\"";
+    getitem "PickledBeets", 1;
+    set QUEST_Easter12, 8;
+    close;
+
+OnEaster2012Out:
+    if (QUEST_Easter12 == 8)
+        set QUEST_Easter12, 9;
+    mes "[Chef]";
+    mes "\"Hey, I coudn't help but noticed your sadness... You really like these silly hats, don't you? Well, since your hat is completely destroyed, just like all my pans, I can give you one of these nice cooking hats. But only if you give my jar of pickled beets back. What do you say?\"";
+    menu
+        "A chef hat for a jar of pickled beets? Of course I want!", L_GetChefhat,
+        "Ahh, keep you silly hat! The pickled beets are way better!", L_KeepBeets;
+    close;
+
+L_GetChefhat:
+    if (countitem("PickledBeets") < 1)
+        goto L_No_Pickledbeets;
+    mes "[Chef]";
+    mes "\"Really? Well, if you are sure about that... Here is your hat!\"";
+    delitem "PickledBeets", 1;
+    getitem "ChefHat", 1;
+    set QUEST_Easter12, 10;
+    close;
+
+L_KeepBeets:
+    mes "[Chef]";
+    mes "\"Hmm, I see that at least you are a wise person. See you later!\"";
+    set QUEST_Easter12, 10;
+    close;
+
+L_No_PanHat:
+    mes "[Chef]";
+    mes "\"So? You said you have the pan, where is it?\"";
+    close;
+
+L_No_Pickledbeets:
+    mes "[Chef]";
+    mes "\"Hey, no pickled beets means no chef hat.\"";
+    close;
+
+L_Easter2012Foolplayers:
+    mes "The chef can't hear you. He keeps looking and feeling the scent of his new recipe.";
+    close;
+
+L_Close:
+    close;
+}
+
+010-2.gat,28,31,0|script|#chefproposition|32767,0,0{
+OnTouch:
+    if (gettime(7) != $@easter2012_year || QUEST_Easter12 != 8 || !((gettime(6) == 4 && gettime(5) >= $@easter2012_reward_start_day) && (gettime(6) == 4 && gettime(5) <= $@easter2012_reward_end_day)))
+        end;
+    doevent "Chef::OnEaster2012Out";
+    end;
 }
diff --git a/world/map/npc/031-1/frozenbeard.txt b/world/map/npc/031-1/frozenbeard.txt
index b4fe4e77..817dc74a 100644
--- a/world/map/npc/031-1/frozenbeard.txt
+++ b/world/map/npc/031-1/frozenbeard.txt
@@ -1,7 +1,12 @@
 //
 
 031-1.gat,97,115,0|script|Frozenbeard|138,{
+    if (QUEST_Easter12 == 2 && ((gettime(6) == 3 && gettime(5) >= $@easter2012_start_day) || (gettime(6) == 4 && gettime(5) < $@easter2012_reward_start_day)))
+        menu
+            "I need to find a way to go back home, can you help me?", L_Frozenbeard_Default,
+            "I heard you know pirates from all around the world, is it true?", L_Frozenbeard_Easter2012;
 
+L_Frozenbeard_Default:
     mes "[Frozenbeard]";
     mes "\"Arrr mate! There is no dock here, so I had to row boat from my ship!  I am pioneering and mapping the trade route between here and Argaes, around the Hurnscald area.  I'll hail my shipmates to send a boat and we'll sail out to Argaes, be there in no time, but it will cost you a fee.  500 gold pieces.  What do you say?";
     menu
@@ -27,4 +32,46 @@ L_NoMoney:
     mes "[Frozenbeard]";
     mes "\"You need more money.  I'll wait here while you get some.\"";
     close;
+
+L_Frozenbeard_Easter2012:
+    mes "[Frozenbeard]";
+    mes "\"Arrrrh mate! Ye be right! I know every single pirate in this world. But not all of them are to be trusted, I must say.\"";
+    next;
+    menu
+        "I need information about the Easter Bunny. I heard some pirates kidnapped him.", -;
+    mes "[Frozenbeard]";
+    mes "\"Arrrrh! Ye shouldn't do this to me. Those pirates are dangerous, I can't put myself in such a situation!\"";
+    next;
+    if (countitem("BlackPearl") < 1) goto L_Frozenbeard_Fear;
+    mes "You take a black pearl from your backpack and starts to play with it.";
+    next;
+    menu
+        "Hmm, too bad, because I was willing to pay well for information, you know?", -;
+    mes "[Frozenbeard]";
+    mes "\"Arrh eh... Did I say dangerous? These pirates are criminals and a shame to our kind. So, if ye give me this pearl I can tell ye all I know about them. It is not much, but maybe it can help.\"";
+    menu
+        "Ok, keep going.", -;
+    mes "[Frozenbeard]";
+    mes "\"Well I heard they took him to a small house around this area, where they have their base. But then they brought him to another place. It might be hot there, judging the way they dressed up. The bunny seemed to show no resistance at all when they kidnapped him. It looked as if he did not know what was happening.\"";
+    next;
+    mes "\"But the most important thing is, the leader of the kidnappers is an old friend of George, the treasure hunter. George is very clever, I am sure he knows how the kidnapper thinks and all, maybe he can give ye a more specific information about this.\"";
+    next;
+    menu
+        "Well, that was useful, take your pearl.", -;
+    if (countitem("BlackPearl") < 1)
+        goto L_Frozenbeard_Nopearl;
+    delitem "BlackPearl", 1;
+    set QUEST_Easter12, 3;
+    mes "[Frozenbeard]";
+    mes "\"Arrrrh! Such a beautiful item! Always glad to help.\"";
+    close;
+
+L_Frozenbeard_Fear:
+    mes "Frozenbeard ends the conversation. You can see he is afraid of the kidnappers.";
+    close;
+
+L_Frozenbeard_Nopearl:
+    mes "[Frozenbeard]";
+    mes "\"Arrrrh! I see no pearl!\"";
+    close;
 }
diff --git a/world/map/npc/easter/2012/_import.txt b/world/map/npc/easter/2012/_import.txt
new file mode 100644
index 00000000..ce4d6ac4
--- /dev/null
+++ b/world/map/npc/easter/2012/_import.txt
@@ -0,0 +1,4 @@
+npc: npc/easter/2012/doors.txt
+npc: npc/easter/2012/easter2012config.txt
+npc: npc/easter/2012/easterbunny.txt
+npc: npc/easter/2012/unclebunny.txt
diff --git a/world/map/npc/easter/2012/doors.txt b/world/map/npc/easter/2012/doors.txt
new file mode 100644
index 00000000..b76f10b4
--- /dev/null
+++ b/world/map/npc/easter/2012/doors.txt
@@ -0,0 +1,21 @@
+004-2.gat,62,28,0|script|#kidnapperdoor|32767,0,0{
+    if (QUEST_Easter12 < 4)
+        goto L_Locked;
+    if (QUEST_Easter12 == 4)
+        message strcharinfo(0), "As you look at the door, you notice the lock is broken. Walking inside the room, you can notice some small white fur around the room. The Easter Bunny was probably here and found a way to escape. You should talk to Uncle Bunny.";
+    if (QUEST_Easter12 == 4)
+        set QUEST_Easter12, 5;
+    warp "004-2.gat", 21, 61;
+    end;
+
+L_Locked:
+    message strcharinfo(0), "The door to the basement is locked.";
+    end;
+}
+
+021-2.gat,42,53,0|script|#easterbunnydoor|32767,0,0{
+    if (QUEST_Easter12 < 5)
+        end;
+    warp "021-2.gat", 70, 57;
+    end;
+}
diff --git a/world/map/npc/easter/2012/easter2012config.txt b/world/map/npc/easter/2012/easter2012config.txt
new file mode 100644
index 00000000..35483871
--- /dev/null
+++ b/world/map/npc/easter/2012/easter2012config.txt
@@ -0,0 +1,28 @@
+// Easter 2012
+// Storyline conceived by mainly by prsm with suggestions from TheKandiman
+// Scripting by mostly by alastrim
+// Bug fixing and testing by Jenalya
+
+// Variable QUEST_Easter12 values:
+// 1 - Player agree to help uncle bunny(to get pearls, petals and orange cupcakes) (unclebunny.txt)
+// 2 - Player gave the items to uncle bunny. Now he needs to look for frozenbeard (unclebunny.txt)
+// 3 - Player found frozenbeard and got information from him after giving him a black pearl. Now he needs to look for george.(frozenbeard.txt)
+// 4 - Player found george and got information from him about a possible location for the easter bunny.(george.txt)
+// 5 - Player found the place where the easter bunny was locked up. (#kidnapperdoor/doors.txt)
+// 6 - Player talked to easter bunny and received the pan hat as a reward. The bunny told the chef wants to talk to you. (easterbunny.txt)
+// 7 - Player accepted to lend his pan hat to the chef.
+// 8 - Player received a jar of pickled beets from the chef, but the hat is ruined.
+// 9 - The chef offers the player a new hat after he tries to leave the room. (#chefproposition/doors.txt)
+// 10 - Player picks one of the options offered by the chef. (keep the pickled beets or change it for a chef hat)
+// 10 - OR Player got the pickled beets and the pan hat wasn't ruined during the process
+
+-|script|#easter2012config|-1,{
+OnInit:
+    set $@easter2012_start_day, 23;
+    set $@easter2012_reward_start_day, 8;
+    set $@easter2012_reward_end_day, 22;
+    set $@easter2012_year, 2012;
+    set $@easter2012_pearl_amount, 3;
+    set $@easter2012_orangecupcake_amount, 20;
+    set $@easter2012_pinkpetal_amount, 5;
+}
diff --git a/world/map/npc/easter/2012/easterbunny.txt b/world/map/npc/easter/2012/easterbunny.txt
new file mode 100644
index 00000000..7cf4fcdd
--- /dev/null
+++ b/world/map/npc/easter/2012/easterbunny.txt
@@ -0,0 +1,30 @@
+// easter bunny
+
+021-2.gat,69,55,0|script|Easter Bunny|173,{
+
+    if (QUEST_Easter12 >= 6) goto L_Easterbunny_Thanks;
+    if (QUEST_Easter12 < 5) goto L_Easterbunny_Notyet;
+
+    mes "[Easter Bunny]";
+    mes "\"Hi " + strcharinfo(0) + "! I was waiting for you. My uncle told me all about the pirates and how you were working really hard to save me. So I decided to give you a gift. You know, such generous and brave actions must be rewarded somehow.\"";
+    next;
+    mes "\"Here is what I have for you. I used it to break the lock of door in that basement. It seems to be a very resistent pan, but it can also be used as a hat. Enjoy!\"";
+    getitem "PanHat", 1;
+    set QUEST_Easter12, 6;
+    next;
+    mes "\"Oh, I forgot to mention. The Chef in Dimond's cove was really interested in this pan when he saw it. I told him it was yours, so you are the one who can decide about this.\"";
+    next;
+    mes "\"If I were you I would see what he wants with this pan, maybe you can even get something good out of it.\"";
+    close;
+
+L_Easterbunny_Notyet:
+    mes "[Easter Bunny]";
+    mes "\"Hello!\"";
+    close;
+
+L_Easterbunny_Thanks:
+    mes "[Easter Bunny]";
+    mes "\"Hello " + strcharinfo(0) + "! Thanks again for all your help.";
+    mes "I don't remember... did I tell you about the Chef from Dimond's cove? He wanted to ask you something about the pan.\"";
+    close;
+}
diff --git a/world/map/npc/easter/2012/unclebunny.txt b/world/map/npc/easter/2012/unclebunny.txt
new file mode 100644
index 00000000..71b23cb9
--- /dev/null
+++ b/world/map/npc/easter/2012/unclebunny.txt
@@ -0,0 +1,136 @@
+// Uncle Bunny
+008-1.gat,45,23,0|script|Uncle Bunny|336,{
+
+    if ((BaseLevel < 30) || (gettimetick(2)-TUT_var < 3*7*86400)) // player must be created at least three weeks ago
+        goto L_TooYoung;
+
+    if (!(gettime(6) == 3 && gettime(5) >= $@easter2012_start_day) && !(gettime(6) == 4 && gettime(5) < $@easter2012_reward_start_day))
+        goto L_Easter2012Over;
+
+    if (QUEST_Easter12 == 1) goto L_Return_Death_Threat;
+    if (QUEST_Easter12 > 1 && QUEST_Easter12 < 5) goto L_Return_Frozenbeard;
+    if (QUEST_Easter12 == 5) goto L_Return_Easter_Bunny;
+    if (QUEST_Easter12 > 5) goto L_Easter2012Over;
+
+    mes "You see a big, funny-looking bunny wearing a bowler hat. He gazes at the horizon with a very sad face.";
+    menu
+        "Hey you, can I help you with anything?", -,
+        "Leave the bunny alone with his problems.", L_Close;
+
+    mes "[Uncle Bunny]";
+    mes "\"Oh, hi! Sorry, I didn't notice you were here. I am so worried about my nephew and his current situation that I can't barely keep a normal conversation.\"";
+    menu
+        "Sorry, but I don't want to be involved in your family troubles right now.", L_Close,
+        "Who is your nephew? What happened to him?", -;
+
+    if (QUEST_Easter11 != 14)
+        goto L_Dont_Know_Easter11;
+
+    mes "[Uncle Bunny]";
+    mes "\"I believe you know him already. He is the Easter Bunny, the one you helped last year with a very nice easter basket. But this year he can't even work on his things...\"";
+    goto L_Ask_For_Help;
+
+L_Dont_Know_Easter11:
+    mes "[Uncle Bunny]";
+    mes "\"I don't think you know him personally, but he is very famous. He is the Easter Bunny. He is widely known for his beautiful baskets full of candies and chocolates but also about his memory problems.\"";
+
+L_Ask_For_Help:
+    next;
+    mes "\"The problem is that some pirates kidnapped him and now they are asking for a lot of expensive things to set him free! They just sent me a terrible message! They are asking for items just to keep him alive!\"";
+    next;
+    mes "\"These criminals are probably inspired by that evil man who kidnapped Santa a couple years ago... They must be thinking they are going to get away with the ransom, just like the other guy. But we have to do something about it! Would you help me with this problem?\"";
+    next;
+    menu
+        "Of course I will. What do you need me to do?", -,
+        "Ehh... I am really busy right now, maybe later.", L_Close;
+
+    set QUEST_Easter12, 1;
+    mes "[Uncle Bunny]";
+    mes "\"Great! We need to be fast. They said they need " + $@easter2012_pearl_amount + " pearls, " + $@easter2012_orangecupcake_amount + " orange cupcakes and " + $@easter2012_pinkpetal_amount + " pink petals to keep him alive. Please, bring it to me as fast as you can.\"";
+    goto L_Close;
+
+L_Return_Death_Threat:
+    mes "[Uncle Bunny]";
+    mes "\"You are back!\"";
+    next;
+    if (countitem("Pearl") >= $@easter2012_pearl_amount && countitem("OrangeCupcake") >= $@easter2012_orangecupcake_amount && countitem("PinkPetal") >= $@easter2012_pinkpetal_amount)
+        goto L_Return_Death_Threat_With;
+
+    mes "\"Oh, but you don't have the items... Remember, we need " + $@easter2012_pearl_amount + " pearls, " + $@easter2012_orangecupcake_amount + " orange cupcakes and " + $@easter2012_pinkpetal_amount + " pink petals to keep him alive.";
+    mes "Please hurry, the Easter Bunny's life depends on you!\"";
+    goto L_Close;
+
+L_Return_Death_Threat_With:
+    mes "\"And you have the items! Thank you! Now we have time to think about something.\"";
+    next;
+    mes "\"While you were collecting the items, I heard there is a pirate called Frozenbeard who is not one of the kidnappers. Maybe he knows something about them or where they are hiding my nephew.\"";
+    next;
+    if (countitem("Pearl") < $@easter2012_pearl_amount || countitem("OrangeCupcake") < $@easter2012_orangecupcake_amount || countitem("PinkPetal") < $@easter2012_pinkpetal_amount)
+        goto L_Noitems;
+    delitem "Pearl", $@easter2012_pearl_amount;
+    delitem "OrangeCupcake", $@easter2012_orangecupcake_amount;
+    delitem "PinkPetal", $@easter2012_pinkpetal_amount;
+    set QUEST_Easter12, 2;
+    getitem "BlackPearl", 1;
+    mes "\"Please, any information you get from him will be extremely valuable! And here, take this black pearl. I heard he is a greedy man, so you can offer this item in case he shows any sign of fear or decides to put a price to his knowledge.\"";
+    goto L_Close;
+
+L_Return_Frozenbeard:
+    mes "[Uncle Bunny]";
+    mes "\"So, what did you find out?\"";
+    next;
+    if (QUEST_Easter12 == 2)
+        menu
+            "Nothing yet, I still need to find this man.", L_Return_Frozenbeard_Close;
+
+    if (QUEST_Easter12 == 3)
+        menu
+            "I found Frozenbeard, but he only refered me to another person.", L_Return_Frozenbeard_George;
+
+    if (QUEST_Easter12 == 4)
+        menu
+            "I know where he is. I am going to save him!", L_Return_Frozenbeard_Save;
+
+L_Return_Frozenbeard_Close:
+    mes "[Uncle Bunny]";
+    mes "\"Please, don't waste too much time or this is going to be a tragedy!\"";
+    goto L_Close;
+
+L_Return_Frozenbeard_George:
+    mes "[Uncle Bunny]";
+    mes "\"Then go after this person!\"";
+    goto L_Close;
+
+L_Return_Frozenbeard_Save:
+    mes "[Uncle Bunny]";
+    mes "\"Oh, Really? Are you sure about this information? If I were younger I would go with you and take my nephew from the hands of the pirates myself, but I am old and weak... All I can do is wish you good luck!\"";
+    goto L_Close;
+
+L_Return_Easter_Bunny:
+    mes "[Uncle Bunny]";
+    mes "\"" + strcharinfo(0) + "! You won't believe! My nephew escaped! He just showed up as if nothing have happened... He told me he woke up in a strange house and realized he didn't know how he got there. Can you believe that?\"";
+    next;
+    mes "\"My nephew forgot he had been kidnapped! He tought it was just one of his blackouts... So, since the door was locked, he just broke the lock and escaped! I guess the pirates were not counting on such a bold move from his part, hahah!\"";
+    next;
+    mes "\"But don't worry, I told him all about the pirates and your efforts to save him! Now he wants to talk to you, he says you deserve a special gift. He went to the Tulimshar workshop where he gets some help with the Easter issues and is waiting for you there.\"";
+    goto L_Close;
+
+L_Easter2012Over:
+    mes "[Uncle Bunny]";
+    mes "\"Ah, I am so glad my nephew was found! Now the nightmare is over! I hope his memory gets better one day.\"";
+    goto L_Close;
+
+L_Noitems:
+    mes "[Uncle Bunny]";
+    mes "\"Wait, I could swear you had the items, but they disappeared. Please, come back with the items!\"";
+    goto L_Close;
+
+L_TooYoung:
+    mes "[Uncle Bunny]";
+    mes "\"Hello, young one. This world is harsh, so be careful out there.\"";
+    goto L_Close;
+
+L_Close:
+    close;
+}
+
diff --git a/world/map/npc/scripts.conf b/world/map/npc/scripts.conf
index 805858a8..0e93035a 100644
--- a/world/map/npc/scripts.conf
+++ b/world/map/npc/scripts.conf
@@ -94,3 +94,7 @@ import: npc/halloween/2011/_import.txt
 
 // Christmas 2011
 // import: npc/xmas/2011/_import.txt
+
+// Easter 2012
+import: npc/easter/2012/_import.txt
+