path: root/npc/merchants/inn.txt

//===== eAthena Script ======================================= 
//= Inn Npcs
//===== By: ================================================== 
//= Darkchild (1.1)
//= Playtester (1.2)
//===== Current Version: ===================================== 
//= 1.6
//===== Compatible With: ===================================== 
//= eAthena 1.0+
//===== Description: ========================================= 
//= Inn Npcs, Save and Heal
//============================================================
//= variables:
//= arg0 - name of npc
//= arg1 - name of the inn
//= arg2 - map to save at
//= arg3, arg4 - x and y cord. to save at
//= @cost - cost of renting a room
//===== Additional Comments: ================================= 
//= 1.1 Blind Effect By Kobra_k88 (Taken from his old script)
//= I added it to all of them though [Darkchild]
//= 1.1a Minor bug fixes and optimizations. Switched from @variables 
//= to arguments.[kobra_k88]
//= 1.2 Rewrote inn script [Playtester]
//= 1.3 Added (finally) Rachel Inn Maid. Official warp
//=	  and save points[erKURITA]
//= 1.4 Added Hugel inn [erKurita]
//= 1.5 Added "end;" after warping the player. [L0ne_W0lf]
//=	- Small corrections to the prontera Inns.
//=	- Removed the Cancel dialog.
//= 1.6 More fixed, changed progression of "Rest"ing.
//=	- Corrected Morroc NPCs. [L0ne_W0lf]
//============================================================ 


//======================== Prontera ===================================
// West Side Inn -------------------
prt_in,244,135,2	script	Inn Employee::Sammy	53,{

	callfunc "F_InnMaid","[Employee Sammy]","Nenkaras","prt_in",238,130;
	warp "prt_in",247,104; end;
}
// East Side Inn ------------------
prt_in,61,141,2	script	Inn Employee::Ahlma#01	53,{

	callfunc "F_InnMaid","[Emplyee Ahlma]","Nenkaras","prt_in",64,136;
	warp "prt_in",64,136; end;
}

//======================== Alberta ====================================
// North --------------------------
alberta_in,32,142,5	script	Inn Maid::Moira	53,{

	callfunc "F_InnMaid","[Moira]","North Inn","alberta_in",26,138;
	warp "alberta_in",18,188; end;
}
// South -----------------------------
alberta_in,55,142,8	script	Inn Maid::Tina	53,{

	callfunc "F_InnMaid","[Tina]","South Inn","alberta_in",60,140;
	warp "alberta_in",68,188; end;
}

//====================== Geffen ======================================
geffen_in,70,64,5	script	Inn Maid::Betty	53,{

	callfunc "F_InnMaid","[Betty]","Geffen Inn","geffen_in",74,60;
	warp "geffen_in",106,106; end;
}

//======================= Payon ======================================
payon_in01,131,62,5	script	Inn Maid::SunHee	53,{

	callfunc "F_InnMaid","[Sun Hee]","Payon Inn","payon_in01",132,56;
	warp "payon_in01",140,15; end;
}

//======================== Morocc ====================================
// North East --------------------------
morocc_in,147,141,3	script	Inn Employee::Hasna	53,{

	callfunc "F_InnMaid","[Employee Hasna]","Morroc Inn","morocc_in",142,140;
	warp "morocc_in",173,135; end;
}
// South --------------------------------
morocc_in,80,100,5	script	Inn Employee::Manar	53,{

	callfunc "F_InnMaid","[Employee Manar]","Morroc Inn","morocc_in",78,95;
	warp "morocc_in",79,123; end;
}

//======================== Rachel ====================================
ra_in01,376,69,4	script	Inn Keeper	931,{

	callfunc "F_InnMaid","[Annie]","Rachel Inn","ra_in01",375,58;
	warp "ra_in01",384,128; end;
}

//======================== Hugel ====================================
hu_in01,246,107,3	script	Inn Maid::Receptionist	53,{

	callfunc "F_InnMaid","[Receptionist]","Hugel Inn","hu_in01",263,95;
	warp "hu_in01",267,5; end;
}

//======================= Inn Function ==============================
function	script	F_InnMaid	{
	mes getarg(0);
	mes "Welcome to";
	mes getarg(1) + ".";
	mes "How may I help you?";
	next;
	menu "Save",Msave, "Take a Rest -> 5000 zeny",Mrent, "Cancel",Mend;

	Msave:
		mes getarg(0);
		mes "Your respawn point";
		mes "has been saved.";
		mes "Thank you,";
		mes "please come again.";
		savepoint getarg(2),getarg(3),getarg(4);
		close;
	Mrent:
		mes getarg(0);
		if(Zeny < 5000){
			mes "I'm sorry, but the service charge";
			mes "is 5,000 zeny. Please make sure";
			mes "that you have enough money to check";
			mes "in next time, okay?";
			close;
		}
		mes "Thank you.";
		mes "I hope you";
		mes "enjoy your rest~";
		close2;
		set Zeny,Zeny - 5000;
		percentheal 100,100;
		return;

	Mend:
		close;
}