1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
|
//===== Hercules Script ======================================
//= Script engine self-tests
//===== By: ==================================================
//= Haru
//===== Current Version: =====================================
//= 1.0
//===== Description: =========================================
//= Script to test operators and possibly other elements of
//= the script engine, useful for regression testing.
- script HerculesSelfTest -1,{
end;
OnCheck:
.@msg$ = getarg(0,"Unknown Error");
.@val = getarg(1,0);
.@ref = getarg(2,1);
if (.@val != .@ref) {
debugmes "Error: "+.@msg$+": '"+.@val+"' != '"+.@ref+"'";
//end;
}
return;
OnInit:
// Array subscript
setarray .@a, 3, 2, 1;
callsub(OnCheck, "Array subscript", .@a[2]);
// Increment and decrement operators ++, --
.@x = 1;
.@y = .@x++; // .@y = .@x; .@x = .@x + 1;
callsub(OnCheck, "Suffix increment ++", .@y);
callsub(OnCheck, "Suffix increment ++", .@x, 2);
.@x = 1;
.@y = .@x--; // .@y = .@x; .@x = .@x - 1;
callsub(OnCheck, "Suffix decrement --", .@y);
callsub(OnCheck, "Suffix decrement --", .@x, 0);
.@x = 0;
.@y = ++.@x; // .@x = .@x + 1; .@y = .@x;
callsub(OnCheck, "Prefix increment ++", .@y);
callsub(OnCheck, "Prefix increment ++", .@x);
.@x = 2;
.@y = --.@x; // .@x = .@x - 1; .@y = .@x;
callsub(OnCheck, "Prefix decrement --", .@y);
callsub(OnCheck, "Prefix decrement --", .@x);
// Order of [] and --/++
.@a[1] = 0;
.@a[1]++; // .@a[1] = .@a[1] + 1;
callsub(OnCheck, "Order of [] and ++", .@a[1]);
.@a[1] = 2;
.@a[1]--; // .@a[1] = .@a[1] - 1;
callsub(OnCheck, "Order of [] and --", .@a[1]);
// Unary operators -, !, ~
.@x = 1;
.@y = -.@x; // .@y = 0 - .@x;
callsub(OnCheck, "Unary operator -", .@y, -1);
.@x = 1;
.@y = !.@x; // if(.@x == 0) .@y = 1; else .@y = 0;
callsub(OnCheck, "Unary operator !", .@y, 0);
.@x = 0x00000001;
.@y = ~.@x; // One's complement of 0x00000001 is 0xfffffffe, which is -2
callsub(OnCheck, "Unary operator ~", .@y, -2);
// Associativity of unary operators -, !, ~
.@x = 1;
.@y = ~ ! .@x; // .@y = ~(!.@x);
callsub(OnCheck, "Associativity of unary ~ and !", .@y, -1);
.@x = 0;
.@y = - ! .@x; // .@y = -(!.@x);
callsub(OnCheck, "Associativity of unary - and !", .@y, -1);
.@x = 1;
.@y = ~ - .@x; // .@y = ~(-.@x);
callsub(OnCheck, "Associativity of unary ~ and -", .@y, 0);
.@x = 1;
.@y = - ~ .@x; // .@y = -(~.@x);
callsub(OnCheck, "Associativity of unary - and ~", .@y, 2);
// Order of unary -, !, ~ and prefix/suffix ++/--
.@x = 2;
.@y = - --.@x; // .@y = -(--.@x);
callsub(OnCheck, "Order of unary - and prefix --", .@y, -1);
callsub(OnCheck, "Order of unary - and prefix --", .@x);
.@x = 1;
.@y = - .@x--; // .@y = -(.@x--);
callsub(OnCheck, "Order of unary - and suffix --", .@y, -1);
callsub(OnCheck, "Order of unary - and suffix --", .@x, 0);
.@x = 0;
.@y = - ++.@x; // .@y = -(++.@x);
callsub(OnCheck, "Order of unary - and prefix ++", .@y, -1);
callsub(OnCheck, "Order of unary - and prefix ++", .@x);
.@x = 1;
.@y = - .@x++; // .@y = -(.@x++);
callsub(OnCheck, "Order of unary - and suffix ++", .@y, -1);
callsub(OnCheck, "Order of unary - and suffix ++", .@x, 2);
.@x = 1;
.@y = !--.@x; // .@y = !(--.@x);
callsub(OnCheck, "Order of unary ! and prefix --", .@y);
callsub(OnCheck, "Order of unary ! and prefix --", .@x, 0);
.@x = 1;
.@y = !.@x--; // .@y = !(.@x--);
callsub(OnCheck, "Order of unary ! and suffix --", .@y, 0);
callsub(OnCheck, "Order of unary ! and suffix --", .@x, 0);
.@x = 0;
.@y = !++.@x; // .@y = !(++.@x);
callsub(OnCheck, "Order of unary ! and prefix ++", .@y, 0);
callsub(OnCheck, "Order of unary ! and prefix ++", .@x);
.@x = 0;
.@y = !.@x++; // .@y = !(.@x++);
callsub(OnCheck, "Order of unary ! and suffix ++", .@y);
callsub(OnCheck, "Order of unary ! and suffix ++", .@x);
.@x = 2;
.@y = ~--.@x; // .@y = ~(--.@x);
callsub(OnCheck, "Order of unary ~ and prefix --", .@y, -2);
callsub(OnCheck, "Order of unary ~ and prefix --", .@x, 1);
.@x = 1;
.@y = ~.@x--; // .@y = ~(.@x--);
callsub(OnCheck, "Order of unary ~ and suffix --", .@y, -2);
callsub(OnCheck, "Order of unary ~ and suffix --", .@x, 0);
.@x = 0;
.@y = ~++.@x; // .@y = ~(++.@x);
callsub(OnCheck, "Order of unary ~ and prefix ++", .@y, -2);
callsub(OnCheck, "Order of unary ~ and prefix ++", .@x, 1);
.@x = 1;
.@y = ~.@x++; // .@y = ~(.@x++);
callsub(OnCheck, "Order of unary ~ and suffix ++", .@y, -2);
callsub(OnCheck, "Order of unary ~ and suffix ++", .@x, 2);
// Binary *, /, % operators
.@x = 2 * 3; // .@x = 6;
callsub(OnCheck, "Binary * operator", .@x, 6);
.@x = 7 / 2; // .@x = 3;
callsub(OnCheck, "Binary / operator", .@x, 3);
.@x = 7 % 2; // .@x = 1;
callsub(OnCheck, "Binary % operator", .@x, 1);
// Associativity of *, /, %
.@x = 8 * 3 / 2; // .@x = (8 * 3) / 2;
callsub(OnCheck, "Associativity of * and /", .@x, 12);
// Order of binary *%/ and unary !-~
.@x = 2 * ! 3; // .@x = 2 * (!3);
callsub(OnCheck, "Order of binary * and unary !", .@x, 0);
.@x = ~ 1 * 2; // .@x = (~1) * 2;
callsub(OnCheck, "Order of unary ~ and binary *", .@x, -4);
// Binary +, - operators
.@x = 1 + 3; // .@x = 4;
callsub(OnCheck, "Binary + operator", .@x, 4);
.@x = 1 - 3; // .@x = -2;
callsub(OnCheck, "Binary - operator", .@x, -2);
// Associativity of +,-
.@x = 0x7fffffff - 0x7ffffff0 + 1; // .@x = (0x7fffffff - 0x7ffffff0) + 1; (without overflow)
callsub(OnCheck, "Associativity of + and -", .@x, 16);
// Order of +, - and *, /, %
.@x = 1 + 3 * 2; // .@x = 1 + (3 * 2);
callsub(OnCheck, "Order of + and *", .@x, 7);
// << and >> operators
.@x = 1<<3; // .@x = 1*2*2*2;
callsub(OnCheck, "Left shift << operator", .@x, 8);
.@x = 12>>2; // .@x = 12/2/2;
callsub(OnCheck, "Right shift >> operator", .@x, 3);
// Associativity of << and >>
.@x = 0x40000000 >> 4 << 2; // .@x = (0x40000000 >> 4) << 2
callsub(OnCheck, "Associativity of >> and <<", .@x, 0x10000000);
// Order of <</>> and +/-
.@x = 4 << 2 + 1; // .@x = 4 << (2+1);
callsub(OnCheck, "Order of << and +", .@x, 32);
// <, <=, >, >= operators
.@x = (1 < 2); // true
.@y = (2 < 2); // false
callsub(OnCheck, "< operator", .@x);
callsub(OnCheck, "< operator", .@y, 0);
.@x = (1 <= 2); // true
.@y = (2 <= 2); // true
callsub(OnCheck, "<= operator", .@x);
callsub(OnCheck, "<= operator", .@y);
.@x = (2 > 1); // true
.@y = (2 > 2); // false
callsub(OnCheck, "> operator", .@x);
callsub(OnCheck, "> operator", .@y, 0);
.@x = (2 >= 1); // true
.@y = (2 >= 2); // true
callsub(OnCheck, ">= operator", .@x);
callsub(OnCheck, ">= operator", .@y);
// Associativity of <,<=,>,>=
.@x = 1 > 0 > 0; // (1 > 0) > 0 --> 1 > 0 --> true
callsub(OnCheck, "Associativity of > operators", .@x);
// Order of >>/<< and </<=/>/>=
.@x = 1 < 1 << 2; // .@x = 1 < (1<<2);
callsub(OnCheck, "Order of < and <<", .@x);
// ==, != operators
.@x = (0 == 0); // true
.@y = (1 == 0); // false
callsub(OnCheck, "== operator", .@x);
callsub(OnCheck, "== operator", .@y, 0);
.@x = (1 != 0); // true
.@y = (1 != 1); // false
callsub(OnCheck, "!= operator", .@x);
callsub(OnCheck, "!= operator", .@y, 0);
// Associativity of ==, !=
.@x = (1 == 0 == 0); // (1 == 0) == 0 --> 0 == 0 --> 1
.@y = (1 != 0 == 0); // (1 != 0) == 0 --> 1 == 0 --> 0
callsub(OnCheck, "Associativity of != and == operators", .@x);
callsub(OnCheck, "Associativity of != and == operators", .@y, 0);
// Order of </<=/>/>= and ==/!=
.@x = (1 == 2 > 1); // true
.@y = (1 < 2 == 1); // true
callsub(OnCheck, "Order of <,>,==", .@x);
callsub(OnCheck, "Order of <,>,==", .@y);
// Bitwise & operator
.@x = (7&4); // 0111 & 0100 --> 0100
.@y = (4&1); // 0100 & 0001 --> 0000
callsub(OnCheck, "Bitwise & operator", .@x, 4);
callsub(OnCheck, "Bitwise & operator", .@y, 0);
// Order of & and ==/!=
.@x = (4 == 7 & 4); // (4 == 7)&4
.@y = (1 & 3 != 1); // 1 & (3 != 1)
callsub(OnCheck, "Order of ==/!= and &", .@x, 0);
callsub(OnCheck, "Order of ==/!= and &", .@y);
// Bitwise ^ operator
.@x = (3^1); // 0011 ^ 0001 --> 0010
callsub(OnCheck, "Bitwise ^ operator", .@x, 2);
// Order of ^ and &
.@x = (0 & 2 ^ 2); // (0 & 2) ^ 2 --> (0000 & 0010) | 0010 --> 0000 ^ 0010 --> 0010
.@y = (2 ^ 2 & 0); // 2 ^ (2 & 0) --> 0010 | (0010 & 0000) --> 0010 ^ 0000 --> 0010
callsub(OnCheck, "Order of ^ and &", .@x, 2);
callsub(OnCheck, "Order of ^ and &", .@y, 2);
// Bitwise | operator
.@x = (3|4); // 0011 | 0100 --> 0111
.@y = (4|1); // 0100 | 0001 --> 0101
callsub(OnCheck, "Bitwise | operator", .@x, 7);
callsub(OnCheck, "Bitwise | operator", .@y, 5);
// Order of ^ and |
.@x = (2 ^ 2 | 2); // (2 ^ 1) | 4 --> (0010 ^ 0010) | 0010 --> 0000 | 0010 --> 0010
.@y = (2 | 2 ^ 2); // 4 | (1 ^ 2) --> 0010 | (0010 ^ 0010) --> 0010 | 0000 --> 0010
callsub(OnCheck, "Order of | and ^", .@x, 2);
callsub(OnCheck, "Order of | and ^", .@y, 2);
// Logical && operator
.@x = (1 && 1); // true
.@y = (0 && 1); // false
callsub(OnCheck, "Logical && operator", .@x);
callsub(OnCheck, "Logical && operator", .@y, 0);
// Associativity of && and short-circuit
.@x = 0;
.@y = (1 && 0 && (.@x = 1)); // should short circuit as false before evaluating the assignment
//FIXME callsub(OnCheck, "Short-circuit of &&", .@x, 0);
callsub(OnCheck, "Associativity of &&", .@y, 0);
// Order of bitwise | and logical &&
.@x = (1 && 0 | 4); // 1 && (0|4)
.@y = (4 | 0 && 1); // (4|0) && 1
callsub(OnCheck, "Order of && and |", .@x);
callsub(OnCheck, "Order of && and |", .@y);
// Logical || operator
.@x = (1 || 1); // true
.@y = (0 || 1); // true
callsub(OnCheck, "Logical || operator", .@x);
callsub(OnCheck, "Logical || operator", .@y);
// Associativity of || and short-circuit
.@x = 0;
.@y = (1 || 0 || (.@x = 1)); // should short circuit as true before evaluating the assignment
//FIXME callsub(OnCheck, "Short-circuit of ||", .@x, 0);
callsub(OnCheck, "Associativity of ||", .@y);
// Order of logical && and ||
.@x = (0 && 1 || 1); // (0 && 1) || 1
.@y = (1 || 1 && 0); // 1 || (1 && 0)
callsub(OnCheck, "Order of && and ||", .@x);
callsub(OnCheck, "Order of && and ||", .@y);
// Ternary conditional operator ?:
.@x = (1 ? 2 : 3); // 2
.@y = (0 ? 2 : 3); // 3
callsub(OnCheck, "Ternary conditional operator", .@x, 2);
callsub(OnCheck, "Ternary conditional operator", .@y, 3);
// Associativity of ?:
.@x = (1 ? 2 : 0 ? 3 : 4);
.@y = (1 ? 1 ? 2 : 3 : 5);
callsub(OnCheck, "Associativity of ?:", .@x, 2);
callsub(OnCheck, "Associativity of ?:", .@y, 2);
// Order of logical || and ternary ?:
.@x = (1 ? 0 : 0 || 1); // 1 ? 0 : (0 || 1) --> false
callsub(OnCheck, "Order of || and ?:", .@x, 0);
// Assignment operators
.@x = 1;
callsub(OnCheck, "Direct assignment operator =", .@x);
.@x += 7; // 1 + 7
callsub(OnCheck, "Assignment by sum +=", .@x, 8);
.@x -= 1; // 8 - 1
callsub(OnCheck, "Assignment by difference -=", .@x, 7);
.@x *= 2; // 7 * 2
callsub(OnCheck, "Assignment by product *=", .@x, 14);
.@x /= 2; // 14 / 2
callsub(OnCheck, "Assignment by quotient /=", .@x, 7);
.@x %= 4; // 7 % 4
callsub(OnCheck, "Assignment by remainder %=", .@x, 3);
.@x <<= 2; // 3 << 2
callsub(OnCheck, "Assignment by bitwise left shift <<=", .@x, 12);
.@x >>= 1; // 12 >> 1
callsub(OnCheck, "Assignment by bitwise right shift >>=", .@x, 6);
.@x &= 5; // 6 & 5 (0110 & 0101 --> 0100)
callsub(OnCheck, "Assignment by bitwise and &=", .@x, 4);
.@x ^= 5; // 4 ^ 5 (0100 ^ 0101 --> 0001)
callsub(OnCheck, "Assignment by bitwise xor ^=", .@x, 1);
.@x |= 2; // 1 | 2 (0001 | 0010 --> 0011)
callsub(OnCheck, "Assignment by bitwise or |=", .@x, 3);
// Associativity of assignment operators
.@x = 0; .@y = 0;
.@x = .@y = 1;
callsub(OnCheck, "1Associativity of =", .@x);
callsub(OnCheck, "2Associativity of =", .@y);
.@x = 0; .@y = 1;
.@x = .@y += 4;
callsub(OnCheck, "3Associativity of =", .@x, 5);
callsub(OnCheck, "4Associativity of =", .@y, 5);
.@x = 5; .@y = 3;
.@z = 8;
/*
* 0001b4 C_NAME setr
* 0001b8 C_ARG
* 0001b9 C_NAME .@x
* 0001bd C_REF
* 0001bd C_INT 16
* 0001bf C_MUL
* 0001c0 C_FUNC
* 0001c1 C_EOL
*/
/* FIXME
.@x *= (.@y += 1);
//set(.@x, .@x * set(.@y, .@y + 1));
//.@x = (.@x * (.@y = .@y + 1));
*/
/*
* 0001c2 C_NAME setr
* 0001c6 C_ARG
* 0001c7 C_NAME .@x
* 0001cb C_REF
* 0001cc C_NAME setr
* 0001d0 C_ARG
* 0001d1 C_NAME .@y
* 0001d5 C_REF
* 0001d5 C_INT 1
* 0001d7 C_ADD
* 0001d8 C_FUNC
* 0001d9 C_MUL
* 0001da C_FUNC
* 0001db C_EOL
*/
/*
* 0001c2 C_NAME setr
* 0001c6 C_ARG
* 0001c7 C_NAME .@x
* 0001cb C_REF
* 0001cc C_NAME setr
* 0001d0 C_ARG
* 0001d1 C_NAME .@y
* 0001d4 C_INT 2
* 0001d6 C_FUNC
* 0001d7 C_MUL
* 0001d8 C_FUNC
* 0001d9 C_EOL
*/
/*
callsub(OnCheck, "5Associativity of =", .@x, 20);
callsub(OnCheck, "6Associativity of =", .@y, 4);
*/
.@x = 0;
if (0)
if (1)
.@x = 2;
else
.@x = 3;
callsub(OnCheck, "Dangling else", .@x, 0);
debugmes "Script engine self-test [ PASSED ]";
}
// vim: set ft=ath :
|
