042-2.gat,28,26,0 script Sorfina 154,4,4{
if (FLAGS & FLAG_TUTORIAL_DONE) goto L_Again;
if (sorfina == 3) goto L_Again;
if (sorfina == 2) goto L_Clothes;
if (sorfina == 1) goto L_Carpet;
callfunc "GameRules";
L_Start:
mes "You open your eyes.";
mes "";
mes "[Old Woman]";
mes "\"Ah, you woke up. It seems you collapsed after you left the boat that brought you to Tulimshar.";
mes "A group of ragtags immediatly took advantage of that and stole all your stuff!\"";
next;
mes "\"My little granddaughter Tanisha saw that, but couldn't do anything to stop them.";
mes "She hurried to get someone to help. It was too late to catch the thieves, but at least the helpers brought you here to recover.\"";
next;
mes "\"We're in the suburbs of Tulimshar here and this area of the town is full of shady people, so I don't think there's a chance to get back your stuff.\"";
mes "She has a sad look on her face, but then she shakes her head and smiles.";
next;
mes "[Old Woman]";
mes "\"Did you come here to look for a job? Many young people come to Tulimshar for this reason.\"";
next;
mes "\"I can tell you some useful things, if you want to hear.";
mes "Oh, and by the way my name is Sorfina.\"";
next;
menu
"That would be great!",L_Tut,
"No, thanks. I already know how things are going.",L_SkipTut;
L_Tut:
mes "[Server]";
mes "The explanations in this tutorial are based on the official client version 0.5.2";
mes "If you're using another client, settings and controls may be different.";
next;
mes "She smiles at you.";
mes "[Sorfina]";
mes "\"A wise decision.\"";
next;
mes "\"You still look rather shaky.";
mes "You're not used to the hot weather, right?\"";
next;
L_Carpet:
if ((getx(0) > 31) && (getx(0) < 35) && (gety(0) > 25) && (gety(0) < 29)) goto L_Shirt;
mes "\"Try to do some steps and walk to that red carpet over there.";
mes "Just use the arrow keys or click at the place you want to go to.\"";
next;
mes "\"Talk to me again when you're on the red carpet. You can either click on me, or press N to focus on me and T to talk.\"";
set sorfina, 1;
close;
L_Shirt:
mes "\"Very good! I'm glad you're recovering.";
mes "Now you should get dressed again. I gave you an old shirt from my son.\"";
next;
mes "\"You can open your inventory with pressing F3 or clicking at the button 'Inventory' in the bar at the upper right corner.\"";
next;
mes "\"After we finished talking click on the shirt and press the equip button.\"";
set sorfina, 2;
close;
L_Naked:
mes "\"Press F3 or click at the button for your equipment in the bar at the upper right corner to open your inventory.\"";
next;
mes "\"After we talked click on the shirt and press the equip button.\"";
next;
mes "\"Talk to me again when you got dressed. You can either click on me, or press N to focus on me and T to talk.\"";
close;
L_Clothes:
if (getequipid(equip_torso) < 0) goto L_Naked;
mes "[Sorfina]";
mes "\"That's much better, don't you think so?\"";
next;
mes "\"I think this will help you a bit. To get more informations, press the button settings and look at the controls. You can also change them as you like.";
mes "Talk to me again if you want me to explain more things.\"";
next;
mes "\"Now you should go to see my granddaughter, she is very worried. She's in the storehouse, that's the second building southeast from here.\"";
next;
mes "\"Oh, and if you're looking for work, you should talk to Aidan when you go to main Tulimshar. They're giving rewards for monster hunting.";
mes "You can find him near the south gate. Well, good luck.\"";
set sorfina, 3;
close;
L_Again:
mes "[Sorfina]";
mes "\"Make yourself at home! Do you have any questions?\"";
next;
if (hasan)
menu
"A guy named Hasan doesn't let me enter main Tulimshar.",L_Hasan,
"Yes, could you explain again about...",L_Explain,
"No, thanks.",L_Close;
menu
"Yes, could you explain about...",L_Explain,
"No, thanks.",L_Close;
close;
L_Explain:
menu
"... walking?",L_Walk,
"... talking?",L_Talk,
"... the inventory and items?",L_Items,
"... shortcuts?",L_Shortcut,
"... what to do in main Tulimshar?",L_Aidan,
"... nevermind.",L_Close;
close;
L_Walk:
mes "[Sorfina]";
mes "\"You can use the arrow keys to walk around.";
mes "Or just click at the place you want to go to.";
mes "But this only works if that place is reachable and walkable.\"";
close;
L_Talk:
mes "[Sorfina]";
mes "\"If you want to talk to a normal person, you can click at him or her.";
mes "Or you can press N to focus on the nearest person and then press T to talk.\"";
next;
mes "\"If you want to talk to other adventurers, press Enter to open your chat window.";
mes "Then type your message and press Enter to send.\"";
next;
mes "\"You may want to talk privately to another adventurer sometimes. In that case you can whisper.";
mes "After pressing Enter type '/whisper [name] [message]'.";
mes "Or you can right click on someone and choose the whisper option.\"";
next;
mes "\"Press F7 to show and hide your chat window.\"";
close;
L_Items:
mes "[Sorfina]";
mes "\"There are three types of items.";
mes "They can be Consumables, Equipment or Miscellaneous.\"";
next;
mes "\"Consumable items such as Potions, can be used only once.";
mes "After use, they will disappear from your inventory.";
mes "There are some rare items that can be used but don't get consumed.";
next;
mes "\"Equipment items like Armors, Weapons, Accessories can be equipped for fashionable purposes or to raise your status.\"";
next;
mes "\"Miscellaneous items such as maggot slime, are used in creating other items, or just to trade and sell.\"";
next;
mes "\"Press F3 to open your inventory.";
mes "When placing your cursor over an item there, you can see a box with some informations about that item.\"";
next;
mes "\"To use or equip an item, select it with clicking on it.";
mes "Then press Use or Equip.\"";
close;
L_Shortcut:
mes "[Sorfina]";
mes "\"Press F8 to open your shortcut window.\"";
next;
mes "\"You can select the item you want to put on a shortcut with your mouse and then click on the position in the shortcut window you want to place it.\"";
next;
mes "\"Now you can use or equip/unequip it with pressing the number of the shortcut.\"";
close;
L_Aidan:
mes "[Sorfina]";
mes "\"I suggest to go to the bazaar near the south gate.";
mes "We're in the north of Tulimshar here, so you have to walk across the town.\"";
next;
mes "\"When you leave this area to the Southeast, you'll come to the docks.";
mes "Follow the street to the south to pass the old town gates.\"";
next;
mes "\"Turn West at the next intersection. You'll pass by the gates of Tulimshar's famos magic school there.";
mes "Just follow the street to the south and you'll reach the bazaar.\"";
next;
mes "\"I heard Aidan is looking for brave adventurers, you might want to talk to him.";
mes "Usually the bazaar is bustling with activity, there are many persons who might know something useful.\"";
close;
L_Hasan:
mes "[Sorfina]";
mes "\"Ah, Hasan. He's causing trouble again?\"";
mes "She shakes her head.";
next;
mes "[Sorfina]";
mes "\This guy was a plague ever since. He's always causing trouble.\"";
next;
mes "\"And his father... Well, one day his father thought he should teach Hasan a lesson.\"";
next;
mes "\"He took him in the desert and then left him there!";
mes "Hasan was only seven years old!\"";
next;
mes "\"I never understood how someone can do something like that to a child, even if it's a rascal like Hasan.\"";
next;
mes "\"Anyway, Hasan tried to find his way back home, but stumbled in a nest of scorpions!\"";
mes "She shakes her head.";
next;
mes "\"If Valon wouldn't have come along that moment, Hasan would have died that day.\"";
next;
mes "\"However, the scorpions poison caused a bad fever and after Hasan had recovered from that, he was even more malicious than before.\"";
mes "She sighs.";
if (hasan == 1)
set hasan, 2;
close;
L_SkipTut:
mes "[Sorfina]";
mes "\"Really? You seem quite unexperienced. Listening to some advices won't hurt.\"";
next;
menu
"Thinking about it twice... please tell me.",L_Tut,
"Yeah, but thanks for the offer. Bye.",-;
mes "[Sorfina]";
mes "\"If you think so. But take at least this.";
set hasan, 0;
set kaan, 0;
set sorfina, 0;
set tanisha, 0;
set maggot, 0;
set FLAGS, FLAGS | FLAG_TUTORIAL_DONE;
getitem "knife", 1;
mes "Good luck.\"";
close;
L_Close:
close;
OnTouch:
if (TUT_var != 0) close;
callfunc "GameRules";
goto L_Start;
close;
}
042-2.gat,44,31,0 script #DoorOut 127,0,0{
if ((sorfina < 3) && !(FLAGS & FLAG_TUTORIAL_DONE)) goto L_Block;
warp "042-1.gat", 37, 57;
end;
L_Block:
message strcharinfo(0), "Sorfina: Wait a moment! You're not ready to leave.";
end;
}
