path: root/npc/030-2/present_helper.txt

030-2,47,82,0	script	Jonathan	NPC328,{
    callfunc "XmasStates";

    if($@xmas_time)
        goto L_XmasMain;
    goto L_OffSeason;

L_OffSeason:
    mes "[Jonathan]";
    mes "\"Hello! Welcome to the reclamation department.\"";
    mes "\"Lucky all the presents stolen have been replaced. Save any you find. You never know what we will need to replace next year.\"";
    goto L_close;

L_XmasMain:
    mes "[Jonathan]";
    mes "\"Hello! Welcome to the reclamation department.\"";

    if(@xmas_helper_bit) goto L_Helping;

    mes "\"We are incredibly busy right now, monsters have stolen some of our presents.\"";
    mes "\"I must go inform Chief Warrick immediately.\"";
    goto L_close;

L_Helping:
    mes "\"Here we take back any presents stolen from us by those nasty creatures.\"";
    next;
    goto L_Main;

L_Main:
    mes "\"Did you find any presents you would like to return?\"";
    next;
    menu
        "No, I just wanted to say hello.",L_close,
        $@xmas_present_amount + " Purple present boxes.",L_Purple,
        $@xmas_present_amount + " Blue present boxes.",L_Blue,
        $@xmas_present_amount + " Green present boxes.",L_Green,
        $@xmas_present_amount + " Yellow present boxes.",L_Yellow,
        $@xmas_present_amount + " White present boxes.",L_White;

L_Purple:
    @karma_bonus = $@xmas_karma_bonus;
    @present_name$ = "PurplePresentBox";
    goto L_RewardIncrease;

L_Blue:
    @karma_bonus = $@xmas_karma_bonus;
    @present_name$ = "BluePresentBox";
    goto L_RewardIncrease;

L_Green:
    @karma_bonus = $@xmas_karma_bonus;
    @present_name$ = "GreenPresentBox";
    goto L_RewardIncrease;

L_Yellow:
    @karma_bonus = 2;
    @present_name$ = "YellowPresentBox";
    goto L_RewardIncrease;

L_White:
    @karma_bonus = 2;
    @present_name$ = "WhitePresentBox";
    goto L_RewardIncrease;

L_RewardIncrease:
    if ($@xmas_present_amount > countitem(@present_name$))
        goto L_NotEnough;
    mes "\"Oh, thank you!\"";
    delitem @present_name$, $@xmas_present_amount;
    callfunc "XmasNice";
    goto L_close;

L_NotEnough:
    mes "\"I am sorry, but you don't have enough presents to return.\"";
    goto L_Main;

L_close:
    mes "\"See You later!\"";
    @present_name$ = "";
    close;
}