path: root/npc/pre-re/guides/guides_izlude.txt

//================= Hercules Script =======================================
//=       _   _                     _
//=      | | | |                   | |
//=      | |_| | ___ _ __ ___ _   _| | ___  ___
//=      |  _  |/ _ \ '__/ __| | | | |/ _ \/ __|
//=      | | | |  __/ | | (__| |_| | |  __/\__ \
//=      \_| |_/\___|_|  \___|\__,_|_|\___||___/
//================= License ===============================================
//= This file is part of Hercules.
//= http://herc.ws - http://github.com/HerculesWS/Hercules
//=
//= Copyright (C) 2012-2015  Hercules Dev Team
//= Copyright (C)  Samuray22
//= Copyright (C)  erKURITA
//= Copyright (C)  MasterOfMuppets
//= Copyright (C)  Lupus
//= Copyright (C)  L0ne_W0lf
//= Copyright (C)  kobra_k88
//=
//= Hercules is free software: you can redistribute it and/or modify
//= it under the terms of the GNU General Public License as published by
//= the Free Software Foundation, either version 3 of the License, or
//= (at your option) any later version.
//=
//= This program is distributed in the hope that it will be useful,
//= but WITHOUT ANY WARRANTY; without even the implied warranty of
//= MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
//= GNU General Public License for more details.
//=
//= You should have received a copy of the GNU General Public License
//= along with this program.  If not, see <http://www.gnu.org/licenses/>.
//=========================================================================
//= Izlude Guides (Pre-Renewal)
//================= Description ===========================================
//= Guides for the City of Izlude
//================= Current Version =======================================
//= 1.5a
//=========================================================================

izlude,121,87,6	script	Guide#iz	8W_SOLDIER,{
	cutin "prt_soldier",2;
	mes "[Izlude Guide]";
	mes "Welcome to Izlude,";
	mes "Prontera's satellite city.";
	mes "If you need any guidance";
	mes "around Izlude, feel free";
	mes "to ask me at anytime.";
	.@loop1 = 1;
	while(.@loop1) {
		next;
		switch(select("City Guide:Remove Marks from Mini-Map:Notice.:Cancel")) {
		case 1:
			mes "[Izlude Guide]";
			mes "Please select";
			mes "a location from";
			mes "the following menu.";
			if (.@compass_check == 0) {
				mes "Would you like me";
				mes "to mark locations";
				mes "on your Mini-Map?";
				next;
				if (select("Yes:No") == 1) .@compass_check = 1;
			}
			.@loop2 = 1;
			while(.@loop2) {
				if (.@wait_button_chk == 0) .@wait_button_chk = 1;
				else next;

				switch(select("^FF0000Swordman Association^000000:Swordman Hall:Arena:Izlude Marina:Weapon Shop:Tool Shop:Cancel")) {
				case 1:
					mes "[Izlude Guide]";
					mes "The Swordman Association";
					mes "is located on an island that is";
					mes "in west Izlude. If you're thinking of changing jobs to Swordman,";
					mes "you should check it out.";
					if (.@compass_check)
						viewpoint 1,52,140,0,0xFF0000;
					break;
				case 2:
					mes "[Izlude Guide]";
					mes "The Swordman Hall";
					mes "is located in the eastern";
					mes "island connected to Izlude.";
					if (.@compass_check)
						viewpoint 1,214,130,1,0x00FF00;
					break;
				case 3:
					mes "[Izlude Guide]";
					mes "Izlude's famous";
					mes "Arena is located at the";
					mes "northern end of Izlude.";
					if (.@compass_check)
						viewpoint 1,128,225,2,0x00FF00;
					break;
				case 4:
					mes "[Izlude Guide]";
					mes "You can find the";
					mes "Marina in the northeast";
					mes "part of Izlude. There, you can";
					mes "ride a ship which will take you";
					mes "to Alberta or Byalan Island.";
					if (.@compass_check)
						viewpoint 1,200,180,3,0xFF0000;
					break;
				case 5:
					mes "[Izlude Guide]";
					mes "You can easily";
					mes "find the Weapon Shop";
					mes "in northwest Izlude.";
					if (.@compass_check)
						viewpoint 1,111,149,4,0xFF00FF;
					break;
				case 6:
					mes "[Izlude Guide]";
					mes "The Tool Shop shouldn't";
					mes "be too hard to find in the";
					mes "northeast part of Izlude.";
					if (.@compass_check)
						viewpoint 1,148,148,5,0xFF00FF;
					break;
				case 7:
					mes "[Izlude Guide]";
					mes "Please ask me to ''Remove";
					mes "Marks from Mini-Map'' if you";
					mes "no longer wish to have the";
					mes "location marks displayed";
					mes "on your Mini-Map.";
					.@loop2 = 0;
					break;
				}
			}
			break;
		case 2:
			viewpoint 2,237,41,0,0x00FF00;
			viewpoint 2,237,41,1,0x0000FF;
			viewpoint 2,46,345,2,0x00FF00;
			viewpoint 2,175,220,3,0xFF0000;
			viewpoint 2,134,221,4,0xFF0000;
			viewpoint 2,204,214,5,0xFF0000;
			.@compass_check = 0;
			break;
		case 3:
			mes "[Izlude Guide]";
			mes "Advances in sorcery and";
			mes "technology have allowed";
			mes "us to update our information";
			mes "system, enabling up to mark";
			mes "locations on your Mini-Map";
			mes "for easier navigation.";
			next;
			mes "[Izlude Guide]";
			mes "Your Mini-Map is located";
			mes "in the upper right corner";
			mes "of the screen. If you can't";
			mes "see it, press the Ctrl + Tab";
			mes "keys or click the ''Map'' button in your Basic Info Window.";
			next;
			mes "[Izlude Guide]";
			mes "On your Mini-Map,";
			mes "click on the ''+'' and ''-''";
			mes "symbols to zoom in and";
			mes "our of your Mini-Map. We";
			mes "hope you enjoy your travels";
			mes "here in the city of Izlude.";
			break;
		case 4:
			mes "[Izlude Guide]";
			mes "Okay then, feel";
			mes "free to come to me";
			mes "if you ever feel lost";
			mes "around Izlude, alright?";
			close2;
			.@loop1 = 0;
			break;
		}
	}
	cutin "prt_soldier",255;
	end;
}