initial commit for magic v3

Fix Druid Tree and add hug to TMW

1 files changed, 54 insertions, 0 deletions

diff --git a/world/map/npc/magic/level2-summon-snakes.txt b/world/map/npc/magic/level2-summon-snakes.txt
new file mode 100644
index 00000000..2bce0f96
--- /dev/null
+++ b/world/map/npc/magic/level2-summon-snakes.txt
@@ -0,0 +1,54 @@
+-|script|summon-snakes|32767
+{
+    end;
+
+OnCast:
+    callfunc "magic_checks"; if(@failed) end; // << I wish we had functions that could return >>
+    if (Sp < 40) end;
+    if (getskilllv(SKILL_MAGIC) < .level) end;
+    if (getskilllv(.school) < .level) end;
+    if (countitem("DarkCrystal") < 1 || countitem("SnakeEgg") < 1) end;
+    if (OrumQuest <= 40) end;
+    delitem "DarkCrystal", 1;
+    delitem "SnakeEgg", 1;
+    set MAGIC_CAST_TICK, gettimetick(2) + 15; // set the new debuff
+    callfunc "adjust_spellpower";
+    set Sp, Sp - 40;
+    misceffect FX_MAGIC_DARKRED, strcharinfo(0);
+    misceffect FX_PENTAGRAM_BUILDUP, strcharinfo(0);
+    callfunc "magic_exp";
+    set .@puppet$, "#"+strnpcinfo(0)+"#"+BL_ID;
+    set .@puppet, puppet(getmap(), POS_X, POS_Y, .@puppet$, 127);
+    set .count, (@spellpower/300)+1, .@puppet;
+    set .master, BL_ID, .@puppet;
+    set .lifetime, @spellpower*80, .@puppet;
+    addnpctimer 4000-(@spellpower*9), .@puppet$+"::OnSummon";
+    addnpctimer 6000, .@puppet$+"::OnDestroy";
+    end;
+
+OnSummon:
+    specialeffect FX_PENTAGRAM_BURST;
+    set .@i, 0;
+    set .@x, getnpcx();
+    set .@y, getnpcy();
+    set .@map$, strnpcinfo(3);
+    callsub S_SummonAll;
+    end;
+
+OnDestroy:
+    destroy;
+
+S_SummonAll:
+    summon .@map$, rand(.@x-2,.@x+2), rand(.@y-2,.@y+2), .master, 1010, 2, .lifetime;
+    set .@i, .@i + 1;
+    if (.@i < .count) goto S_SummonAll;
+    return;
+
+OnInit:
+    set .school, SKILL_MAGIC_DARK;
+    set .invocation$, chr(MAGIC_SYMBOL) + "halhiss"; // used in npcs that refer to this spell
+    callfunc "magic_register2";
+    set .level, 2;
+    set .exp_gain, 3;
+    end;
+}