1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
|
// author: Jenalya
// state0, 1, 2: you shouldn't be able to come here
// state3: it's your first visit, you can choose a reward
// state4: you can do daily quests with white and yellow presents boxes
031-2,29,28,0|script|Angela#house|196
{
if (QL_CINDY == 4) goto L_Hello_Again;
if (QL_CINDY == 3) goto L_Reward;
mes "...";
goto L_Close;
L_Reward:
mes "[Angela]";
mes "\"Hello " + strcharinfo(0) + ", thank you again. I'm so glad Cindy is back home safe.\"";
next;
mes "\"As I told you, my husband is an adventurer. He is on one of his travels, so he couldn't rescue Cindy himself.\"";
next;
mes "\"I want to give you one of his treasures. Beside all the junk he brings, there are some very valuable things.\"";
next;
mes "\"This item is called the Rock Knife. When you wield it, you feel as robust as a rock.\"";
getinventorylist;
if (@inventorylist_count == 100)
goto L_Full_Inv;
getitem "RockKnife", 1;
set QL_CINDY, 4;
next;
mes "\"I hope this will be useful for you.\"";
next;
mes "\"I am so glad Cindy is safe. But there is still another problem. The Yetis took away all the white and yellow present boxes we wanted to bring to Santa!\"";
next;
mes "\"Usually, Yetis are very shy - I wonder why they did that. There is something strange going on.\"";
next;
mes "\"May I ask you for help again? I'll give you a small reward for every 3 boxes of one color you bring me.\"";
goto L_Close;
L_Full_Inv:
mes "\"Oh, it seems you carry so much stuff - I will keep it for you until you can take it.\"";
goto L_Close;
L_Hello_Again:
mes "[Angela]";
mes "\"Hello! Good to see you again. Please warm yourself.\"";
next;
menu
"I just wanted to say hello.",L_Close,
"I have some yellow present boxes.",L_Yellow,
"I have some white present boxes.",L_White;
L_Yellow:
set @dq_level, 70;
set @dq_cost, 32;
set @dq_count, 3;
set @dq_name$, "YellowPresentBox";
set @dq_friendly_name$, "yellow present box";
set @dq_money, 5300;
set @dq_exp, 1300;
callfunc "DailyQuest";
next;
if (@dq_return == 4)
mes "\"Santa will be glad to have them back.\"";
goto L_Close;
L_White:
set @dq_level, 80;
set @dq_cost, 64;
set @dq_count, 3;
set @dq_name$, "WhitePresentBox";
set @dq_friendly_name$, "white present box";
set @dq_money, 10800;
set @dq_exp, 2800;
callfunc "DailyQuest";
next;
if (@dq_return == 4)
mes "\"You are a great help!\"";
goto L_Close;
L_Close:
set @dq_level, 0;
set @dq_cost, 0;
set @dq_count, 0;
set @dq_name$, "";
set @dq_friendly_name$, "";
set @dq_money, 0;
set @dq_exp, 0;
set @dq_return, 0;
close;
}
|
