path: root/world/map/npc/magic/level2-summon-spiky-mushroom.txt

-|script|spikymushroom|32767
{
    end;

OnCast:
    callfunc "magic_checks"; if(@failed) end; // << I wish we had functions that could return >>
    if (Sp < 33) end;
    if (getskilllv(SKILL_MAGIC) < .level) end;
    if (getskilllv(.school) < .level) end;
    if (countitem("HardSpike") < 1 || countitem("Root") < 1) end;
    delitem "HardSpike", 1;
    delitem "Root", 1;
    set MAGIC_CAST_TICK, gettimetick(2) + 20; // set the new debuff
    callfunc "adjust_spellpower";
    set Sp, Sp - 33;
    misceffect FX_MAGIC_BLUE, strcharinfo(0);
    misceffect FX_PENTAGRAM_BUILDUP, strcharinfo(0);
    callfunc "magic_exp";
    set .@puppet$, "#"+strnpcinfo(0)+"#"+BL_ID;
    set .@puppet, puppet(getmap(), POS_X, POS_Y, .@puppet$, 127);
    set .count, (@spellpower/120)+1, .@puppet;
    set .master, BL_ID, .@puppet;
    set .lifetime, @spellpower*400, .@puppet;
    addnpctimer 5000-(@spellpower*9), .@puppet$+"::OnSummon";
    addnpctimer 6000, .@puppet$+"::OnDestroy";
    end;

OnSummon:
    specialeffect FX_PENTAGRAM_BURST;
    set .@i, 0;
    set .@x, getnpcx();
    set .@y, getnpcy();
    set .@map$, strnpcinfo(3);
    callsub S_SummonAll;
    end;

OnDestroy:
    destroy;

S_SummonAll:
    summon .@map$, rand(.@x-2,.@x+2), rand(.@y-2,.@y+2), .master, 1019, 2, .lifetime;
    set .@i, .@i + 1;
    if (.@i < .count) goto S_SummonAll;
    return;

OnInit:
    set .school, SKILL_MAGIC_ASTRAL;
    set .invocation$, chr(MAGIC_SYMBOL) + "kalrenk"; // used in npcs that refer to this spell
    callfunc "magic_register2";
    set .level, 2;
    set .exp_gain, 1;
    end;
}