//===== eAthena Script =======================================
//= Custom Kiel Dungeon Warper
//===== By: ==================================================
//= Lupus
//===== Current Version: =====================================
//= 1.0
//===== Compatible With: =====================================
//= eAthena 1.0
//===== Description: =========================================
//= I't custom 8) But you have to pay every time u enter
//===== Additional Comments: =================================
//=
//============================================================
prontera.gat,157,168,2 script Kiel Capry 68,{
mes "[Kiel Capry]";
mes callfunc("F_Hi");
mes "Help us! Everybody's evacuated! There's an accident in my father's University...";
if(rand(2))close;
specialeffect 417;
next;
emotion e_wah;
mes "[Kiel Capry]";
mes "My father, ^FF0000Kiel Carlo^000000 is waiting for help in the broken elevator.";
if(rand(2))close;
next;
mes "[Kiel Capry]";
mes "What? Our home is located in the middle of ^FF0000Yuno field 08^000000...";
close;
}
kh_school.gat,119,146,3 script Kiel Carlo 748,{
mes "[Kiel Carlo]";
mes callfunc("F_Hi");
mes "We have evacuated all the students!";
mes "What? Are you going to jump in the lift tunnel, just in hands of the gone bad robots?";
mes "Well... we nedd money. Will you pay 10.000z?";
next;
emotion e_hmm;
menu "Yep.",M_GO, "No way!",-;
mes "[Kiel Carlo]";
mes "Well... "+callfunc("F_Bye");
close;
M_GO:
mes "[Kiel Carlo]";
mes "I never let you go if you don't meet these conditions:";
mes "1. You have to be 70 Base Level or upper.";
mes "2. You have to donate 10.000 zeny.";
next;
if(BaseLevel<70 || Zeny<10000){
mes "[Kiel Carlo]";
mes "Alas... I can't let you in.";
emotion e_sry;
close;
}
set Zeny,Zeny-10000;
warp "kh_kiehl02.gat",rand(46,53),rand(9,12);
end;
}
kh_kiehl02.gat,49,5,0 warp warpk06 1,1,kh_school.gat,119,146
