path: root/npc/001-1_Tulimshar/vincent.txt

new_3-1.gat,135,42,0	script	Vincent	113,{
	if(Bugleg == 1) goto L_Reas;
	if(Bugleg == 2) goto L_Done;
	set @TEMP, rand(4);
	if(@TEMP == 0) goto L_1;
	if(@TEMP == 1) goto L_2;
	if(@TEMP == 2) goto L_3;
	if(@TEMP == 3) goto L_4;

L_1:
	mes "[Vincent]";
	mes "\"I just need 30 more [Bug Legs] to finish my action figure!\"";
	next;
	goto L_Ask;

L_2:
	mes "[Vincent]";
	mes "\"This maggot action figure is awesome! I just need to attach [30 Part A{Bug Leg}]\"";
	next;
	goto L_Ask;

L_3:
	mes "[Vincent]";
	mes "\"This is a great action figure! A must have! All I need is a few parts...\"";
	goto L_Ask;

L_4:
	mes "[Vincent]";
	mes "\"Can you get me 30 [Bug Legs]? I need them to replace the action figure parts.\"";
	next;
	goto L_Ask;

L_Ask:
	mes "[Vincent]";
	mes "\"Will you help me find 30 [Bug Legs]?\"";
	next;
	menu
		"Yes", L_Sure,
		"No", -;
	close;

L_Sure:
	set Bugleg, 1;
	set @TEMP,rand(4);
	if(@TEMP == 0) goto J_1;
	if(@TEMP == 1) goto J_2;
	if(@TEMP == 2) goto J_3;
	if(@TEMP == 3) goto J_4;

J_1:
	mes "[Vincent]";
	mes "\"Thank you!\"";
	next;
	goto L_Wait;

J_2:
	mes "[Vincent]";
	mes "\"I don't know how to thank you enough!\"";
	next;
	goto L_Wait;

J_3:
	mes "[Vincent]";
	mes "\"I will thank you when I get them!\"";
	next;
	goto L_Wait;

J_4:
	mes "[Vincent]";
	mes "\"I'm sure I will give a small reward. :D\"";
	next;
	goto L_Wait;

L_Wait:
	mes "[Vincent]";
	mes "\"Now please go get me 30 [Bug Legs]\"";
	close;

L_Reas:
	if(countitem(518) >= 30) goto L_Have;
	mes "[Vincent]";
	mes "\"Please help me collect 30 [Bug Legs]!\"";
	close;

L_Have:
	delitem 518, 30;
	mes "[Vincent]";
	mes "\"Excellent! Finally I can complete the model!!\"";
	next;
	mes "[Vincent]";
	mes "\"Here you go, a little of my appreciation!\"";
	next;
	set zeny, zeny + 1000;
	set Bugleg, 2;
	close;

L_Done:
	mes "[Vincent]";
	mes "\"Thanks for your help!\"";
	close;
}