1 files changed, 97 insertions, 0 deletions
diff --git a/npc/030-2/bedding_helper.txt b/npc/030-2/bedding_helper.txt
new file mode 100755
index 00000000..22463251
--- /dev/null
+++ b/npc/030-2/bedding_helper.txt
@@ -0,0 +1,97 @@
+
+030-2,37,77,0	script	Osmo	NPC328,{
+    callfunc "XmasStates";
+
+    if($@xmas_time)
+        goto L_XmasMain;
+    goto L_OffSeason;
+
+L_OffSeason:
+    mes "[Osmo]";
+    mes "\"It's nice to relax and not have to worry about Xmas.\"";
+    mes "\"All that rush to gather those furs kills me every year.\"";
+    goto L_close;
+
+L_XmasMain:
+    if (XMASTIME & $@xmas_helper_bit_bed_ends) goto L_Done;
+    if (XMASTIME & $@xmas_helper_bit_bed_starts) goto L_Bedding;
+    if (@xmas_helper_bit) goto L_Helping;
+
+    mes "[Osmo]";
+    mes "\"What? Uh, excuse me, I have some work to do.\"";
+    goto L_close;
+
+L_Helping:
+    mes "[Osmo]";
+    mes "\"You came in at just the right moment. I was informed that our bedding material for fragile presents is nearly depleted.";
+    mes "Could you bring me " + $@xmas_bedding_amount + " White Furs?\"";
+    next;
+    mes "[Osmo]";
+    mes "\"Take care that it's real White Fur.";
+    mes "Other materials tend to go out of place in the present box, leaving the fragile content unprotected from any pushes.\"";
+    XMASTIME = XMASTIME | $@xmas_helper_bit_bed_starts;
+    goto L_close;
+
+L_Bedding:
+    mes "[Osmo]";
+    mes "\"Ah, you're back. Do you have the " + $@xmas_bedding_amount + " White Fur needed as bedding for fragile presents?\"";
+    if ((countitem("WhiteFur") >= $@xmas_bedding_amount) && (countitem("CottonCloth") >= $@xmas_bedding_amount))
+        menu
+            "Yeah, here it is. (Give the White Fur.)",L_Fur,
+            "Sure, here it is. (Give the Cotton Cloth.)",L_Cloth,
+            "No, I'm still working on that.",L_close;
+    if (countitem("WhiteFur") >= $@xmas_bedding_amount)
+        menu
+            "Yeah, here it is. (Give the White Fur.)",L_Fur,
+            "No, I'm still working on that.",L_close;
+    if (countitem("CottonCloth") >= $@xmas_bedding_amount)
+        menu
+            "Sure, here it is. (Give the Cotton Cloth.)",L_Cloth,
+            "No, I'm still working on that.",L_close;
+    if ((countitem("WhiteFur") < $@xmas_bedding_amount) && (countitem("CottonCloth") < $@xmas_bedding_amount))
+        menu
+            "No.", L_close;
+    goto L_close;
+
+L_Fur:
+    if (countitem("WhiteFur") < $@xmas_bedding_amount)
+        goto L_NoItems;
+    delitem "WhiteFur", $@xmas_bedding_amount;
+    XMASTIME = XMASTIME | $@xmas_helper_bit_bed_ends;
+    @karma_bonus = $@xmas_karma_bonus;
+    callfunc "XmasNice";
+    callfunc "XmasXpReward";
+    mes "[Osmo]";
+    mes "\"Wonderful! Thanks for your effort.\"";
+    goto L_close;
+
+L_Cloth:
+    if (countitem("CottonCloth") < $@xmas_bedding_amount)
+        goto L_NoItems;
+    delitem "CottonCloth", $@xmas_bedding_amount;
+    XMASTIME = XMASTIME &~ $@xmas_helper_bit_bed_starts;
+    XMASTIME = XMASTIME | $@xmas_helper_bit_bed_ends;
+    @karma_bonus = $@xmas_karma_bonus;
+    callfunc "XmasNaughty";
+    callfunc "XmasXpReward";
+    mes "He doesn't notice that you're giving him Cotton Cloth.";
+    mes "[Osmo]";
+    mes "\"Wonderful! Thanks for your effort.\"";
+    goto L_close;
+
+L_Done:
+    mes "[Osmo]";
+    if (!(@xmas_helper_bedding))
+        mes "\"The Fur you brought me isn't working very well.\"";
+    if (@xmas_helper_bedding)
+        mes "\"Thanks for helping out with the bedding material.\"";
+    goto L_close;
+
+L_NoItems:
+    mes "[Osmo]";
+    mes "\"Where do you have it? Is this a joke?\"";
+    goto L_close;
+
+L_close:
+    close;
+}