path: root/npc/other/gympass.txt

//===== eAthena Script ======================================= 
//= Gym Pass Cash Item NPC
//===== By: ================================================== 
//= Kisuka
//===== Current Version: ===================================== 
//= v1.1
//===== Compatible With: ===================================== 
//= eAthena SVN
//===== Description: ========================================= 
//= Exchange Gym Passes to learn "Enlarge Weight Limit"
//= iRO NPC situated in Payon beside Kafra Shop.
//===== Additional Comments: ================================= 
//= 1.0 First version [L0ne_W0lf]
//= 1.1 Fixed the NPC saying you "00" [L0ne_W0lf]
//============================================================ 

payon,173,141,4	script	Ripped Cabus#GymPass	899,{
	mes "[Ripped]";
	mes "Hey, there. People aren't";
	mes "as physically active as they";
	mes "used to be. Even if you fight";
	mes "for a living, your body might";
	mes "be weak and flabby in some";
	mes "areas. Know what I mean?";
	next;
	mes "[Ripped]";
	mes "Hey, train with me, and I can";
	mes "guarantee that you'll be able";
	mes "to lift and carry more of your";
	mes "stuff. Just gimme your";
	mes "^FF0000Gym Pass^000000 each time,";
	mes "and we'll be good to go.";
	next;
	mes "[Ripped]";
	mes "But don't get too excited:";
	mes "no matter how much training";
	mes "I take you through, you can";
	mes "overdo it. You ever hear of";
	mes "anyone that got too buff?";
	mes "That's cuz they're dead. See?";
	next;
	mes "[Ripped]";
	mes "I'd say that it'd be safe";
	mes "for you to seriously train";
	mes "with me and increase your";
	mes "item carrying capacity ^FF000010 times^000000.";
	mes "So... Are you ready to sweat?";
	next;
	switch(select("Yes:No:Um, my workouts wore off.")) {
	case 1:
		if (countitem(7776) == 0) {
			mes "[Ripped]";
			mes "Dude, what'd I tell you?";
			mes "You gotta bring me your";
			mes "^FF0000Gym Pass^000000 if you wanna";
			mes "work out, and build up your";
			mes "item carrying muscles.";
			close;
		}
		else if (getskilllv(681) >= 10) {
			mes "[Ripped]";
			mes "Dude, I don't think we can";
			mes "build up your item carrying";
			mes "muscles anymore than that.";
			mes "It's too dangerous for your";
			mes "body if we even tried! C'mon,";
			mes "I told you about the limits.";
			close;
		}
		else {
			mes "[Ripped]";
			mes "Oh, awesome, I see you";
			mes "brought your Gym Pass.";
			mes "Alright, just do what I do,";
			mes "and try to feel the burn.";
			mes "Ready? Let's do this.";
			next;
			specialeffect2 79;
			next;
			specialeffect2 372;
			next;
			specialeffect2 10;
			next;
			specialeffect2 62;
			next;
			skill 681,getskilllv(681)+1,0;
			delitem 7776,1;
			set gympassmemory,gympassmemory+1;
			mes "[Ripped]";
			mes "There, you should be able";
			mes "to carry more stuff with you.";
			mes "Let's see, we can increase";
			mes "your item carrying capacity";
			mes "^FF00000" + (10-getskilllv(681)) + "^000000 more times if we continue";
			mes "training together like this.";
			close;
		}
	case 2:
		mes "[Ripped]";
		mes "Aw, that's too bad.";
		mes "Well, come back if you";
		mes "change your mind. Tell";
		mes "your friends about me:";
		mes "if they're flabby, I'll help";
		mes "get them in shape.";
		close;
	case 3:
		if (getskilllv(681) == 0) {
			mes "[Ripped]";
			mes "Uhh...";
			mes "We didn't work out";
			mes "together before.";
			mes "I'm sure about that.";
			close;
		}
		else {
			mes "[Ripped]";
			mes "What happened?";
			mes "You let your item carrying";
			mes "muscles just atrophy? Lucky";
			mes "for you, there's such a thing";
			mes "as muscle memory. It's won't take";
			mes "as long to build 'em back up...";
			next;
			specialeffect2 79;
			next;
			specialeffect2 372;
			next;
			specialeffect2 10;
			next;
			specialeffect2 62;
			next;
			skill 681,gympassmemory,0;
			mes "[Ripped]";
			mes "How about that?";
			mes "Your item carrying";
			mes "muscles grew back,";
			mes "just like that! Try not to";
			mes "wimp out again, okay?";
			close;
		}
	}
}