summaryrefslogtreecommitdiff
path: root/npc/002-1
diff options
context:
space:
mode:
Diffstat (limited to 'npc/002-1')
-rw-r--r--npc/002-1/_import.txt20
-rw-r--r--npc/002-1/_mobs.txt15
-rw-r--r--npc/002-1/_warps.txt18
-rwxr-xr-xnpc/002-1/anwar.txt172
-rwxr-xr-xnpc/002-1/bard.txt117
-rwxr-xr-xnpc/002-1/elanore.txt618
-rwxr-xr-xnpc/002-1/gaurds.txt15
-rwxr-xr-xnpc/002-1/itka.txt19
-rwxr-xr-xnpc/002-1/lieutenant_dausen.txt110
-rwxr-xr-xnpc/002-1/luca.txt449
-rwxr-xr-xnpc/002-1/mapflags.txt1
-rwxr-xr-xnpc/002-1/mine_debug.txt68
-rwxr-xr-xnpc/002-1/nickos.txt113
-rwxr-xr-xnpc/002-1/nomads.txt13
-rwxr-xr-xnpc/002-1/npcs.txt22
-rwxr-xr-xnpc/002-1/sarah.txt75
-rwxr-xr-xnpc/002-1/soul-menhir.txt15
-rwxr-xr-xnpc/002-1/stewen.txt22
-rwxr-xr-xnpc/002-1/traveler.txt7
19 files changed, 1889 insertions, 0 deletions
diff --git a/npc/002-1/_import.txt b/npc/002-1/_import.txt
new file mode 100644
index 00000000..7b375b44
--- /dev/null
+++ b/npc/002-1/_import.txt
@@ -0,0 +1,20 @@
+// Map 002-1: Tulimshar South
+// This file is generated automatically. All manually added changes will be removed when running the Converter.
+"npc/002-1/_mobs.txt",
+"npc/002-1/_warps.txt",
+"npc/002-1/anwar.txt",
+"npc/002-1/bard.txt",
+"npc/002-1/elanore.txt",
+"npc/002-1/gaurds.txt",
+"npc/002-1/itka.txt",
+"npc/002-1/lieutenant_dausen.txt",
+"npc/002-1/luca.txt",
+"npc/002-1/mapflags.txt",
+"npc/002-1/mine_debug.txt",
+"npc/002-1/nickos.txt",
+"npc/002-1/nomads.txt",
+"npc/002-1/npcs.txt",
+"npc/002-1/sarah.txt",
+"npc/002-1/soul-menhir.txt",
+"npc/002-1/stewen.txt",
+"npc/002-1/traveler.txt",
diff --git a/npc/002-1/_mobs.txt b/npc/002-1/_mobs.txt
new file mode 100644
index 00000000..3a6bf126
--- /dev/null
+++ b/npc/002-1/_mobs.txt
@@ -0,0 +1,15 @@
+// This file is generated automatically. All manually added changes will be removed when running the Converter.
+// Map 002-1: Tulimshar South mobs
+002-1,93,62,12,4 monster Piou 1002,11,100000,30000
+002-1,112,62,5,4 monster Piou 1002,11,100000,30000
+002-1,108,73,5,4 monster Piou 1002,11,100000,30000
+002-1,62,28,1,7 monster Piou 1002,6,100000,30000
+002-1,74,96,12,16 monster Piousse 1003,12,100000,30000
+002-1,113,114,5,3 monster Piou 1002,11,100000,30000
+002-1,43,61,5,35 monster Piousse 1003,6,100000,30000
+002-1,70,92,24,9 monster Piousse 1003,10,100000,30000
+002-1,40,93,9,10 monster Tortuga 1004,10,100000,30000
+002-1,42,40,4,14 monster Clover Patch 1033,8,100000,30000
+002-1,33,75,4,20 monster Clover Patch 1033,8,100000,30000
+002-1,99,62,18,4 monster Piousse 1003,6,100000,30000
+002-1,73,105,10,10 monster Plushroom Field 1011,6,100000,30000
diff --git a/npc/002-1/_warps.txt b/npc/002-1/_warps.txt
new file mode 100644
index 00000000..6ffc689d
--- /dev/null
+++ b/npc/002-1/_warps.txt
@@ -0,0 +1,18 @@
+// This file is generated automatically. All manually added changes will be removed when running the Converter.
+// Map 002-1: Tulimshar South warps
+002-1,63,20,0 warp #002-1_63_20 4,0,001-1,63,118
+002-1,103,20,0 warp #002-1_103_20 4,0,001-1,103,118
+002-1,119,95,0 warp #002-1_119_95 0,2,006-1,21,47
+002-1,92,114,0 warp #002-1_92_114 0,0,002-3,85,49
+002-1,33,109,0 warp #002-1_33_109 0,0,002-3,51,35
+002-1,109,45,0 warp #002-1_109_45 0,0,002-2,75,100
+002-1,115,45,0 warp #002-1_115_45 0,0,002-2,83,100
+002-1,99,43,0 warp #002-1_99_43 0,0,002-2,120,66
+002-1,114,35,0 warp #002-1_114_35 0,0,002-2,78,131
+002-1,110,29,0 warp #002-1_110_29 0,0,002-2,68,122
+002-1,73,35,0 warp #002-1_73_35 0,0,002-2,44,33
+002-1,57,35,0 warp #002-1_57_35 0,0,002-2,120,94
+002-1,67,29,0 warp #002-1_67_29 0,0,002-2,23,109
+002-1,113,107,0 warp #002-1_113_107 0,0,005-3,52,37
+002-1,49,20,0 warp #002-1_49_20 0,0,004-3,24,94
+002-1,57,26,0 warp #002-1_57_26 0,0,002-2,119,131
diff --git a/npc/002-1/anwar.txt b/npc/002-1/anwar.txt
new file mode 100755
index 00000000..37def423
--- /dev/null
+++ b/npc/002-1/anwar.txt
@@ -0,0 +1,172 @@
+002-1,95,67,0 script Anwar NPC156,{
+ @cloth_amount = 3;
+ @silk_amount = 30;
+
+ @firstTry_exp = 400;
+ @secondTry_exp = 700;
+ @material_exp = 1000;
+ @final_exp = 2000;
+
+ if (.@q >= 15) goto L_Done;
+ if (.@q >= 13) goto L_GiveEomie;
+ if (.@q >= 11) goto L_GiveTinris;
+ if (.@q == 10) goto L_GiftMaterial;
+ if (.@q >= 5) goto L_SecondTry;
+ if (.@q >= 1) goto L_FirstTry;
+
+ mesn;
+ mes "\"Hello. You look like one of those young people who come here to go on an adventure.";
+ mes "Would you be interested in doing some small errand for me?\"";
+ menu
+ "Sure!",L_Sure,
+ "I'm busy, sorry.",L_Close;
+
+L_Sure:
+ mesn;
+ mes "\"That's the spirit! Ok, I'm tired of spending most of my time working on this field. I heard the magicians at the magic school are researching ways to enhance the growth of plants with magic.\"";
+ next;
+ mes "\"I can't go there myself, since this area of the city is full of sneaky ragtags and they will rob my field if I leave here. Could you go to the magic school and ask for some magic enhancement for my field?\"";
+ next;
+ mes "\"To find the school just follow the street north back into town. The school is the castle at the north end of town.\"";
+ .@q = 1;
+ goto L_Close;
+
+L_FirstTry: // .@q >= 1 but below 5
+ mesn;
+ mes "\"I hope the wizards at the magic school can help me with the field. I'd really like to have more free time. I want to make clothing, but I'm not experienced enough to make a living out of that.\"";
+ if (.@q != 4)
+ goto L_Close;
+ menu
+ "Tinris gave me a magic fertilizer for your field, but he isn't sure if it works.",L_Next;
+
+L_Next:
+ mesn;
+ mes "\"Really? Well, let's try it out!\"";
+ mes "He takes the fertilizer and starts to bespatter the field.";
+ next;
+ mes "But it doesn't seem to be good for the plants, they start to shrivel and get brown.";
+ mesn;
+ mes "\"Oh no! What is this? It's damaging my plants! Go back to Tinris and tell him it doesn't work!\"";
+ getexp @firstTry_exp, 0;
+ .@q = 5;
+ goto L_Close;
+
+L_SecondTry: // .@q >= 5 but below 10
+ mesn;
+ mes "\"I hope Tinris can come up with a better fertilizer. My plants are suffering from the first try.\"";
+ if (.@q != 9)
+ goto L_Close;
+ menu
+ "Here is another one. Eomie cast a spell on it.",L_Continue;
+
+L_Continue:
+ mesn;
+ mes "\"Eomie? I heard she's amazingly skilled with nature magic. I'll try if this works better.\"";
+ mes "He takes the fertilizer and puts it on only a few plants, then waits a moment to see the result.";
+ next;
+ mes "The plants recover a bit and become green again.";
+ mesn;
+ mes "\"Ah, this one is better. I'll put it on the entire field.\"";
+ getexp @secondTry_exp, 0;
+ .@q = 10;
+ next;
+ goto L_GiftMaterial;
+
+L_GiftMaterial: // .@q == 10
+ mesn;
+ mes "\"I want to show my gratitude to Tinris and Eomie. Can you help me once again? I would like to make some clothes for them and need " + @cloth_amount + " pieces of Cotton Cloth and " + @silk_amount + " Silk Cocoons.\"";
+ menu
+ "I have it.",L_GiveGiftStuff,
+ "Where can I get that?",L_Hint,
+ "I'll see what I can do.",L_Close;
+
+L_GiveGiftStuff:
+ getinventorylist;
+ if (@inventorylist_count == 100)
+ goto L_Full_Inv;
+ if ((countitem("CottonCloth") < @cloth_amount) || (countitem("SilkCocoon") < @silk_amount))
+ goto L_NoItem;
+ delitem "CottonCloth", @cloth_amount;
+ delitem "SilkCocoon", @silk_amount;
+ getexp @material_exp, 0;
+
+ getitem "GreenVNeckSweater", 1;
+ .@q = 11;
+ mesn;
+ mes "\"Great! I'll start right away with the present for Tinris. That shouldn't take long.\"";
+ mes "After a short while of cutting and sewing he holds a V-Neck Sweater in his hands. Then he dyes it green.";
+ next;
+ mesn;
+ mes "\"Wonderful! Could you please bring this to Tinris to show him my gratitude?\"";
+ goto L_Close;
+
+L_Hint:
+ mesn;
+ mes "\"As far as I know Cotton Cloth is given out as reward for hunting monsters. You should talk to Aidan in Candor.\"";
+ next;
+ mes "\"Otherwise Cotton Cloth can be sheared from Mouboo and silk cocoons come from Silkworms.";
+ mes "They live in the woodland area around Hurnscald. You can get there by taking the ferry.\"";
+ goto L_Close;
+
+L_GiveTinris: // .@q >= 11 but below 13
+ mesn;
+ mes "\"Did you already bring the Green V-Neck Sweater to Tinris?\"";
+ if (.@q != 12)
+ menu
+ "Not yet.",L_Close;
+ menu
+ "Yes, he was very happy.",L_Happy;
+
+L_Happy:
+ getinventorylist;
+ if (@inventorylist_count == 100)
+ goto L_Full_Inv;
+ mesn;
+ mes "\"Wonderful! I also finished the present for Eomie. Can you bring it to her?\"";
+ getitem "SilkHeadband", 1;
+ .@q = 13;
+ goto L_Close;
+
+L_GiveEomie: // .@q >= 13 but below 15
+ getinventorylist;
+ if (@inventorylist_count == 100)
+ goto L_Full_Inv;
+ mesn;
+ mes "\"Did you give the Silk Headband to Eomie?\"";
+ if (.@q != 14)
+ menu
+ "Not yet.",L_Close;
+ menu
+ "Yes. She asked me to thank you.",L_ThankYou;
+
+L_ThankYou:
+ mes "Anwar smiles.";
+ mesn;
+ mes "\"I'm so happy. Thank you so much for your help. I made this for you while you went to see Eomie.\"";
+ getexp @final_exp, 0;
+ getitem "DarkGreenCottonTrousers", 1;
+ .@q = 15;
+ goto L_Close;
+
+L_Done: // .@q == 15
+ mesn;
+ mes "\"Thank you so much for your help. The plants are growing much better now. I don't have to spend all my time working in the field any more.";
+ mes "Finally I can do what I'm really interested in and work on getting better at sewing clothes.\"";
+ goto L_Close;
+
+L_NoItem:
+ mesn;
+ mes "\"You don't have it!\"";
+ goto L_Close;
+
+L_Full_Inv:
+ mesn;
+ mes "\"You carry a lot of stuff. Come back when you have more room.\"";
+ goto L_Close;
+
+L_Close:
+ @cloth_amount = 0;
+ @silk_amount = 0;
+ @inventorylist_count = 0;
+ close;
+}
diff --git a/npc/002-1/bard.txt b/npc/002-1/bard.txt
new file mode 100755
index 00000000..648cf4c4
--- /dev/null
+++ b/npc/002-1/bard.txt
@@ -0,0 +1,117 @@
+
+002-1,91,33,0 script Bard NPC152,{
+ setarray @songs$, "\"There once was a bard, who had it hard, because a man in dark green, was very mean.\"",
+ "\"At Hurnscald inn, there was a person of fairest skin, declining wedding bands from quite a many hands.\"",
+ "\"As the Sun sets down in the forest's brown, she whom the fragrance holds counts her gold.\"";
+ @name$ = "Bill Ballshaker the Bard";
+ mes "[" + @name$ + "]";
+ mes "\"Greetings, traveler! Have you come to listen to my stories?\"";
+ next;
+ goto L_Main;
+
+L_Main:
+ menu
+ "Sing me a song, lute man!", L_Song,
+ "Have you heard any news?", L_News,
+ "What do you know about...", L_Question,
+ "Farewell!", L_close;
+
+L_News:
+
+ mes "[" + @name$ + "]";
+ mes "\"News I have for you indeed, lest you have already overheard (for then it would no longer be news to you!)\"";
+ next;
+ mes "[" + @name$ + "]";
+ mes "\"Rumor has it that an ancient source of magic, a Mana Seed, has been sighted in the west, beyond the fair town of Hurnscald.\"";
+ next;
+ MAGIC_FLAGS = MAGIC_FLAGS | MFLAG_MANASEED_RUMOUR;
+ mes "[" + @name$ + "]";
+ mes "\"Whence it came, nobody knows... but they say that sometimes such Mana Seeds may choose a powerful individual to impart some of its mystic power to!\"";
+ next;
+ mes "[" + @name$ + "]";
+ mes "\"I wonder who might be qualified?\"";
+ next;
+ goto L_Main;
+
+L_Question:
+ callfunc "MagicTalkOptionsSetup";
+ @ignore = @QQ_ASTRALSOUL;
+ callfunc "MagicTalkMenu";
+
+ if (@c == 0) goto L_Main;
+ if (@c == @QQ_ELANORE) goto L_Q_elanore;
+ if (@c == @QQ_MANASEED) goto L_Q_manaseed;
+ if (@c == @QQ_WYARA) goto L_Q_wyara;
+ if (@c == @QQ_SAGATHA) goto L_Q_sagatha;
+ if (@c == @QQ_AULDSBEL) goto L_Q_auldsbel;
+ if (@c == @QQ_OLDWIZ) goto L_Q_oldwiz;
+
+ mes "[" + @name$ + "]";
+ mes "\"Alas, I know very little about this matter.\"";
+ next;
+ goto L_Main;
+
+L_Q_oldwiz:
+ mes "[" + @name$ + "]";
+ mes "\"The old wizard has been an old man for as long as I remember, living near the mountains in his magic hut – a hut that is bigger on the inside, just like in the old tales of Gyer Filla the Wise....\"";
+ next;
+ mes "[" + @name$ + "]";
+ mes "\"I doubt that they are the same person, though. For one, I have never seen his hut fly. For another, Gyer never took apprentices.\"";
+ next;
+ goto L_Main;
+
+L_Q_elanore:
+ mes "[" + @name$ + "]";
+ mes "\"Elanore is this town's healer. Rumor has it that she traveled far and wide when she was younger, to learn the deepest secrets of healing magic, after her brother caught a mysterious illness.\"";
+ next;
+ goto L_Main;
+
+L_Q_manaseed:
+ mes "[" + @name$ + "]";
+ mes "\"The Mana Seed is said to be a source of great magic. Perhaps some witch or wizard might know more about it?\"";
+ next;
+ goto L_Main;
+
+L_Q_wyara:
+ mes "[" + @name$ + "]";
+ mes "\"Wyara is not actually from Hurnscald. As a young witch, she decided to settle down there to help the people of Hurnscald. She is kind and gentle, except towards the Doctor, who seems to have little respect for her potions.\"";
+ next;
+ goto L_Main;
+
+L_Q_sagatha:
+ mes "[" + @name$ + "]";
+ mes "\"Sagatha! Ah, such a wonderful and mysterious being; the center of many a tale...\"";
+ next;
+ mes "[" + @name$ + "]";
+ mes "\"Some say that she is the most powerful witch in all of Argaes. I don't know whether that is true or not, but I am quite certain that she is the most beautiful witch of all! Alas, she will let no man touch her...\"";
+ mes "He sighs.";
+ next;
+ mes "[" + @name$ + "]";
+ mes "\"I met her only twice, back in my traveling days, but there are two pieces of advice I can give you:\"";
+ next;
+ mes "[" + @name$ + "]";
+ mes "\"First, she will suffer no fool easily, particularly no man.\"";
+ next;
+ mes "[" + @name$ + "]";
+ mes "\"Second, the creatures of the forest mean everything to her. Harm them, and you may find her an enemy – and a powerful one at that...\"";
+ next;
+ goto L_Main;
+
+L_Q_auldsbel:
+ mes "[" + @name$ + "]";
+ mes "\"Auldsbel is a wizard further north. From what I have gathered he bought a hut near Hurnscald some years back and often comes here to experiment on things. This is probably because he is not allowed to do these experiments where he comes from.\"";
+ next;
+ goto L_Main;
+
+L_Song:
+ mes "[" + @name$ + "]";
+ @id = rand(3);
+ mes @songs$[@id];
+ goto L_close;
+
+L_close:
+ @name$ = "";
+ @id = 0;
+ cleararray @songs$[0], "", 2;
+ close;
+}
diff --git a/npc/002-1/elanore.txt b/npc/002-1/elanore.txt
new file mode 100755
index 00000000..3a546cd2
--- /dev/null
+++ b/npc/002-1/elanore.txt
@@ -0,0 +1,618 @@
+
+function script ElanoreFix {
+ @Q_MASK = NIBBLE_1_MASK;
+ @Q_SHIFT = NIBBLE_1_SHIFT;
+
+ set @Q_STATUS_MAX, 3; // FIXME once level 3 magic was released
+
+ @Q_status = (QUEST_MAGIC2 & @Q_MASK) >> @Q_SHIFT;
+ if (@Q_status > @Q_STATUS_MAX)
+ @Q_status = @STATUS_INITIAL;
+ if (@Q_status > 1 && (getskilllv(SKILL_MAGIC_LIFE) < 2))
+ @Q_status = @STATUS_INITIAL;
+
+ QUEST_MAGIC2 = (QUEST_MAGIC2 & ~(@Q_MASK) | (@Q_status << @Q_SHIFT));
+ return;
+}
+
+function script elanore_decrease_exp {
+ @Q_heal_exp = MAGIC_EXPERIENCE >> 24;
+ if (@Q_heal_exp < 8) goto L_OnPcKillWipe;
+ @Q_heal_exp = @Q_heal_exp - 8;
+ goto L_OnPcKillFinish;
+
+L_OnPcKillWipe:
+ @Q_heal_exp = 0;
+ goto L_OnPcKillFinish;
+
+L_OnPcKillFinish:
+ MAGIC_EXPERIENCE = (MAGIC_EXPERIENCE & ~(255 << 24)) | (@Q_heal_exp << 24);
+ goto L_Return;
+
+L_Return:
+ return;
+}
+
+002-1,75,62,0 script Elanore#_M NPC108,{
+ @has_magic = getskilllv(SKILL_MAGIC);
+
+ @Q_MASK = NIBBLE_1_MASK;
+ @Q_SHIFT = NIBBLE_1_SHIFT;
+
+ @Q_status = (QUEST_MAGIC2 & @Q_MASK) >> @Q_SHIFT;
+ @Q_heal_exp = MAGIC_EXPERIENCE >> 24;
+
+ // Set up SkillUp function
+ @SUP_id = SKILL_MAGIC_LIFE;
+ @SUP_name$ = "Life Magic";
+
+ @STATUS_INITIAL = 0;
+ @STATUS_LEARNED_LIGHT_HEAL = 1;
+ @STATUS_MASTERED_LIGHT_HEAL = 2;
+ @STATUS_LEARNED_LAY_ON_HANDS = 3;
+ @STATUS_WAITING_FOR_KADIYA = 4;
+ @STATUS_READY_TO_LEARN_CURE_POISON = 5;
+ @STATUS_LEARNED_CURE_POISON = 6;
+
+ callfunc "ElanoreFix";
+
+ // This operation works around an earlier possible corruption of this state
+ if (@Q_status > @Q_STATUS_MAX)
+ @Q_status = @STATUS_INITIAL;
+ callsub S_Update_Var;
+ if (sc_check(SC_POISON)) goto L_CurePoison;
+ if (BaseLevel > 20) goto L_NoHeal;
+ @temp = rand(4);
+ if(@temp == 1) goto L_Heal2;
+ if(@temp == 2) goto L_Heal3;
+ if(@temp == 3) goto L_Heal4;
+ goto L_Heal1;
+
+L_Heal1:
+
+ mes "[Elanore the Healer]";
+ mes "\"You don't look too well; let me treat your wounds.\"";
+ next;
+ goto L_Heal_L;
+
+L_Heal2:
+
+ mes "[Elanore the Healer]";
+ mes "\"I will make quick work of your wounds.\"";
+ next;
+ goto L_Heal_L;
+
+L_Heal3:
+
+ mes "[Elanore the Healer]";
+ mes "\"Need a healing?\"";
+ next;
+ goto L_Heal_L;
+
+L_Heal4:
+
+ mes "[Elanore the Healer]";
+ mes "\"Sometimes you just need to run from battle.\"";
+ next;
+ goto L_Heal_L;
+
+L_Heal_L:
+ @temp = rand(3);
+ if(@temp == 1) goto L_Heal_2;
+ if(@temp == 2) goto L_Heal_3;
+ if(@temp == 3) goto L_Heal_4;
+ goto L_Heal_1;
+
+L_Heal_1:
+
+ mes "[Elanore the Healer]";
+ mes "\"Here you go!\"";
+ heal 10000,10000;
+ goto L_close;
+
+L_Heal_2:
+
+ mes "[Elanore the Healer]";
+ mes "\"Painless, wasn't it?";
+ heal 10000,10000;
+ goto L_close;
+
+L_Heal_3:
+
+ mes "[Elanore the Healer]";
+ mes "\"You should be more careful.\"";
+ heal 10000,10000;
+ goto L_close;
+
+L_Heal_4:
+
+ mes "[Elanore the Healer]";
+ mes "\"Much better, right?!\"";
+ heal 10000,10000;
+ goto L_close;
+
+L_NoHeal:
+ if (MAGIC_FLAGS)
+ goto L_Chat;
+ goto L_NoHealMessage;
+
+L_NoHealMessage:
+ mes "[Elanore the Healer]";
+ mes "\"I'm sorry but unless you are young and in need, I can't help you, and your level is already higher than twenty.";
+ mes "With so many gaurds still injured, I really have no time to help.";
+ mes "You can get some rest in the inn near here.\"";
+ goto L_close;
+
+L_Chat:
+ mes "[Elanore the Healer]";
+ mes "\"Hello! Can I help you?\"";
+ next;
+ goto L_Main;
+
+L_Main:
+ if (@has_magic && (@Q_status == @STATUS_INITIAL))
+ menu
+ "Can you heal me?", L_NoHealMessage,
+ "Can you teach me magic?", L_Teach,
+ "What do you know about...", L_Question,
+ "Goodbye!", L_Bye;
+ if (@has_magic && (@Q_status > @STATUS_INITIAL))
+ menu
+ "Can you heal me?", L_NoHealMessage,
+ "Can you teach me more?", L_Teach,
+ "Where can I get more lifestones?", L_Lifestones,
+ "What do you know about...", L_Question,
+ "Goodbye!", L_Bye;
+ if (!@has_magic)
+ menu
+ "Can you heal me?", L_NoHealMessage,
+ "What do you know about...", L_Question,
+ "Goodbye!", L_Bye;
+ goto L_close;
+
+L_Lifestones:
+ mes "[Elanore the Healer]";
+ mes "\"I always need components for my own healing spells. If you bring me ten gamboge leaves, ten alizarin leaves, ten mauve leaves and ten cobalt leaves, I can make ten lifestones; I will give you half of them.\"";
+ next;
+ menu
+ "OK, I will get them.", L_close,
+ "No way!", L_close,
+ "Here you are!", L_Trade,
+ "Can I make them myself?", L_MakeSelf;
+
+L_Trade:
+ if (countitem("MauveHerb") < 10) goto L_Trade_Missing;
+ if (countitem("GambogeHerb") < 10) goto L_Trade_Missing;
+ if (countitem("AlizarinHerb") < 10) goto L_Trade_Missing;
+ if (countitem("CobaltHerb") < 10) goto L_Trade_Missing;
+ getinventorylist;
+ if (@inventorylist_count == 100 && countitem("Lifestone") == 0
+ && countitem("MauveHerb") > 10
+ && countitem("GambogeHerb") > 10
+ && countitem("AlizarinHerb") > 10
+ && countitem("CobaltHerb") > 10) goto L_NoRoom;
+
+ delitem "MauveHerb", 10;
+ delitem "GambogeHerb", 10;
+ delitem "AlizarinHerb", 10;
+ delitem "CobaltHerb", 10;
+ getitem "Lifestone", 5;
+ getexp 200, 1;
+ mes "[Elanore the Healer]";
+ mes "Elanore carefully goes over your leaves, then smiles.";
+ mes "\"These will do just fine.\"";
+ mes "She picks up all fourty and presses them together in her hands, then whispers something.";
+ next;
+ mes "[Elanore the Healer]";
+ mes "As she opens her hands again, the leaves have turned into ten golden crystals.";
+ mes "\"Five for you and five for me.\"";
+ mes "She smiles.";
+ mes "[200 experience points]";
+ goto L_close;
+
+L_NoRoom:
+ mes "[Elanore the Healer]";
+ mes "\"Oh... it seems that you have no room for the lifestones. But please do come back later when you have made a little space.\"";
+ goto L_close;
+
+L_Trade_Missing:
+ mes "[Elanore the Healer]";
+ mes "Elanore counts the leaves you show her.";
+ mes "\"No, I am sorry. Please bring me ten leaves each of gamboge, alizarin, mauve, and cobalt.\"";
+ goto L_close;
+
+L_MakeSelf:
+ mes "[Elanore the Healer]";
+ if (@has_magic < 2) goto L_MakeSelf_no;
+ goto L_MakeSelf_yes;
+
+L_MakeSelf_yes:
+ mes "\"Oh, but of course! You are powerful enough to make your own lifestones, using the enchantment '" + get(.invocation$, "enchant-lifestone") + "'. This will consume a bug leg or a maggot slime or one of each of the four healing herbs, though.\"";
+ goto L_close;
+
+L_MakeSelf_no:
+ mes "\"No, you are not powerful enough yet. Please come back and ask me again when you have learned to control more powerful magic, though!\"";
+ goto L_close;
+
+L_Teach:
+ if (@Q_status == @STATUS_INITIAL) goto L_T_Initial;
+ if (@Q_status == @STATUS_LEARNED_LIGHT_HEAL) goto L_T_ChkAdvTo2;
+ if (@Q_status == @STATUS_MASTERED_LIGHT_HEAL) goto L_T_ChkAdvToLOH;
+ if (@Q_status == @STATUS_LEARNED_LAY_ON_HANDS) goto L_T_Explain3;
+ if (@Q_status == @STATUS_WAITING_FOR_KADIYA) goto L_T_ChkAdvTo3;
+ if (@Q_status == @STATUS_READY_TO_LEARN_CURE_POISON) goto L_T_CurePosion;
+ if (@Q_status == @STATUS_LEARNED_CURE_POISON) goto L_T_dunno;
+
+ mes "[Elanore the Healer]";
+ mes "\"You have made good progress, but you lack the magical power to advance further. Also, I would like to observe you some more to be certain that you will make a good healer.\"";
+ goto L_close;
+
+L_T_Initial:
+ mes "[Elanore the Healer]";
+ mes "\"I will only teach you magic of the school of Life, and that only if you prove yourself to be a good healer – that is, if you use your powers to help others.\"";
+ mes "She hesistates.";
+ next;
+ mes "[Elanore the Healer]";
+ mes "\"I don't know you very well, but I don't think that there is any harm in teaching you a simple spell.\"";
+ mes "She reaches inside her satchel and pulls out a piece of crystal, glittering in the sun.";
+ mes "\"This here is a lifestone, life energy encased in a crystal shell. You will need it for most healing magic.\"";
+ next;
+ mes "[Elanore the Healer]";
+ mes "\"To heal someone, first locate the injury. As a beginner, you have to touch the wound; with practice, it will be enough to think about it. Hold the lifestone in one hand, touching the wound with the other.\"";
+ mes "\"Then say, '" + get(.invocation$, "lesser-heal") + "', followed by the name of the one you wish to heal.\"";
+ next;
+ mes "[Elanore the Healer]";
+ mes "\"You might want to write that down, actually. In fact, you might want to make sure to keep notes of all spells you hear, for you never know if you will hear them again!\"";
+ mes "\"The invocation was '" + get(.invocation$, "lesser-heal") + "'.\"";
+ next;
+ mes "[Elanore the Healer]";
+ mes "\"This will only cure cuts and bruises, though, and it will take some time to take effect. It will be useless to mend broken bones or more severe injuries!\"";
+ mes "\"To heal yourself, it's enough to just say '" + get(.invocation$, "lesser-heal") + "' by itself.\"";
+ next;
+ mes "[Elanore the Healer]";
+ mes "\"Let me give you a lifestone to get started with.\"";
+ next;
+ getinventorylist;
+ if ((@inventorylist_count == 100) && (countitem("Lifestone") == 0)) goto L_T_Initial_Noroom;
+ getitem "Lifestone", 1;
+ @Q_status = @STATUS_LEARNED_LIGHT_HEAL;
+ callsub S_Update_Var;
+
+ mes "[Elanore the Healer]";
+ mes "Elanore hands you the crystal.";
+ mes "\"Here you are. I hope that it will allow you to do good!\"";
+ goto L_close;
+
+L_T_Initial_Noroom:
+ mes "[Elanore the Healer]";
+ mes "\"Oh... you managed to put things into every little nook and pocket, haven't you? Well, come back later, I will give it to you then.\"";
+ goto L_close;
+
+L_T_ChkAdvTo2:
+ mes "[Elanore the Healer]";
+ if (@Q_heal_exp < 20) goto L_T_ChkAdvTo2_fail;
+ mes "Elanore smiles at you.";
+ mes "\"From what I have been hearing, you seem to be doing well on your way to becoming a healer. I have decided to accept you as a student of the School of Life Magic.\"";
+ next;
+ if (getskilllv(SKILL_MAGIC) < 2) goto L_T_AdvTo2_warn;
+ goto L_T_AdvTo2_skip;
+
+L_T_AdvTo2_warn:
+ mes "[Elanore the Healer]";
+ mes "\"But be warned: you won't be able to use advanced healing magic until you are more capable in your regular magic usage.\"";
+ next;
+ goto L_T_AdvTo2_skip;
+
+L_T_AdvTo2_skip:
+ mes "[Elanore the Healer]";
+ mes "\"Please stand still.\"";
+ mes "She walks up to you, holds your shoulders, and smiles at you.";
+ next;
+ mes "[Elanore the Healer]";
+ mes "Then, she rises up on her tiptoes and kisses you on your forehead.";
+ next;
+ mes "[Elanore the Healer]";
+ mes "You feel a strange, tingling kind of warmth spread through your body.";
+ @Q_status = @STATUS_MASTERED_LIGHT_HEAL;
+ callsub S_Update_Var;
+ @SUP_xp = 5000;
+ @SUP_lvl = 2;
+ callfunc "SkillUp";
+ goto L_close;
+
+L_T_ChkAdvTo2_fail:
+ mes "\"I think I would like to observe you for a little longer to see if you would make a good healer.\"";
+ if (@Q_heal_exp < 5)
+ mes "\"You are still at the beginning of your path, but do keep practicing.\"";
+ if ((@Q_heal_exp >= 5) && (@Q_heal_exp < 15))
+ mes "\"You are making progress, but you still need more practice.\"";
+ if (@Q_heal_exp >= 15)
+ mes "\"You have made good progress, but please do continue in your efforts.\"";
+ goto L_close;
+
+L_T_ChkAdvToLOH:
+ if (getskilllv(SKILL_MAGIC) < 2) goto L_T_LOH_adv_abort0;
+ if (@Q_heal_exp < 30) goto L_T_LOH_adv_abort1;
+
+ mes "[Elanore the Healer]";
+ mes "\"I will now teach you how to heal by laying on your hands. The technique is similar to the spell I taught you at the beginning, but this time you transfer your own health instead of drawing health from a lifestone.\"";
+ next;
+ mes "[Elanore the Healer]";
+ mes "\"First, lay your hand on the person you wish to heal. You needn't touch the injury itself, though you have to touch the skin until you are a little more experienced. Then, medidate on the word '" + get(.invocation$, "lay-on-hands") + "'\"";
+ next;
+ mes "[Elanore the Healer]";
+ mes "\"This will let your own life force flow into the person you are healing. If you are badly injured yourself, you will not be able to do this.\"";
+ mes "[1000 experience points]";
+ getexp 1000, 0;
+ @Q_status = @STATUS_LEARNED_LAY_ON_HANDS;
+ callsub S_Update_Var;
+ goto L_close;
+
+L_T_LOH_adv_abort0:
+ mes "[Elanore the Healer]";
+ mes "\"You don't have enough magical power to learn the next healing spell yet.\"";
+ goto L_close;
+
+L_T_LOH_adv_abort1:
+ mes "[Elanore the Healer]";
+ mes "\"I'm sorry, but I am not yet convinced that you are a good enough healer. Please continue in your endeavours.\"";
+ goto L_close;
+
+L_T_Explain3:
+ if (getskilllv(SKILL_MAGIC) < 3) goto L_T_Explain3_abort;
+ if (@Q_heal_exp < 50) goto L_T_Explain3_fail;
+
+ mes "[Elanore the Healer]";
+ mes "Elanore smiles.";
+ mes "\"You seem to be ready to advance as a healer. There is one favour I must ask of you first, though.\"";
+ set QUEST_MAGIC2, (QUEST_MAGIC2 & ~(NIBBLE_3_MASK)); // Initialise Kadiya quest
+ @Q_status = @STATUS_WAITING_FOR_KADIYA;
+ callsub S_Update_Var;
+ next;
+
+ mes "[Elanore the Healer]";
+ mes "\"There is a man here in Tulimshar with a beautiful young daughter; his name is Omar, and his daughter's name is Kadiya.\"";
+ mes "\"Once, when I was a young apprentice, I made a mistake treating Omar. Ever since, he no longer trusts me.\"";
+ next;
+
+ mes "[Elanore the Healer]";
+ mes "\"But his daugher has contracted Mopox, so she needs help. He doesn't trust me, but perhaps he will trust you; you have been helping quite a few people, after all.\"";
+ next;
+ goto L_3_menu;
+
+L_3_menu:
+ menu
+ "What should I do?", L_3_what_to_do,
+ "Where can I find the sick girl?", L_3_where,
+ "How did you mess up?", L_3_messup,
+ "I will get started right away.", L_Main,
+ "Maybe later.", L_Main;
+
+L_3_what_to_do:
+ mes "[Elanore the Healer]";
+ mes "\"You will have to brew a Mopox cure potion and give it to her. You should ask Caul to help you, he knows the recipe.\"";
+ next;
+ mes "[Elanore the Healer]";
+ mes "\"First, you will need a concentration potion and an iron potion – together, they will give her her strength back. You also need a lifestone, and a gamboge leaf against the toxins in her body.\"";
+ next;
+ mes "[Elanore the Healer]";
+ mes "\"You then have to add in roots, water, mauve leaves and sulphur powder until the brew is gooey and neither light nor dark. Caul will explain the details to you.\"";
+ next;
+ mes "[Elanore the Healer]";
+ mes "\"There is a transmutation spell to make sulphur powder. If you don't know the magic, perhaps you can ask a transmutation mage to help you with this part.\"";
+ next;
+ goto L_3_menu;
+
+L_3_messup:
+ mes "[Elanore the Healer]";
+ mes "\"Ah... well, Omar is a trader, and a frequent traveler. One day he came back from a journey with fleas in his beard and asked me to get rid of them.\"";
+ next;
+ mes "[Elanore the Healer]";
+ mes "\"Unfortunately I used the wrong lotion on the fleas, so instead of being scared away, they grew to enormous proportions and ate up all of his beard.\"";
+ next;
+ mes "[Elanore the Healer]";
+ mes "Elanore blushes.";
+ mes "\"Ever since then he hasn't been very trusting towards my skills, and I suppose that I can't blame him. But I don't want poor Kadiya to suffer because of that.\"";
+ next;
+ goto L_3_menu;
+
+L_3_where:
+ mes "[Elanore the Healer]";
+ mes "\"Kadiya and Omar live relatively close by. See this corner in the inner city wall east of here? Turn past it, then go north. It's the second house.\"";
+ next;
+ goto L_3_menu;
+
+L_T_Explain3_abort:
+ mes "[Elanore the Healer]";
+ mes "\"I'm sorry, but you lack the magical power to advance.\"";
+ goto L_close;
+
+L_T_Explain3_fail:
+ mes "[Elanore the Healer]";
+ if (@Q_heal_exp < 30)
+ mes "\"You seem to have regressed as a healer. This is worrisome; please mend your ways or I will not teach you any further.\"";
+ if ((@Q_heal_exp >= 30) && (@Q_heal_exp < 40))
+ mes "\"You still need more practice in the art of healing.\"";
+ if ((@Q_heal_exp >= 40))
+ mes "\"You are doing well, but you need some more practice as a healer first.\"";
+ goto L_close;
+
+L_T_ChkAdvTo3:
+ callfunc "KadiyaSubquestConsts";
+
+ if (@Q_kadiya_status >= @Q_STATUS_COMPLETED) goto L_T_AdvTo3Ready;
+
+ mes "[Elanore the Healer]";
+ mes "\"Please help Kadiya.\"";
+ next;
+ goto L_3_menu;
+
+L_T_AdvTo3Ready:
+ mes "[Elanore the Healer]";
+ mes "\"I have heard of what you did. Hiding the potion in her favorite food – that was clever.\"";
+ mes "She smiles at you.";
+ mes "\"Omar let me have a look at her earlier, and she seems to be recovering. You did very well.";
+ next;
+ mes "[Elanore the Healer]";
+ mes "Elanor turns towards you, rises up on her toes and kisses you on the forehead.";
+ next;
+ @xp = 30000;
+ if (@Q_kadiya_status == @Q_STATUS_COMPLETED_ELANORE)
+ @xp = 50000;
+ mes "[Elanore the Healer]";
+ mes "You feel a strange, tingling kind of warmth spread through your body.";
+ mes "[" + @xp + " experience points]";
+ mes "[Level 3 in Life Magic]";
+
+ @Q_status = @STATUS_READY_TO_LEARN_CURE_POISON;
+ callsub S_Update_Var;
+ getexp @xp, 0;
+ if (getskilllv(SKILL_MAGIC_LIFE) < 3)
+ addtoskill SKILL_MAGIC_LIFE, 3;
+ next;
+
+ if (@Q_kadiya_status != @Q_STATUS_COMPLETED_ELANORE) goto L_Main;
+
+ mes "[Elanore the Healer]";
+ mes "\"Overall I am impressed by your progress. If you continue as you are doing now, you might become a great healer.\"";
+ mes "She hands you a handful of lifestones.";
+ mes "\"Please come back soon; there is more that I would like to teach you.\"";
+ next;
+ MAGIC_FLAGS = MAGIC_FLAGS | MFLAG_ELANORE_OMAR;
+ getitem "Lifestone", 20;
+
+ goto L_Main;
+
+L_T_CurePosion:
+ mes "[Elanore the Healer]";
+ mes "\"Thank you again for your help with Kadiya!\"";
+ mes "\"Curing sicknesses is often quite difficult; most of them require complicated potions to be brewed.\"";
+ next;
+ mes "[Elanore the Healer]";
+ mes "\"Fortunately, things are much easier with most poisons. For those we have a simple spell that only requires a Gamboge leaf.\"";
+ mes "\"This is the next spell that I would like to teach you.\"";
+ next;
+ mes "[Elanore the Healer]";
+ mes "\"If you would like to cure someone who is poisoned, first rub a Gamboge leaf between your hands. Your hands must be covered in Gamboge liquid for this to work.\"";
+ mes "\"Speak the invocation, `" + get(.invocation$, "cure-poison") + "'.\"";
+ mes "\"Next, you either touch the poisoned person with your hands, or speak their name. You have to be close for this to work, though.\"";
+ next;
+ mes "[Elanore the Healer]";
+ mes "\"Once again, the invocation is `" + get(.invocation$, "cure-poison") + "'.\"";
+ mes "\"Come back again soon; there is another spell I would like to teach you.\"";
+ next;
+ @Q_status = @STATUS_LEARNED_CURE_POISON;
+ callsub S_Update_Var;
+ goto L_Main;
+
+L_T_dunno:
+ mes "[Elanore the Healer]";
+ mes "\"Hmm. I wanted to teach you something, but I've forgotten what it was... please come back later.\"";
+ next;
+ goto L_Main;
+
+L_Question:
+ callfunc "MagicTalkOptionsSetup";
+ @ignore = @QQ_ELANORE;
+ callfunc "MagicTalkMenu";
+
+ if (@c == 0) goto L_Main;
+ if (@c == @QQ_MANASEED) goto L_Q_manaseed;
+ if (@c == @QQ_MANAPOTION) goto L_Q_manapotion;
+ if (@c == @QQ_WYARA) goto L_Q_wyara;
+ if (@c == @QQ_SAGATHA) goto L_Q_sagatha;
+ if (@c == @QQ_AULDSBEL) goto L_Q_auldsbel;
+ if (@c == @QQ_OLDWIZ) goto L_Q_oldwiz;
+ if (@c == @QQ_ASTRALSOUL) goto L_Q_astralsoul;
+
+ mes "[Elanore the Healer]";
+ mes "Elanore shakes her head.";
+ mes "\"I am sorry, but I don't think that I know anything that would help you.\"";
+ next;
+ goto L_Main;
+
+L_Q_astralsoul:
+ mes "[Elanore the Healer]";
+ mes "\"The astral soul skill is one of the most important skills for mages. I learned this focus long time ago. Without that skill your magic is quite useless, isn't it? If the rumors are really true, there is an experienced mage in the Woodlands around Hurnscald.\"";
+ next;
+ goto L_Main;
+
+L_Q_oldwiz:
+ mes "[Elanore the Healer]";
+ mes "\"He is a kind old man. He stays mostly with his books and his apprentice, though we have chatted a few times.\"";
+ next;
+ goto L_Main;
+
+L_Q_manaseed:
+ mes "[Elanore the Healer]";
+ mes "She smiles.";
+ mes "\"If the rumors are true and there really is a Mana Seed, then that would be wonderful news – perhaps we will have a few more healers soon!\"";
+ next;
+ goto L_Main;
+
+L_Q_manapotion:
+ mes "[Elanore the Healer]";
+ mes "\"I'm sorry, but I can't help you with that.\"";
+ next;
+ goto L_Main;
+
+L_Q_wyara:
+ mes "[Elanore the Healer]";
+ mes "\"Wyara is the Hurnscald town witch. She was also the town healer before the Doctor moved there.\"";
+ next;
+ goto L_Main;
+
+L_Q_sagatha:
+ mes "[Elanore the Healer]";
+ mes "\"Oh, I have only met Sagatha once or twice, while collecting herbs. She is a warm and gentle person, but she tries to hide it.\"";
+ next;
+ goto L_Main;
+
+L_Q_auldsbel:
+ mes "[Elanore the Healer]";
+ mes "\"Oh, sorry – I don't really know him very well.\"";
+ next;
+ goto L_Main;
+
+L_CurePoison:
+ mes "[Elanore the Healer]";
+ mes "\"Oh dear! That looks like poison; hang on...\"";
+ mes "She performs a complicated gesture.";
+ sc_end(SC_POISON);
+ sc_end(SC_SLOWPOISON);
+ misceffect sfx_magic_life, strcharinfo(0);
+ misceffect sfx_magic_life;
+ next;
+ mes "[Elanore the Healer]";
+ mes "\"There you are, right as rain! Now you take care, all right?\"";
+ goto L_close;
+
+L_Bye:
+ mes "[Elanore the Healer]";
+ mes "\"Goodbye!\"";
+ goto L_close;
+
+L_close:
+ @Q_MASK = 0;
+ @Q_SHIFT = 0;
+ @has_magic = 0;
+ @Q_STATUS_MAX = 0;
+ @Q_heal_exp = 0;
+ @Q_status = 0;
+ @SUP_id = 0;
+ @SUP_name$ = "";
+ @ignore = 0;
+ @STATUS_LEARNED_LIGHT_HEAL = 0;
+ @STATUS_MASTERED_LIGHT_HEAL = 0;
+ @STATUS_LEARNED_LAY_ON_HANDS = 0;
+ @STATUS_WAITING_FOR_KADIYA = 0;
+ @STATUS_READY_TO_LEARN_CURE_POISON = 0;
+ @STATUS_LEARNED_CURE_POISON = 0;
+ @temp = 0;
+ @xp = 0;
+ close;
+
+S_Update_Var:
+ QUEST_MAGIC2 = (QUEST_MAGIC2 & ~(@Q_MASK) | (@Q_status << @Q_SHIFT));
+ return;
+}
diff --git a/npc/002-1/gaurds.txt b/npc/002-1/gaurds.txt
new file mode 100755
index 00000000..c69a823f
--- /dev/null
+++ b/npc/002-1/gaurds.txt
@@ -0,0 +1,15 @@
+002-1,100,21,0 script Guard#port1 NPC104,{
+ mes "[Guard]";
+ mes "\"Lots of stuff happens in the port district. Those sailors can get quite rowdy.\"";
+ close;
+}
+002-1,61,27,0 script Guard#port2 NPC104,{
+ mes "[Guard]";
+ mes "\"You wouldn't believe the refuse that comes in from the docks.\"";
+ close;
+}
+002-1,83,48,0 script Guard#east1 NPC104,{
+ mes "[Guard]";
+ mes "\"I make sure less desirables don't bother the Nobles.\"";
+ close;
+}
diff --git a/npc/002-1/itka.txt b/npc/002-1/itka.txt
new file mode 100755
index 00000000..42ae91bd
--- /dev/null
+++ b/npc/002-1/itka.txt
@@ -0,0 +1,19 @@
+002-1,66,39,0 script Itka NPC114,{
+ mes "[Itka]";
+ mes "\"This hotel is the best!\"";
+ next;
+ mes "\"It has a Baker, a Barber, a Casino and a Theatre.\"";
+ next;
+ mes "\"Come on inside now!\"";
+ close;
+
+OnTimer300000:
+ npctalk strnpcinfo(0), "Come to The Wizard's Rest!";
+ setnpctimer 0;
+ end;
+
+OnInit:
+ if (debug >= 2) end;
+ initnpctimer;
+ end;
+}
diff --git a/npc/002-1/lieutenant_dausen.txt b/npc/002-1/lieutenant_dausen.txt
new file mode 100755
index 00000000..1144232d
--- /dev/null
+++ b/npc/002-1/lieutenant_dausen.txt
@@ -0,0 +1,110 @@
+002-1,63,67,0 script Lieutenant Dausen NPC122,{
+ if (QL_MINEALL == 21) goto L_LD_Key;
+ if (QL_MINEALL == 7) goto L_LD_Miners;
+ if (QL_MINEALL == 6) goto L_LD_Orders;
+ if (QL_MINEALL == 5) goto L_LD_Nickos_Waits;
+ if (QL_MINEALL == 4) goto L_LD_Nickos;
+ if (QL_MINEALL == 3) goto L_LD_Waits;
+ if (QL_MINEALL == 2) goto L_LD_Woe_Is_Me;
+ if (QL_MINEALL == 1) goto L_LD_Drinks;
+
+ mes "[Lieutenant Dausen]";
+ mes "\"Hello. I am Lieutenant Dausen. I monitor the monster threat around the city to ensure the safety of its citizens.\"";
+ if (QL_MINEALL)
+ goto L_close;
+ goto L_LD_Start;
+
+L_LD_Start:
+ QL_MINEALL = 1;
+ next;
+ mes "\"Out here in the desert, it sure does get hot! My men and I get thirsty rather quickly. Cactus Drinks are our favourite; if you can get some for us, we'd surely appreciate your effort. About 10 would do.\"";
+ goto L_close;
+
+L_LD_Drinks:
+ if (countitem ("CactusDrink") < 10)
+ goto L_LD_NotEnough_Drink;
+ getinventorylist;
+ if (@inventorylist_count - (countitem("CactusDrink") == 10) > 99)
+ goto L_LD_TooMany;
+ QL_MINEALL = 2;
+ delitem "CactusDrink", 10;
+ getitem "Boots", 1;
+ mes "[Lieutenant Dausen]";
+ mes "\"Great! This will help us make it through the hot day. As a gift for your troubles, take these boots to keep your feet from burning on the sand. Have a good day...\"";
+ next;
+ mes "Lieutenant Dausen mumbles to himself and rubs his head.";
+ next;
+ mes "\"I have another problem, though. I mixed up the orders to my men, Nickos and Stewen. Someone needs to let them know they're going to have to hold their post for a while longer instead of taking a break. However, I can't leave my post! Oh, what to do, what to do...\"";
+ menu
+ "I can help you out, since you helped me too.", L_LD_Help,
+ "Thanks for the boots, gotta run now.", L_LD_NoHelp;
+
+L_LD_NotEnough_Drink:
+ mes "[Lieutenant Dausen]";
+ mes "\"Hi again. My men and I sure are thirsty for our favorite drink, the Cactus Drink. If we had about 10, it would help us out a great deal in this sandstorm.\"";
+ goto L_close;
+
+L_LD_TooMany:
+ mes "[Lieutenant Dausen]";
+ mes "\"Oh, it seems you have too many items for me to give you a reward. Come back after you drop or sell some items.\"";
+ goto L_close;
+
+L_LD_Woe_Is_Me:
+ mes "[Lieutenant Dausen]";
+ mes "\"I have a problem. I mixed up the orders to my men! Someone needs to let them know they're going to have to hold their post for a while longer instead of taking a break. However, I can't leave my post. Oh, what to do, what to do...\"";
+ menu
+ "I can help you out, since you helped me out too.", L_LD_Help,
+ "Bye-bye.", L_LD_NoHelp;
+
+L_LD_Help:
+ QL_MINEALL = 3;
+ mes "[Lieutenant Dausen]";
+ mes "\"Oh! Would you? You are ever most helpful! Could you let Stewen know first? I'm the most worried about the monsters from the eastern desert and he should know first to hold his post. Come back to me after you see him. Hope to hear from you soon!\"";
+ goto L_close;
+
+L_LD_NoHelp:
+ mes "[Lieutenant Dausen]";
+ mes "\"See you later then.\"";
+ goto L_close;
+
+L_LD_Waits:
+ mes "[Lieutenant Dausen]";
+ mes "\"I do hope Stewen holds his post. If you could tell them to do so, it would help me out a great deal.\"";
+ goto L_close;
+
+L_LD_Nickos:
+ QL_MINEALL = 5;
+ mes "[Lieutenant Dausen]";
+ mes "\"Thanks for letting Stewen know. Can you now tell Nickos to hold his post too? He guards the mine to the south, monitoring the monster threat and protecting the miners when he can.\"";
+ goto L_close;
+
+L_LD_Nickos_Waits:
+ mes "[Lieutenant Dausen]";
+ mes "\"Could you let Nickos know to hold his post? It would be very helpful. He is guarding the mine south of here.\"";
+ goto L_close;
+
+L_LD_Orders:
+ QL_MINEALL = 7;
+ Zeny = Zeny + 500;
+ mes "[Lieutenant Dausen]";
+ mes "\"Thank you for clearing up the orders to my men! Here's some gold for your efforts.\"";
+ next;
+ mes "\"If you think you can handle the monsters lurking out here, I'm sure Nickos and the miners could use some help. Talk to you later.\"";
+ goto L_close;
+
+L_LD_Miners:
+ mes "[Lieutenant Dausen]";
+ mes "\"I monitor the monster threat around the city to ensure the safety of its citizens.\"";
+ next;
+ mes "\"If you think you can handle the monsters lurking out here, I'm sure Nickos and the miners could use some help. Talk to you later.\"";
+ goto L_close;
+
+L_LD_Key:
+ QL_MINEALL = 22;
+ mes "[Lieutenant Dausen]";
+ mes "\"Oh, Naem lost his key? Here, take this spare. It should help you get into the underground palace.\"";
+ goto L_close;
+
+L_close:
+ close;
+}
diff --git a/npc/002-1/luca.txt b/npc/002-1/luca.txt
new file mode 100755
index 00000000..4c139cc2
--- /dev/null
+++ b/npc/002-1/luca.txt
@@ -0,0 +1,449 @@
+
+002-1,112,26,0 script Luca NPC102,{
+ @Exp_BRAWLING = 2000;
+
+ if (BaseLevel >= 35) goto L_Teach;
+
+ if (BaseLevel >= 25) goto L_Teach_soon;
+
+ mes "[Luca the Hunter]";
+ mes "\"Ouch! It hurts, this wound I got from battle.\"";
+ next;
+ menu "Tell me about it",L_Exp,"Nevermind",L_Nev;
+
+L_Exp:
+ mes "[Luca the Hunter]";
+ mes "\"I was just coming back from a long journey. I ran into a group of scorpions and started fighting them for experience.\"";
+ next;
+ mes "[Luca the Hunter]";
+ mes "\"Then, out of a cave came a BLACK one! I had NEVER seen it before!\"";
+ next;
+ mes "[Luca the Hunter]";
+ mes "\"Luckily I had a camera with me! Here's a picture of it... Let me find it, I put it in my pocket somewhere...\"";
+ next;
+ mes "[Luca the Hunter]";
+ mes "\"Oh man! My pockets have been ripped clean off!\"";
+ goto L_close;
+
+L_Nev:
+ mes "[Luca the Hunter]";
+ mes "\"Hmpf!\"";
+ goto L_close;
+
+L_Teach_soon:
+ mes "[Luca the Hunter]";
+ mes "\"You've grown quite a bit stronger since I first saw you, strolling around town like that! You know, if you train a little more, maybe we can help each other out a little?\"";
+ goto L_close;
+
+L_Teach:
+ if (getskilllv(SKILL_POOL)) goto L_Teachmore;
+
+ mes "[Luca the Hunter]";
+ mes "\"Hey there! You've become quite the adventurer, haven't you? I think it's time that someone taught you some basic skills.\"";
+ next;
+ mes "[Luca the Hunter]";
+ mes "\"If you want, I can help with that!\"";
+ next;
+ menu
+ "Sure, that sounds fun!", L_Next,
+ "I'm not interested.", L_Nev;
+
+L_Next:
+ mes "[Luca the Hunter]";
+ mes "\"All right! It's not all that easy, though. First you have to learn how to focus. That's because you can learn many skills, but you can't focus on all of them all the time.\"";
+ next;
+ mes "[Luca the Hunter]";
+ mes "\"When you can do that, you can learn some real skills, and when you know them, you can come back to me to tell me which ones you want to focus on. Deal?\"";
+ next;
+ menu
+ "Yeah!", L_Teach0_follow,
+ "Certainly!", L_Teach0_follow,
+ "Wait... what do you mean?", L_Explain,
+ "Please explain some more.", L_Explain,
+ "No.", L_Nev;
+
+L_Teach0_follow:
+ if (getskilllv(SKILL_POOL)) goto L_Teachmore;
+
+ mes "[Luca the Hunter]";
+ mes "\"Great! Now, before I can give you that skill, I have to make sure that those stories about you are all true and that you really are experienced enough.\"";
+ next;
+ mes "[Luca the Hunter]";
+ mes "\"So I'm going to ask you some easy questions.\"";
+ next;
+ mes "[Luca the Hunter]";
+ mes "\"First, who is the man who guards the entrance to the old Tulimshar underground arena?\"";
+ next;
+ input @answer$;
+ if (@answer$ != "Phaet" && @answer$ != "phaet") goto L_wronganswer;
+ mes "[Luca the Hunter]";
+ mes "\"Good. Next, what's the name of the pipe-smoker who lives on top of Lore Mountain and makes leathery goods there?\"";
+ next;
+ input @answer$;
+ if (@answer$ != "Pachua" && @answer$ != "pachua") goto L_wronganswer;
+ mes "[Luca the Hunter]";
+ mes "\"Great! One more: Who was the adventurer who built Dimond's Cove for Dimond?\"";
+ next;
+ input @answer$;
+ if (@answer$ != "Merlin" && @answer$ != "merlin") goto L_wronganswer;
+ mes "[Luca the Hunter]";
+ mes "Luca laughs in excitement.";
+ mes "\"All right! You're the real thing, my friend!\"";
+ next;
+ mes "[Luca the Hunter]";
+ mes "\"Now stand over there. This should only take a second...\"";
+ mes "He takes off a pendant he is wearing and holds it up.";
+ next;
+ mes "[Luca the Hunter]";
+ mes "\"See that fang at the end of the chain? Keep staring at it.\"";
+ next;
+ mes "[Luca the Hunter]";
+ mes "He starts swinging the pendant back and forth.";
+ mes "\"And whatever you do, don't blink. Don't look away, and don't blink.\"";
+ next;
+ mes "[Luca the Hunter]";
+ mes "The world slows down around you as you focus on the pendant going back...";
+ next;
+ mes "and forth...";
+ next;
+ mes "and back...";
+ next;
+ mes "and forth...";
+ next;
+ mes "and back...";
+ next;
+ mes "and...";
+ next;
+ mes "You feel relaxed.";
+ next;
+ mes "[Luca the Hunter]";
+ mes "\"... still there?\"";
+ mes "You hear the sound of fingers snapping. Why would someone do that on such a calm day?";
+ next;
+ mes "[Luca the Hunter]";
+ mes "\"Oh, good... I think it worked. Nice job!\"";
+ mes "He grins.";
+ mes "[You gain 10,000 experience points]";
+ mes "[You learned Skill Focus]";
+ addtoskill SKILL_POOL, 1;
+ getexp 10000, 0;
+ next;
+ goto L_Teachmore2;
+
+L_wronganswer:
+ mes "[Luca the Hunter]";
+ mes "\"No, that was wrong. I suppose you're not as experienced as I thought you'd be.\"";
+ goto L_close;
+
+L_Explain:
+ mes "[Luca the Hunter]";
+ mes "\"Alright, what do you want to know?\"";
+ next;
+ goto L_Explain_loop;
+
+L_Explain_loop:
+ menu
+ "What's skill focus?", L_explain_focus,
+ "What skills are there?", L_explain_skills,
+ "How do skills work?", L_explain_work,
+ "Thanks, I think I got it!", L_Next;
+
+L_explain_focus:
+ mes "[Luca the Hunter]";
+ mes "\"Well, you can learn many, many skills. But you can't really use all of them at once, not even old Auldsbels' head is big enough for that! So you have to focus.\"";
+ next;
+ mes "[Luca the Hunter]";
+ mes "\"But you can change that focus whenever you want. It works like this: You come to me, you tell me what you want to focus on, and we do exercises until it's stuck in your head.\"";
+ next;
+ mes "[Luca the Hunter]";
+ mes "\"If there's not enough space in your head, you'll first have to stop thinking about some other thing. There's an exercise I learned to do that, so when you talk to me you can just let me know what you want to forget.\"";
+ next;
+ mes "[Luca the Hunter]";
+ if (getskilllv(SKILL_POOL) == 0)
+ mes "\"Right now you can't focus on anything yet, so I'll first have to teach you a simple skill to keep your focus.\"";
+ if (getskilllv(SKILL_POOL) == 1)
+ mes "\"Right now you can only focus on one thing at a time. So if you want to change what your focus is, you have to forget whatever else you've focused on.\"";
+ if (getskilllv(SKILL_POOL) > 1)
+ mes "\"You can focus on " + getskilllv(SKILL_POOL) + " skills right now.\"";
+ next;
+ mes "[Luca the Hunter]";
+ mes "\"You can come back to me to focus or unfocus a skill whenever you want, I'm here all day.\"";
+ next;
+ mes "\"For unfocusing you need to bring a potion; a special potion. That potion is not the easiest to get, but I am sure you are able to.\"";
+ next;
+ goto L_Explain_loop;
+
+L_explain_skills:
+ mes "[Luca the Hunter]";
+ mes "\"Well, I don't really know... lots, I think. I can teach you brawling, which is good when you've run out of arrows or don't have a weapon around.\"";
+ next;
+ mes "[Luca the Hunter]";
+ mes "\"But there's other skills around. Some mages need special skills to concentrate, so ask around in that crowd, if that's your thing.\"";
+ next;
+ mes "[Luca the Hunter]";
+ mes "\"I've also heard that there is someone in Hurnscald who can help you make your body more resistant against some things. But body and mind belong together, so you probably have to focus for that, too.\"";
+ next;
+ mes "[Luca the Hunter]";
+ mes "\"Other than that, just ask around! There have to be some people who can teach you something...\"";
+ next;
+ goto L_Explain_loop;
+
+L_explain_work:
+ mes "[Luca the Hunter]";
+ mes "\"Well, skills allow you to be better in some things, or allow to do what you couldn't do without them. When you've learned a skill and are focusing on it, then it affects what you do.\"";
+ next;
+ mes "[Luca the Hunter]";
+ mes "\"Now, when you start out with a skill, you won't be very good at it yet. But if you keep practicing you'll learn how to get better.\"";
+ next;
+ mes "[Luca the Hunter]";
+ mes "\"My old teacher always called that getting `skill points' and that you can see them with [F5], whoever that is.\"";
+ next;
+ //TODO:
+ //mes "[Luca the Hunter]";
+ //mes "\"She also said that with this [F5] thing you can get better at those skills, and that it costs you as many skill points as the level you want to go to.\"";
+ //next;
+ mes "[Luca the Hunter]";
+ mes "\"She always would have one cactus potion too many... but she was an amazing teacher.\"";
+ mes "He nods emphatically.";
+ next;
+ goto L_Explain_loop;
+
+L_Teachmore:
+ mes "[Luca the Hunter]";
+ mes "\"Good to see you again!\"";
+ next;
+ goto L_Teachmore2;
+
+L_Teachmore2:
+ setarray @choices, 0,0,0,0,0;
+ setarray @choice$, "", "", "", "", "";
+ @choice_nr = 0;
+
+ @C_focus = 1;
+ @C_unfocus = 2;
+ @C_teachbrawling = 3;
+ @C_teachnothing = 4;
+ @C_explainagain = 5;
+ @C_nvm = 6;
+ @C_focusoverview = 7;
+
+ getactivatedpoolskilllist;
+ if (!((getskilllv(SKILL_POOL) - @skilllist_count) > 0)) goto L_Teachmore2_nof;
+ getunactivatedpoolskilllist;
+ if (@skilllist_count == 0) goto L_Teachmore2_nof;
+ @choices[@choice_nr] = @C_focus;
+ @choice$[@choice_nr] = "I would like to focus.";
+ @choice_nr = @choice_nr + 1;
+ goto L_Teachmore2_nof;
+
+L_Teachmore2_nof:
+ getactivatedpoolskilllist;
+ if (@skilllist_count == 0) goto L_Teachmore2_nounf;
+ @choices[@choice_nr] = @C_unfocus;
+ @choice$[@choice_nr] = "I would like to unfocus.";
+ @choice_nr = @choice_nr + 1;
+ goto L_Teachmore2_nounf;
+
+L_Teachmore2_nounf:
+ if (!(getskilllv(SKILL_BRAWLING)))
+ @choices[@choice_nr] = @C_teachbrawling;
+ if (getskilllv(SKILL_BRAWLING))
+ @choices[@choice_nr] = @C_teachnothing;
+ @choice$[@choice_nr] = "Can you teach me a skill?";
+ @choice_nr = @choice_nr + 1;
+
+ @choices[@choice_nr] = @C_explainagain;
+ @choice$[@choice_nr] = "Can you explain skills again?";
+ @choice_nr = @choice_nr + 1;
+
+ if (!(getskilllv(SKILL_POOL))) goto L_Teachmore2_noovv;
+ @choices[@choice_nr] = @C_focusoverview;
+ @choice$[@choice_nr] = "Can you tell me what skills I'm currently focused on?";
+ @choice_nr = @choice_nr + 1;
+ goto L_Teachmore2_noovv;
+
+L_Teachmore2_noovv:
+ @choices[@choice_nr] = @C_nvm;
+ @choice$[@choice_nr] = "I'm done for now, thanks!";
+ @choice_nr = @choice_nr + 1;
+
+ menu
+ @choice$[0],L_MenuItems,
+ @choice$[1],L_MenuItems,
+ @choice$[2],L_MenuItems,
+ @choice$[3],L_MenuItems,
+ @choice$[4],L_MenuItems;
+
+L_MenuItems:
+ @menu = @menu - 1;
+ if (@choices[@menu] == 0) goto L_close;
+ if (@choices[@menu] == @C_focus) goto L_Focus;
+ if (@choices[@menu] == @C_unfocus) goto L_Unfocus;
+ if (@choices[@menu] == @C_teachbrawling) goto L_Teach_brawling;
+ if (@choices[@menu] == @C_teachnothing) goto L_Teach_nothing;
+ if (@choices[@menu] == @C_explainagain) goto L_Teachmore_explain;
+ if (@choices[@menu] == @C_focusoverview) goto L_Focus_overview;
+ if (@choices[@menu] == @C_nvm) goto L_close;
+ goto L_close;
+
+L_Teachmore_explain:
+ goto L_Explain;
+
+L_Focus:
+ getunactivatedpoolskilllist;
+ @skilllist_id[@skilllist_count] = 0;
+ @skilllist_name$[@skilllist_count] = "Nevermind";
+ @skilllist_name$[@skilllist_count + 1] = "";
+ menu
+ @skilllist_name$[0], L_MenuItems1,
+ @skilllist_name$[1], L_MenuItems1,
+ @skilllist_name$[2], L_MenuItems1,
+ @skilllist_name$[3], L_MenuItems1,
+ @skilllist_name$[4], L_MenuItems1,
+ @skilllist_name$[5], L_MenuItems1,
+ @skilllist_name$[6], L_MenuItems1,
+ @skilllist_name$[7], L_MenuItems1;
+
+L_MenuItems1:
+ @menu = @menu - 1;
+ if (@skilllist_id[@menu] == 0) goto L_Teachmore2;
+
+ poolskill @skilllist_id[@menu];
+ goto L_Teachmore2;
+
+L_Unfocus:
+ if (countitem("GrimaceOfDementia") > 0) goto L_Unfocus_menu;
+
+ if (MAGIC_FLAGS & MFLAG_KNOWS_UNFOCUS_RECIPE) goto L_Nopotion;
+
+ mes "[Luca the Hunter]";
+ mes "\"Unfocusing is one of the harder parts though, because it is sunk in. You see?\"";
+ next;
+ mes "\"So to remove that mental focus we will need a special potion.\"";
+ next;
+ mes "\"Maybe you should consult some very skilled alchemists.\"";
+ next;
+ mes "\"Ah yes, of course you will need a recipe. Although the alchemist usually knows it.\"";
+ next;
+ mes "\"The potion is called Grimace of Dementia. So the alchemist will know for sure.\"";
+ MAGIC_FLAGS = MAGIC_FLAGS | MFLAG_KNOWS_UNFOCUS_RECIPE;
+ menu
+ "Ok, I will get a Grimace of Dementia potion", L_close,
+ "Alright, be right back!", L_close;
+
+L_Nopotion:
+ mes "[Luca the Hunter]";
+ mes "\"Hey, you really need that dementia potion for unfocusing.\"";
+ next;
+ mes "\"Come back when you've found a suitable alchemist who can mix such a potion.\"";
+ next;
+ goto L_Teachmore2;
+
+L_Unfocus_menu:
+ mes "[Luca the Hunter]";
+ mes "\"Ahh, I see you have a dementia potion.\"";
+ next;
+ mes "\"What skill would you like to unfocus?\"";
+
+ getactivatedpoolskilllist;
+
+ @skilllist_id[@skilllist_count] = 0;
+ @skilllist_name$[@skilllist_count] = "Nevermind";
+ @skilllist_name$[@skilllist_count + 1] = "";
+ menu
+ @skilllist_name$[0], L_MenuItems2,
+ @skilllist_name$[1], L_MenuItems2,
+ @skilllist_name$[2], L_MenuItems2,
+ @skilllist_name$[3], L_MenuItems2,
+ @skilllist_name$[4], L_MenuItems2,
+ @skilllist_name$[5], L_MenuItems2,
+ @skilllist_name$[6], L_MenuItems2,
+ @skilllist_name$[7], L_MenuItems2;
+
+L_MenuItems2:
+ @menu = @menu - 1;
+ if (@skilllist_id[@menu] == 0) goto L_Teachmore2;
+
+ if (countitem("GrimaceOfDementia") == 0) goto L_Nopotion;
+ delitem "GrimaceOfDementia", 1;
+
+ unpoolskill @skilllist_id[@menu];
+ goto L_close;
+
+L_Focus_overview:
+ getactivatedpoolskilllist;
+
+ if (@skilllist_count != 0) goto L_Focus_overview1;
+ mes "[Luca the Hunter]";
+ mes "\"You aren't focused on a skill at the moment.\"";
+ next;
+ goto L_Teachmore2;
+
+L_Focus_overview1:
+ mes "[Luca the Hunter]";
+ @message$ = "\"At the moment you are focused on ";
+ goto L_Focus_overview2;
+
+L_Focus_overview2:
+ @skilllist_count = @skilllist_count-1;
+ @message$ = @message$ + @skilllist_name$[@skilllist_count];
+ if (@skilllist_count == 0) goto L_Focus_overview3;
+ @message$ = @message$ + ", ";
+ goto L_Focus_overview2;
+
+L_Focus_overview3:
+ @message$ = @message$ + ".\"";
+ mes @message$;
+ next;
+ goto L_Teachmore2;
+
+L_Teach_brawling:
+ mes "[Luca the Hunter]";
+ mes "\"Well, yes, I can teach you brawling. It's a nice thing, if you have nothing left but your hands to defend yourself.\"";
+ next;
+ mes "He is laughing.";
+ mes "\"And is handy, if some sapling starts getting naughty.\"";
+ next;
+ mes "He raises his hands in front of his face and clenches his fists.";
+ mes "\"Ok, let's go! Hold your hands like this.\"";
+ next;
+ mes ".......";
+ next;
+ mes "Some bruises later.";
+ mes "\"Great! I think, you got it.\"";
+ next;
+ @SUP_id = SKILL_BRAWLING;
+ @SUP_lvl = 1;
+ @SUP_name$ = "Brawling";
+ @SUP_xp = @Exp_BRAWLING;
+ callfunc "SkillUp";
+ goto L_close;
+
+L_Teach_nothing:
+ mes "[Luca the Hunter]";
+ mes "\"I was able to teach you brawling. For other professions you should visit someone else.\"";
+ next;
+ mes "\"You see, I am an adventurer. Everybody has his tricks. But you really should visit someone who is a teacher, not an adventurer, now.\"";
+ next;
+ goto L_Teachmore2;
+
+L_close:
+ @SUP_id = 0;
+ @SUP_lvl = 0;
+ @SUP_name$ = "";
+ @SUP_xp = 0;
+ @Exp_BRAWLING = 0;
+ @answer$ = "";
+ @message$ = "";
+ cleararray @choices[0], 0, 4;
+ cleararray @choice$[0], "", 4;
+ @choice_nr = 0;
+ @C_focus = 0;
+ @C_unfocus = 0;
+ @C_teachbrawling = 0;
+ @C_teachnothing = 0;
+ @C_explainagain = 0;
+ @C_nvm = 0;
+ @C_focusoverview = 0;
+ close;
+}
diff --git a/npc/002-1/mapflags.txt b/npc/002-1/mapflags.txt
new file mode 100755
index 00000000..8e244b73
--- /dev/null
+++ b/npc/002-1/mapflags.txt
@@ -0,0 +1 @@
+//002-1 mapflag resave 001-1,60,105
diff --git a/npc/002-1/mine_debug.txt b/npc/002-1/mine_debug.txt
new file mode 100755
index 00000000..b7f6ff23
--- /dev/null
+++ b/npc/002-1/mine_debug.txt
@@ -0,0 +1,68 @@
+
+function script DesertMineDebug {
+ mes "[Mine Debug]";
+ mes "What would you like to do?";
+ menu
+ "Reset", L_Reset,
+ "Set", L_Set,
+ "Show", L_Show,
+ "nothing.", L_close;
+
+L_Reset:
+ QL_MINEALL = 0;
+ FLAGS = FLAGS &~ FLAG_GOT_NAEM_GLOVES;
+ FLAGS = FLAGS &~ FLAG_OPENED_UNDERGROUND;
+ goto L_close;
+
+L_Set:
+ mes "Values are between 0 and 28";
+ mes "8 is Mine Start";
+ mes "18 is Angry Scorpions Start";
+ mes "20 is Underground Palace Start";
+ mes "26 is Giant Cave Maggot Start";
+ input QL_MINEALL;
+ goto L_close;
+
+L_Show:
+ mes "Current State: " + QL_MINEALL;
+ goto L_close;
+
+L_close:
+ return;
+}
+002-1,61,69,0 script Mine Debug#1 NPC122,{
+ callfunc "DesertMineDebug";
+ close;
+
+OnInit:
+ if (!debug)
+ disablenpc "Mine Debug#1";
+ end;
+}
+002-3,45,49,6 script Mine Debug#2 NPC109,{
+ callfunc "DesertMineDebug";
+ close;
+
+OnInit:
+ if (!debug)
+ disablenpc "Mine Debug#2";
+ end;
+}
+002-4,88,99,6 script Mine Debug#3 NPC109,{
+ callfunc "DesertMineDebug";
+ close;
+
+OnInit:
+ if (!debug)
+ disablenpc "Mine Debug#3";
+ end;
+}
+002-5,43,96,6 script Mine Debug#4 NPC340,{
+ callfunc "DesertMineDebug";
+ close;
+
+OnInit:
+ if (!debug)
+ disablenpc "Mine Debug#4";
+ end;
+}
diff --git a/npc/002-1/nickos.txt b/npc/002-1/nickos.txt
new file mode 100755
index 00000000..80c71da0
--- /dev/null
+++ b/npc/002-1/nickos.txt
@@ -0,0 +1,113 @@
+002-1,46,108,0 script Nickos NPC123,{
+ if (QL_MINEALL == 20) goto L_UGQ;
+ if (QL_MINEALL == 19) goto L_AS_Done;
+ if (QL_MINEALL == 18) goto L_AS_Start;
+ if (QL_MINEALL >= 11) && (QL_MINEALL < 18) goto L_Guards;
+ if (QL_MINEALL == 10) goto L_Check_Happy;
+ if (QL_MINEALL > 7) && (QL_MINEALL < 10) goto L_Waits;
+ if (QL_MINEALL == 7) goto L_Mine;
+ if (QL_MINEALL == 6) goto L_Orders_Received;
+ if (QL_MINEALL == 5) goto L_Orders;
+ if (QL_MINEALL < 5) goto L_See_Dausen_First;
+
+ mes "[Nickos]";
+ mes "\"I'm watching this mine to make sure the monsters don't harm the miners.\"";
+ goto L_close;
+
+L_See_Dausen_First:
+ mes "[Nickos]";
+ mes "\"I'm watching this mine to make sure the monsters don't harm the miners.\"";
+ next;
+ mes "[Nickos]";
+ mes "\"The mines are closed from tourists due to the monster threat. If you want to get in you will need to prove yourself first. Talk to Lieutenant Dausen, my superior, if you want to make a formal complaint.\"";
+ goto L_close;
+
+L_Orders:
+ QL_MINEALL = 6;
+ mes "[Nickos]";
+ mes "\"I have to hold my post longer? Argh! I was looking forward to my break. Oh well, thanks for letting me know.\"";
+ goto L_close;
+
+L_Orders_Received:
+ mes "[Nickos]";
+ mes "\"Thanks for letting me know Lieutenant Dausen wants me to stick it out for a while longer. Even though I would've liked my break, I'm sure these miners could use my watchful eye.\"";
+ goto L_close;
+
+L_Mine:
+ mes "[Nickos]";
+ mes "\"I haven't heard from the miners in a while, but I've got to keep to my post unless there is due reason to investigate. Normally the miners take care of themselves without any problem.\"";
+ next;
+ mes "[Nickos]";
+ mes "\"Could you check on them for me, though?\"";
+ menu
+ "Yes.", L_Mine_Open,
+ "No.", L_Disappoint;
+
+L_Disappoint:
+ mes "Nickos looks disappointed.";
+ goto L_close;
+
+L_Mine_Open:
+ QL_MINEALL = 8;
+ mes "[Nickos]";
+ mes "\"Excellent! You now have my permission to enter the mine. Your assistance helps ease my worries.\"";
+ goto L_close;
+
+L_Waits:
+ mes "[Nickos]";
+ mes "\"Please be sure to get word from Nathan and Naem to make sure everthing is okay down there. Your assistance helps ease my worries.\"";
+ goto L_close;
+
+L_Check_Happy:
+ QL_MINEALL = 11;
+ Zeny = Zeny + 500;
+ mes "[Nickos]";
+ mes "\"Oh, everything is okay? That's great! I think they are pretty busy and could use some help. Feel free to give them a hand. Here's some gold for your troubles.\"";
+ goto L_close;
+
+L_Guards:
+ mes "[Nickos]";
+ mes "\"I'm watching this mine to make sure the monsters don't harm the miners.\"";
+ next;
+ mes "\"Talk to Nathan the miner, I'm sure the miners could use some help down there.\"";
+ goto L_close;
+
+L_AS_Start:
+ QL_MINEALL = 19;
+ mes "[Nickos]";
+ mes "\"Oh, the angry scorpions are becoming a problem? We could thin down their numbers a bit. I can make it worth your time, but of course, I'll need something to show your work. Bring me 10 Angry Scorpion Stingers to demonstrate your effectiveness, and you will be rewarded for your efforts.\"";
+ goto L_close;
+
+L_AS_Done:
+ if (countitem ("AngryScorpionStinger") < 10)
+ goto L_AS_NotDone;
+ getinventorylist;
+ if (@inventorylist_count - (countitem("AngryScorpionStinger") == 10) > 99)
+ goto L_TooMany;
+ QL_MINEALL = 20;
+ delitem "AngryScorpionStinger", 10;
+ getitem "LeatherShield", 1;
+ mes "[Nickos]";
+ mes "\"Ah, you are a fine combatant! Take this Leather Shield, it might be useful for your future battles.\"";
+ next;
+ mes "\"You might be ready to take on the underground palace. If you are interested, go talk to Naem about unlocking the barrier, he's got the key and the code to open it.\"";
+ goto L_close;
+
+L_AS_NotDone:
+ mes "[Nickos]";
+ mes "\"Bring me 10 Angry Scorpion Stingers and I'll know their numbers are down. You will be rewarded for your efforts.\"";
+ goto L_close;
+
+L_TooMany:
+ mes "[Nickos]";
+ mes "\"Oh, it seems you have too many items. Please get rid some some and I'll give you a reward.\"";
+ goto L_close;
+
+L_UGQ:
+ mes "[Nickos]";
+ mes "\"You might be ready to take on the underground palace. If you are interested, talk to the miners about unlocking the barrier, they've got the key to open it.\"";
+ goto L_close;
+
+L_close:
+ close;
+}
diff --git a/npc/002-1/nomads.txt b/npc/002-1/nomads.txt
new file mode 100755
index 00000000..78b25708
--- /dev/null
+++ b/npc/002-1/nomads.txt
@@ -0,0 +1,13 @@
+
+002-1,101,114,0 script Samuel NPC132,{
+ mes "[Samuel the Nomad]";
+ mes "\"This is really a nice place.\"";
+ mes "Don't you think so?\"";
+ close;
+}
+
+002-1,105,114,0 script Elijah NPC128,{
+ mes "[Elijah the Nomad]";
+ mes "\"It's nice to find a respite like this...\"";
+ close;
+}
diff --git a/npc/002-1/npcs.txt b/npc/002-1/npcs.txt
new file mode 100755
index 00000000..72340405
--- /dev/null
+++ b/npc/002-1/npcs.txt
@@ -0,0 +1,22 @@
+002-1,96,23,0 script Jeric NPC214,{
+ @npcname$ = "Jeric";
+
+ mes "[" + @npcname$ + "]";
+ mes "\"My father is an adventurer.\"";
+ next;
+ mes "\"After he proved himself around town, the guards let him fight monsters in the Sandstorm mine.\"";
+ @npcname$ = "";
+ close;
+}
+002-1,112,48,0 script Silvia NPC207,{
+ @npcname$ = "Silvia";
+
+ mes "[" + @npcname$ + "]";
+ mes "\"If you follow the road west, then north, you will arrive at the Bazaar in Northern Tulimshar.\"";
+ next;
+ mes "\"If you go west, then north, you'll see the Wizard Academy my parents just sent me to.\"";
+ next;
+ mes "\"The Academy is good, but I wish I had more free time. It takes a lot of intelligence to get what the teachers are talking about.\"";
+ @npcname$ = "";
+ close;
+}
diff --git a/npc/002-1/sarah.txt b/npc/002-1/sarah.txt
new file mode 100755
index 00000000..e703194f
--- /dev/null
+++ b/npc/002-1/sarah.txt
@@ -0,0 +1,75 @@
+002-1,93,43,0 script Sarah NPC106,{
+ if (QL_SARAH >= 2) goto L_Done;
+ if (QL_SARAH == 1) goto L_Progress;
+
+ mes "[Sarah]";
+ mes "\"Boy, am I hungry or what!\"";
+ next;
+
+ @temp = rand(2);
+ if(@temp == 1) goto L_Opening1;
+ goto L_Opening0;
+
+L_Opening0:
+ mes "\"Cherry Cake is the best!\"";
+ next;
+ goto L_Ask;
+
+L_Opening1:
+ mes "\"Mmm, Cherry Cake... I love it!\"";
+ next;
+ goto L_Ask;
+
+L_Ask:
+ mes "\"Can you bring me a piece of Cherry Cake? Pretty please?\"";
+ menu
+ "Yes.", L_Req0,
+ "No.", L_close;
+
+L_Req0:
+ mes "[Sarah]";
+ mes "\"Yippee! Bring me a piece of Cherry Cake, and I'll give you a nice hat!\"";
+ next;
+ QL_SARAH = 1;
+ mes "[Sarah]";
+ mes "\"Please bring it to me!\"";
+ goto L_close;
+
+L_Progress:
+ if (countitem("CherryCake") < 1)
+ goto L_NotEnough;
+ mes "[Sarah]";
+ mes "\"Whee!\"";
+ next;
+ mes "You brought me Cherry Cake! Here is your new hat, as promised.\"";
+ getinventorylist;
+ if ((@inventorylist_count - (countitem("CherryCake") == 1)) > 99) goto L_TooMany;
+ delitem "CherryCake", 1;
+ getitem "SerfHat", 1;
+ QL_SARAH = 2;
+ close2;
+ emotion EMOTE_TONGUE, strcharinfo(0);
+ end;
+
+L_NotEnough:
+ mes "[Sarah]";
+ mes "\"Oh, I'm starving! Please bring me Cherry Cake!\"";
+ goto L_close;
+
+L_Done:
+ mes "[Sarah]";
+ mes "\"It was so tasty, I can't eat anything more... Thank you!\"";
+ close2;
+ emotion EMOTE_TONGUE, strcharinfo(0);
+ end;
+
+L_close:
+ @temp = 0;
+ close;
+
+L_TooMany:
+ next;
+ mes "[Sarah]";
+ mes "\"You don't have room for my reward. I'll wait until you do.\"";
+ goto L_close;
+}
diff --git a/npc/002-1/soul-menhir.txt b/npc/002-1/soul-menhir.txt
new file mode 100755
index 00000000..5506a97f
--- /dev/null
+++ b/npc/002-1/soul-menhir.txt
@@ -0,0 +1,15 @@
+
+002-1,58,60,0 script Soul Menhir#tulimshar NPC345,{
+ @map$ = "001-1";
+ setarray @Xs, 57, 58, 59, 57, 59, 57, 59;
+ setarray @Ys, 59, 59, 59, 60, 60, 61, 61;
+ @x = 0;
+ @y = 0;
+ callfunc "SoulMenhir";
+ @map$ = "";
+ cleararray @Xs[0], 0, 7;
+ cleararray @Ys[0], 0, 7;
+ @x = 0;
+ @y = 0;
+ close;
+}
diff --git a/npc/002-1/stewen.txt b/npc/002-1/stewen.txt
new file mode 100755
index 00000000..b2d216f3
--- /dev/null
+++ b/npc/002-1/stewen.txt
@@ -0,0 +1,22 @@
+002-1,116,93,0 script Stewen NPC123,{
+ if (QL_MINEALL == 4) goto L_TMW_Quest_Received;
+ if (QL_MINEALL == 3) goto L_TMW_Quest;
+
+ mes "[Stewen]";
+ mes "\"I'm keeping a watchful eye on the monsters to the east so they don't threaten Tulimshar's citizens. They are pretty strong.\"";
+ goto L_close;
+
+L_TMW_Quest:
+ QL_MINEALL = 4;
+ mes "[Stewen]";
+ mes "\"I don't get a break?! Lieutenant Dausen needs to ask the Wizard's Council for more help out here. Either that or give me a raise! Oh well. Thanks for letting me know.\"";
+ goto L_close;
+
+L_TMW_Quest_Received:
+ mes "[Stewen]";
+ mes "\"Thanks again for letting me know Lieutenant Dausen isn't letting me take a break. Once I get out of here, I'll let him know I want a raise!\"";
+ goto L_close;
+
+L_close:
+ close;
+}
diff --git a/npc/002-1/traveler.txt b/npc/002-1/traveler.txt
new file mode 100755
index 00000000..61226caa
--- /dev/null
+++ b/npc/002-1/traveler.txt
@@ -0,0 +1,7 @@
+
+002-1,60,41,0 script Nina the Traveler NPC103,{
+ @npcname$ = "Nina";
+ @NpcTravelBit = $@tulimshar_bit;
+ callfunc "Traveler";
+ end;
+}
generated by cgit v1.2.3-60-g2f50 (git 2.42.0) at 2024-06-23 19:38:15 +0000