path: root/npc/re/guides/guides_moscovia.txt

//===== Hercules Script ======================================
//= Moscovia Guide
//===== By: ==================================================
//= L0ne_W0lf
//===== Current Version: =====================================
//= 1.2
//===== Description: =========================================
//= [Official Conversion]
//= Guide for the city of Moscovia.
//===== Additional Comments: =================================
//= 1.0 First version, Renewal guide.
//= 1.1 Optimized (a little bit). [Euphy]
//= 1.2 Navigation system update. [Euphy]
//============================================================

moscovia,161,76,3	script	Moscovia Guide#01mosc	4_F_RUSWOMAN1,{
	mes "[Moscovia Guide]";
	mes "A paradise on the sea,";
	mes "beautiful waves and warm sunshine.";
	mes "^8B4513Moscovia^000000 is waiting for you.";
	mes "I'm supporting to offer information about here.";
	mes "If you want to ask anything just feel free tell me.";
	F_Navi("[Moscovia Guide]");
	set .@str$,"Is there anything else I can do for you?";
	while (1) {
		next;
		switch(select("[ Kafra Employee ]:[ Palace ]:[ Chapel ]:[ Weapon Shop ]:[ Armor Shop ]:[ Tool Shop ]:[ Inn ]:[ Return to Alberta ]:Remove Marks from Mini-Map:Cancel")) {
		case 1:
			mes "[Moscovia Guide]";
			mes "The ^0000FFKafra Employee^000000 has";
			mes "been marked on your mini-map";
			mes "Check your mini-map.";
			mes "Do you need anything else?";
			viewpoint 1,223,191,0,0x0A82FF;
			break;
		case 2:
			mes "[Moscovia Guide]";
			mes "In the "+F_Navi("Palace","moscovia,255,140","^006400")+" you will find our Lord the Czar and other servants.";
			mes .@str$;
			viewpoint 1,255,140,1,0x0A82FF;
			break;
		case 3:
			mes "[Moscovia Guide]";
			mes "The "+F_Navi("Chapel","moscovia,253,179","^008080")+" is located here.";
			mes .@str$;
			viewpoint 1,253,179,2,0xAAFF00;
			break;
		case 4:
			mes "[Moscovia Guide]";
			mes "You can buy weapons from the best craftsmen in Moscovia if you go to the "+F_Navi("Weapon Shop","moscovia,186,191","^FF1493")+".";
			mes .@str$;
			viewpoint 1,186,191,3,0x008080;
			break;
		case 5:
			mes "[Moscovia Guide]";
			mes "You will find only the best gear at the Moscovia "+F_Navi("Armor Shop","moscovia,204,169","^8B4513")+".";
			mes .@str$;
			viewpoint 1,204,169,4,0xB200FF;
			break;
		case 6:
			mes "[Moscovia Guide]";
			mes "The "+F_Navi("Tool Shop","moscovia,221,176","^FF1493")+" is located just south from the center of town.";
			mes "You can find all sorts of things you need for your travels.";
			mes .@str$;
			viewpoint 1,221,176,5,0xFF1493;
			break;
		case 7:
			mes "[Moscovia Guide]";
			mes "The Inn "+F_Navi("Sticky Herb Tree","moscovia,227,206")+" is just north from the center of town.";
			mes "If you need to rest, there is no better place to stay.";
			mes .@str$;
			viewpoint 1,227,206,6,0x8B4513;
			break;
		case 8:
			mes "[Moscovia Guide]";
			mes "You can find the";
			mes F_Navi("Moscovia P.R. Officer","moscovia,166,53")+" at the docks if";
			mes "you want to return to Alberta.";
			viewpoint 1,166,53,7,0x00BFFF;
			break;
		case 9:
			mes "[Moscovia Guide]";
			mes "I'll remove all marks from your mini-map.";
			mes .@str$;
			viewpoint 2,1,1,0,0xFFFFFF;
			viewpoint 2,1,1,1,0xFFFFFF;
			viewpoint 2,1,1,2,0xFFFFFF;
			viewpoint 2,1,1,3,0xFFFFFF;
			viewpoint 2,1,1,4,0xFFFFFF;
			viewpoint 2,1,1,5,0xFFFFFF;
			viewpoint 2,1,1,6,0xFFFFFF;
			viewpoint 2,1,1,7,0xFFFFFF;
			break;
		case 10:
			mes "[Moscovia Guide]";
			mes "Enjoy your trip~!";
			close;
		}
	}
}
moscovia,226,191,4	duplicate(Moscovia Guide#01mosc)	Moscovia Guide#02mosc	4_F_RUSWOMAN1