path: root/npc/functions/global_event_handler.txt

-	script	#GlobalHandler	NPC32767,{
    end;

OnPCLoginEvent:
    @login_event = 1;
    adddefaultskills();
    //callfunc "fixHeadStyles"; // convert headstyles
    ClearVariables(); // removes / converts old variables
    DisplayMOTD(); // send the motd to the client, if enabled
    TMWBirthday();
    // add more here
    vaultOnLogin();
    @login_event = 2;
    end;

OnPCLogoutEvent:
    GM = 0;
    vaultOnLogout();
    end;

OnPCKillEvent:
    elanore_decrease_exp(); // decrease heal exp for doing bad things
    end;

OnNPCKillEvent:
OnMobKillEvent:
    MobPoints();
    end;

OnPCDieEvent:
    @necromancer = 0;
    callfunc "SpawnGhost";
    set @killerrid, 0; // reset killer rid
    end;

// Cleanup: Retain chat logs for 24~48 hours
// Cleanup: Retain item logs for 2 months
OnClock0501:
    query_sql("DELETE FROM `picklog` WHERE `time` < '"+sqldate(0, -2)+"'");
    query_sql("DELETE FROM `zenylog` WHERE `time` < '"+sqldate(0, -2)+"'");
OnClock1701:
    if (gettime(GETTIME_DAYOFMONTH) > 1)
        query_sql("DELETE FROM `chatlog` WHERE `time` < '"+sqldate(-1)+"'");
    end;

OnInit:
    MOTD(); // set the MOTD array
    end;

OnDie:
    percentheal -100, -100;
    end;
}