path: root/npc/001-2/wizards.txt

// Tulimshar Wizards (The Mana World Doomsday Quest)
-	script	Magic Council	NPC32767,{
    explode .@n, strnpcinfo(0), "#";
    if   (.@n[1] == 9) mes "The arch wizard seems to be busy.";
    else if (.@n[1])   mes "The wizard seems to ignore you.";
    else               mes "Strangely, you feel nothing – as if its membrane is closed to you.";
    next;
    mes "Perhaps you should come back later.";
    close;

OnInit:
    .distance = 4;
    end;
}

// Quest giver
001-2,104,27,0	script	Arch-Wizard#9	NPC354,{
    function dd5Neutral;
    function dd5Intro;
    function dd5Words;
    function dd5Almost;
    function dd5Finish;

    if (BaseLevel < 100) dd5Neutral();

    switch (getq(Quest_Doomsday)) {
    case 0:
        dd5Intro(); break;
    case 1:
        dd5Words(); break;
    case 2:
        dd5Almost(); break;
    case 3:
        dd5Finish(); break;
    default:
        dd5Neutral(); break;
    }
    close;

// Not enough level
function dd5Neutral {
    mes l("The arch wizard seems to be busy.");
    next;
    mes l("Perhaps you should come back later.");
    close;
}

// Quest begin
function dd5Intro {
    mesn;
    mesq l("Ah, %s. A good thing you came here.", strcharinfo(0));
    next;
    // Pre-requisite: TMW Swamps OK
    if (getq(Quest_Reapercry) < 2) {
        mesn;
        mesq l("We have found a... disturbance, which we would like you to investigate, in Hurnscald's Crypt.");
        next;
        mesn;
        mesq l("I'm afraid that this is all I can tell you for now.");
        return;
    }
    // OK
    mesn;
    mesq l("I believe you have found the ruined Keshlam Swamps, didn't you?");
    next;
    mesn;
    mesq l("That place have an eerie energy to it. And you know, not many things can scare an arch wizard.");
    next;
    mesn;
    mesq l("Have you ever used a time traveler before?");
    askyesno();
    mes "";
    mesn;
    mesq l("What I feel from there is something which transcends time travel. Some power outside of the domain of time must be at play.");
    next;
    mesn;
    mesq l("We've dispatched a wizard team to investigate. And... Well, you must see it for yourself, you guess. Let's just say... Pocket dimension.");
    next;
    mesn;
    mesq l("We need someone strong to challenge something which we're not sure if it is our past, our present, our future, or even a parallel timeline for all we know. Are you up to this task?");
    mesc l("Accepting this quest will replay \"The Mana World: Doomsday\"."), 1;
    next;
    if (askyesno() == ASK_NO) {
        mes "";
        mesn;
        mesq l("I see. I should have sought someone more corageous, I guess. Please, stop wasting our time.");
        return;
    }
    mesn;
    mesq l("Great! There should be an engraving somewhere there. You should chant some ancient words our scholars have found.");
    setq Quest_Doomsday, 1;
    next;
    dd5Words();
    return;
}

// Quest reminder
function dd5Words {
    mesn;
    mesq l("Go to the engraving and recite the following:");
    mes b("Tutin Jande Liaise"); // In Jande Lustitiae (latin) [anagram]
    next;
    mesn;
    mesq l("It means \"Jande's Justice\". Jande is the Great Dragon of Earth.");
    next;
    mesn;
    mesq l("It seems to be in a time-lock, but we found a powerful entity which our wizards could not defeat. Try defeating it, and report back if you find out anything.");
    next;
    mesn;
    mesq l("...Also, if you don't know what a Great Dragon is, then please, go visit a library. We the wizard council of Tulimshar have more important things to do.");
    return;
}

// As a participant
function dd5Almost {
    mesn;
    mesq l("I can see horror in your eyes. I assume you fought whatever was there.");
    next;
    mesn;
    mesq l("Many of our wizards did and had the same scary expression in your eyes. But I did not ask you to fight, I asked you to win.");
    next;
    mesn;
    mesq l("So please, do not bother me until you have some sort of trophy to show off. I'll repeat again the words you need to recite at the engraving:");
    mes b("Tutin Jande Liaise"); // In Jande Lustitiae (latin) [anagram]
    return;
}

function dd5Finish {
    mesn;
    // Must be wearing the Savior Armor to finish this quest
    if (!isequipped(SaviorArmor)) {
        mesq l("Please do not bother me until you have some sort of trophy to show off.");
        return;
    } else {
        mesq l("Now, isn't this a fancy armor you're wearing...?");
        next;
    }
    mesn;
    mesq l("I can recognize it's made of Zealite. That is... the same material from which our Soul Menhirs are made.");
    next;
    mesn;
    mesq l("If that was our future, how grim it is! Likely, the Soul Menhirs were destroyed on that... reality.");
    next;
    mesn;
    mesq l("Keep the armor. I'll inform the other sages about this.");
    next;
    select
        l("Thanks!"),
        l("Actually, there was more...");
    mes "";
    mesn;
    mesq l("Oh right, I almost forgot your reward. Here, take this gold. Don't waste it all on candies. Now shoo, shoo, begone! You're disrupting me!");
    Zeny+=1000000; // One Million GP - FIXME
    setq Quest_Doomsday, 4;
    return;
}

OnInit:
    .distance = 4;
    end;
}


001-2,104,19,0	duplicate(Magic Council)	Desert Mana Seed#_M	NPC166
001-2,99,22,0	duplicate(Magic Council)	Wizard#1	NPC355
001-2,92,24,0	duplicate(Magic Council)	Wizard#2	NPC356
001-2,92,30,0	duplicate(Magic Council)	Wizard#3	NPC357
001-2,99,32,0	duplicate(Magic Council)	Wizard#4	NPC358
001-2,110,22,0	duplicate(Magic Council)	Wizard#5	NPC359
001-2,117,24,0	duplicate(Magic Council)	Wizard#6	NPC360
001-2,117,30,0	duplicate(Magic Council)	Wizard#7	NPC361
001-2,110,32,0	duplicate(Magic Council)	Wizard#8	NPC362
//001-2,104,27,0	duplicate(Magic Council)	Arch-Wizard#9	NPC354