path: root/npc/013-2_Magic_house/wizard.txt

013-2.gat,66,39,0	script	Old Wizard#_W	116,{
	set @has_magic, getskilllv(SKILL_MAGIC);
        set MAGIC_FLAGS, MAGIC_FLAGS | MFLAG_KNOWS_OLD_WIZARD;

        mes "[Old Wizard]";
        mes "\"Ah, hello... \"";
        next;

        menu
		"Hey old man, you look worried - you okay?", L_easter_worried,
        	"Thanks, that's very kind of you!",thanks,
                "Can you teach me magic?", L_teach_rude,
        	"Oh, shut up!",shutup;
        close;

L_teach_rude:
        mes "[Old Wizard]";
        mes "\"I certainly could, but I already have an apprentice.\"";
        close;

shutup:
        mes "[Old Wizard]";
        mes "\"That attitude isn't going to get you very far, my dear.\"";
        close;
thanks:
        mes "[Old Wizard]";
        mes "\"Behind this door, my apprentice will serve you.\"";
        next;
        if (@has_magic)
            menu
	        "Alright.",ok,
                "I am studying magic, can you help?", L_new_student,
	        "Your apprentice? ... No thanks.",nothx;
        if (!@has_magic)
            menu
	        "Alright.",ok,
	        "Your apprentice? ... No thanks.",nothx;
nothx:
        mes "[Old Wizard]";
        mes "\"Goodbye, then!\"";
        close;

L_new_student:
        mes "[Old Wizard]";
        mes "\"Studying is very good for the mind... um, I'm afraid that just at the moment I'm - well, I suppose I could teach you one spell.\"";
        next;

        menu
		"That would be very kind of you!", -,
                "No, but thank you!", nothx;

        mes "[Old Wizard]";
        mes "\"This one may not seem too powerful, but it can be quite handy; it's the 'hide' spell. It will shield you from some forms of detection magic.\"";
        next;

        mes "[Old Wizard]";
        mes "\"Put a piece of cotton cloth on your head, and speak out '" + getspellinvocation("hide") + "', loudly and clearly. The protection lasts quite long, but you may have to renew it on occasion.\"";
        next;

        mes "[Old Wizard]";
        mes "\"You can also cast it on others, of course. Just speak their name after you prononuce the invocation.\"";
        next;

        mes "[Old Wizard]";
        mes "\"You may find it useful for getting a little peace and quiet at times, but it can also get in the way of friends trying to find you, so use it with care.\"";
        next;

        if (getskilllv(SKILL_MAGIC_ASTRAL) >= 2)
		close;

        mes "[Old Wizard]";
        mes "\"I'm not sure if you are experienced enough to cast it yet, though.  You may need to first learn astral magic.\"";
        close;

ok:
        mes "[Old Wizard]";
        mes "\"Beware the flying notes though, some of them are really dangerous. I haven't been able to persuade them to get back into their book. And avoid the mirror, it's been acting strange lately.\"";
        next;
        mes "\"Oh, and please don't take my apprentice too seriously. He still has a lot to learn.\"";
        close;

L_easter_worried:
	mes "[Old Wizard]";
	setarray @cryptic$, "\"Mm, I'm alright. But you'd better head off home... doesn't do to be abroad of late.\"",	"\"An intruder is abroad, my young man. It may be nothing, but I doubt it! Best go home before it gets dark.\"", "\"Darkness, my boy, darkness. I'm not afraid, but I'm worried!\"", "\"I was out gathering herbs, but... well, you should go home as well.\"";
	set @random_index, rand(getarraysize(@cryptic$));
	mes @cryptic$[@random_index];
	if (@random_index == 1) goto L_easter_abroad;
	if (@random_index == 2) goto L_easter_abroad;
	if (@random_index == 3) goto L_easter_darkness;
	if (@random_index == 4) goto L_easter_gohome;
	close;

L_easter_abroad:
	menu
		"Abroad? You mean like, the beach? Sand, sun and... palm trees?", L_easter_holiday,
		"Um, okay.", -,
	close;

L_easter_holiday:
	mes "[Old Wizard]";
	mes "\"No, you fool! I mean like... about. You know? *sigh* Never mind...\"";
	close;

L_easter_darkness:
	menu
		"Ha! Bet you are afraid.", L_easter_afraid,
		"Worried? Why?", L_easter_whyworried,
		"Okay. Bye.", -;
	close;

L_easter_afraid:
	mes "[Old Wizard]";
	mes "\"Don't be ridiculous! Humph!\"";
	close;

L_easter_whyworried:
	mes "[Old Wizard]";
	mes "\"I'm afraid I can't tell you that...\"";
	next;
	mes "\"I don't know myself!\"";
	close;

L_easter_gohome:
	menu
		"Leave me alone, you crazy old man.", L_easter_crazy,
		"Thanks for the advice, I guess...", L_easter_thanks,
		"Yeah, I think so too.", -,
		close;

L_easter_crazy:
	mes "[Old Wizard]";
	mes "\"Humph! Young scoundrel, be off with you! Do something useful for once... I hear the old woman in Hurnscald was looking for some help.\"";
	close;

L_easter_thanks:
	mes "[Old Wizard]";
	mes "\"Take care, now, my boy.\"";
	close;	


}