path: root/npc/pre-re/guides/guides_alberta.txt

//===== Hercules Script ======================================
//= Alberta Guides
//===== By: ==================================================
//= kobra_k88; L0ne_W0lf
//===== Current Version: =====================================
//= 1.5a
//===== Description: =========================================
//= [Official Conversion]
//= Guides for the city of Alberta
//===== Additional Comments: =================================
//= Fully working
//= 1.1 Fixed Armory coords, thanks to Freya team
//= 1.2 Optimized, updated common guide names [Lupus]
//= 1.3 Updated the guide according to how it is on iRO, thanks [MasterOfMuppets]
//=     to Muad_Dib
//= 1.4 Fitted the many lines into 1 or 2, and corrected some typos [erKURITA]
//= 1.5 Rescripted to official 10.3 standards. [L0ne_W0lf]
//= 1.5 Fixed some errors with the loop[Samuray22]
//	-Thanks to $ephiroth.
//============================================================

alberta,23,238,4	script	Guide#alb::AlbGuide	8W_SOLDIER,{
	cutin "prt_soldier",2;
	mes "[Alberta Guide]";
	mes "Welcome to Alberta,";
	mes "the Port City. Feel free";
	mes "to ask me if you're having";
	mes "trouble finding anything in";
	mes "town, or if you just need";
	mes "guidance around the city.";
	.@loop1 = 1;
	while (.@loop1) {
		next;
		switch(select("City Guide:Remove Marks from Mini-Map:Notice:Cancel")) {
		case 1:
			mes "[Alberta Guide]";
			mes "Please select";
			mes "a location from";
			mes "the following menu.";
			if (.@compass_check == 0) {
				mes "Would you like me";
				mes "to mark locations";
				mes "on your Mini-Map?";
				next;
				if (select("Yes:No") == 1) .@compass_check = 1;
			}
			.@loop2 = 1;
			while (.@loop2) {
				if (.@wait_button_chk == 0) .@wait_button_chk = 1;
				else next;

				switch(select("^FF0000Merchant Guild^000000:Weapon Shop:Tool Shop:Inn:Forge:Cancel")) {
				case 1:
					mes "[Alberta Guide]";
					mes "The Merchant Guild";
					mes "handles Job Changes";
					mes "to the Merchant Class,";
					mes "and is located in the";
					mes "southwest corner";
					mes "of Alberta.";
					if (.@compass_check)
						viewpoint 1,33,41,2,0xFF0000;
					break;
				case 2:
					mes "[Alberta Guide]";
					mes "The Weapon Shop";
					mes "can be found in the";
					mes "southern end of Alberta.";
					if (.@compass_check)
						viewpoint 1,117,37,3,0xFF00FF;
					break;
				case 3:
					mes "[Alberta Guide]";
					mes "The Tool Shop";
					mes "is kind of close";
					mes "to the center of";
					mes "Alberta. It shouldn't";
					mes "be too hard to find.";
					if (.@compass_check)
						viewpoint 1,98,154,4,0xFF00FF;
					break;
				case 4:
					mes "[Alberta Guide]";
					mes "There's an Inn";
					mes "at the northern";
					mes "end of Alberta";
					mes "where you can rest.";
					if (.@compass_check)
						viewpoint 1,65,233,5,0xFF00FF;
					break;
				case 5:
					mes "[Alberta Guide]";
					mes "The Forge in Alberta";
					mes "is in the same building";
					mes "as the Merchant Guild.";
					mes "It's to the southwest.";
					if (.@compass_check)
						viewpoint 1,35,41,6,0xFF00FF;
					break;
				case 6:
					mes "[Alberta Guide]";
					mes "Please ask me to ''Remove";
					mes "Marks from Mini-Map'' if you";
					mes "no longer wish to have the";
					mes "location marks displayed";
					mes "on your Mini-Map.";
					.@loop2 = 0;
				}
			}
			break;
		case 2:
			viewpoint 2,237,41,2,0xFF0000;
			viewpoint 2,237,41,3,0xFF00FF;
			viewpoint 2,46,345,4,0xFF00FF;
			viewpoint 2,175,220,5,0xFF00FF;
			viewpoint 2,175,220,6,0xFF00FF;
			.@compass_check = 0;
			break;
		case 3:
			mes "[Alberta Guide]";
			mes "Advances in sorcery and";
			mes "technology have allowed";
			mes "us to update our information";
			mes "system, enabling up to mark";
			mes "locations on your Mini-Map";
			mes "for easier navigation.";
			next;
			mes "[Alberta Guide]";
			mes "Your Mini-Map is located";
			mes "in the upper right corner";
			mes "of the screen. If you can't";
			mes "see it, press the Ctrl + Tab";
			mes "keys or click the ''Map'' button in your Basic Info Window.";
			next;
			mes "[Alberta Guide]";
			mes "On your Mini-Map,";
			mes "click on the ''+'' and ''-''";
			mes "symbols to zoom in and";
			mes "our of your Mini-Map. We";
			mes "hope you enjoy your travels";
			mes "here in the city of Alberta.";
			break;
		case 4:
			mes "[Alberta Guide]";
			mes "Be safe when you";
			mes "travel and don't hesitate";
			mes "to ask me if you have any";
			mes "questions about Alberta.";
			close2;
			.@loop1 = 0;
		}
	}
	cutin "prt_soldier",255;
	end;
}

alberta,120,60,3	duplicate(AlbGuide)	Guide#2alb	8W_SOLDIER