1 files changed, 90 insertions, 0 deletions
diff --git a/npc/012-1/flowerpentagram2.txt b/npc/012-1/flowerpentagram2.txt
new file mode 100644
index 00000000..b7f6f99b
--- /dev/null
+++ b/npc/012-1/flowerpentagram2.txt
@@ -0,0 +1,90 @@
+
+012-1,143,70,0	script	#FlowerPentagram2	NPC400,{
+    if (OrumQuest >= 31) goto L_PlacedFifthFlower;
+
+    if (OrumQuest > 20) goto L_PlacedSecondFlower;
+    if (OrumQuest == 20) goto L_SecondFlower;
+
+    message strcharinfo(0), "There is something odd about this place.";
+    end;
+
+L_SecondFlower:
+    mes "Orum described this place. You have to place the second magical flower here.";
+    menu
+        "Place the flower.", L_Next,
+        "Leave.", L_close;
+
+L_Next:
+    if (isin("012-1", 142, 69, 144, 71))
+        goto L_Place;
+
+    mes "This isn't working, you're too far away.";
+    goto L_close;
+
+L_Place:
+    set @localMonsterCount,
+        mobcount("012-1", "#FlowerPentagram2::OnSquirrelDeath") +
+        mobcount("012-1", "#FlowerPentagram2::OnMushroomDeath") +
+        mobcount("012-1", "#FlowerPentagram2::OnScorpionDeath") +
+        mobcount("012-1", "#FlowerPentagram2::OnRScorpionDeath");
+    if (@localMonsterCount > 2)
+        goto L_MonstersAlive;
+
+    if (countitem("PurpleSummonFlower") < 1)
+        goto L_NoFlower;
+    delitem "PurpleSummonFlower", 1;
+    mes "Remembering what happened the last time, you take a careful look around. Everything's calm. You proceed to place the second flower.";
+    mes "Sensing a certain tension build up around you, you can't help but feel alarmed.";
+    OrumQuest = 21;
+    close2;
+    areamonster "012-1", 140, 64, 146, 73, "", 1105, 2, "#FlowerPentagram2::OnSquirrelDeath";
+    areamonster "012-1", 140, 64, 146, 73, "", 1106, 2, "#FlowerPentagram2::OnMushroomDeath";
+    areamonster "012-1", 140, 64, 146, 73, "", 1003, 2, "#FlowerPentagram2::OnScorpionDeath";
+    areamonster "012-1", 140, 64, 146, 73, "", 1004, 2, "#FlowerPentagram2::OnRScorpionDeath";
+    @value = 15;
+    callfunc "QuestSagathaAnnoy";
+    @value = 0;
+    end;
+
+OnSquirrelDeath:
+    fix_mobkill(1105);
+    end;
+
+OnMushroomDeath:
+    fix_mobkill(1106);
+    end;
+
+OnScorpionDeath:
+    fix_mobkill(1003);
+    end;
+
+OnRScorpionDeath:
+    fix_mobkill(1004);
+    end;
+
+L_MonstersAlive:
+    mes "As you get closer to the place, you feel an unnerving presence.";
+    mes "This place has recently been used to summon something! And the beings are still nearby!";
+    next;
+    mes "You should get rid of them before attempting the summoning yourself.";
+    goto L_close;
+
+L_NoFlower:
+    mes "You look into your pocket, but the flower isn't there. Where did you put it?";
+    mes "If you can't find it, you should talk to Orum again.";
+    goto L_close;
+
+L_PlacedSecondFlower:
+    mes "You placed the second of Orum's magical flowers on this spot.";
+    mes "You can still feel the magical power shimmering around this place, waiting to be unleashed.";
+    goto L_close;
+
+L_PlacedFifthFlower:
+    mes "This is where you placed the second of Orum's magical flowers.";
+    mes "However, now that the summoning spell has been cast, everything is back to normal here.";
+    goto L_close;
+
+L_close:
+    @localMonsterCount = 0;
+    close;
+}