path: root/world/map/npc/001-1/bleacher.txt

//

001-1.gat,27,53,0|script|Candide|156,{
    mes "[Candide]";
    mes "\"I've figured out how that volcanic ash bleaches cloth.";
    mes "I could do it for you, but I'll need three piles of ash and 5,000 GP for supplies per item.\"";
    next;

    if (countitem("PileOfAsh") < 3) goto L_no_ash;

    if (Zeny < 5000) goto L_no_money;

    menu
        "I'd like to bleach something", -,
        "No thanks", L_Close;

L_bleach_menu:
    mes "[Candide]";
    mes "\"What would you like to bleach?\"";
    next;

    menu
        "Cotton shirt", L_cottonshirt,
        "V-Neck sweater", L_vneck,
        "Turtleneck sweater", L_tneck,
        "Cotton shorts", L_shorts,
        "Cotton trousers", L_trousers,
        "Cotton skirt", L_skirt,
        "Miniskirt", L_miniskirt,
        "Tank top ", L_tanktop,
        "Short tank top", L_tanktop_short,
        "Silk robe", L_robe,
        "Cotton headband", L_cotton_headband,
        "Desert hat", L_desert_hat,
        "Cotton boots", L_cotton_boots,
        "Cotton gloves", L_cotton_gloves,
        "Rabbit ears", L_rabbit_ears,
        "Wizard hat", L_wizard_hat,
        "Bowler hat", L_bowler_hat,
        "Red lined sorcerer robe", L_red_lined_sorcerer_robe,
        "Green lined sorcerer robe", L_greenlinedsorcererrobe,
        "Dark blue lined sorcerer robe", L_darkbluelinedsorcererrobe,
        "Yellow lined sorcerer robe", L_yellowlinedsorcererrobe,
        "Light blue lined sorcerer robe", L_lightbluelinedsorcererrobe,
        "Pink lined sorcerer robe", L_pinklinedsorcererrobe,
        "Black lined sorcerer robe", L_blacklinedsorcererrobe,
        "Orange lined sorcerer robe", L_orangelinedsorcererrobe,
        "Purple lined sorcerer robe", L_purplelinedsorcererrobe,
        "Dark green lined sorcerer robe", L_darkgreenlinedsorcererrobe,
        "White lined sorcerer robe", L_whitelinedsorcererrobe,
        "Bowler hat (brown)", L_bowler_hat_brown,
        "Fine dress", L_fine_dress,
        "Cotton cloth", L_cottoncloth,
        "Nevermind", -;
    goto L_Close;

L_cottonshirt:
    set @normal, 1202;
    set @dyeBase, 2050;
    goto L_choose_color;

L_vneck:
    set @normal, 624;
    set @dyeBase, 2060;
    goto L_choose_color;

L_tneck:
    set @normal, 564;
    set @dyeBase, 2070;
    goto L_choose_color;

L_shorts:
    set @normal, 586;
    set @dyeBase, 2110;
    goto L_choose_color;

L_trousers:
    set @normal, 648;
    set @dyeBase, 2180;
    goto L_choose_color;

L_skirt:
    set @normal, 632;
    set @dyeBase, 2100;
    goto L_choose_color;

L_miniskirt:
    set @normal, 771;
    set @dyeBase, 2170;
    goto L_choose_color;

L_tanktop:
    set @normal, 688;
    set @dyeBase, 2090;
    goto L_choose_color;

L_tanktop_short:
    set @normal, 689;
    set @dyeBase, 2120;
    goto L_choose_color;

L_robe:
    set @normal, 720;
    set @dyeBase, 2080;
    goto L_choose_color;

L_cotton_headband:
    set @normal, 724;
    set @dyeBase, 2140;
    goto L_choose_color;

L_desert_hat:
    set @normal, 723;
    set @dyeBase, 2130;
    goto L_choose_color;

L_cotton_boots:
    set @normal, 735;
    set @dyeBase, 2150;
    goto L_choose_color;

L_cotton_gloves:
    set @normal, 741;
    set @dyeBase, 2160;
    goto L_choose_color;

L_rabbit_ears:
    set @normal, 1255;
    set @dyeBase, 2190;
    goto L_choose_color;

L_wizard_hat:
    set @normal, 4028;
    set @dyeBase, 2200;
    goto L_choose_color;

L_bowler_hat:
    set @normal, 4030;
    set @dyeBase, 2210;
    goto L_choose_color;

L_red_lined_sorcerer_robe:
    set @normal, 798;
    set @dyeBase, 2220;
    goto L_choose_color;

L_greenlinedsorcererrobe:
    set @normal, 5010;
    set @dyeBase, 5000;
    goto L_choose_color;

L_darkbluelinedsorcererrobe:
    set @normal, 5021;
    set @dyeBase, 5011;
    goto L_choose_color;

L_yellowlinedsorcererrobe:
    set @normal, 5032;
    set @dyeBase, 5022;
    goto L_choose_color;

L_lightbluelinedsorcererrobe:
    set @normal, 5043;
    set @dyeBase, 5033;
    goto L_choose_color;

L_pinklinedsorcererrobe:
    set @normal, 5054;
    set @dyeBase, 5044;
    goto L_choose_color;

L_blacklinedsorcererrobe:
    set @normal, 5065;
    set @dyeBase, 5055;
    goto L_choose_color;

L_orangelinedsorcererrobe:
    set @normal, 5076;
    set @dyeBase, 5066;
    goto L_choose_color;

L_purplelinedsorcererrobe:
    set @normal, 5087;
    set @dyeBase, 5077;
    goto L_choose_color;

L_darkgreenlinedsorcererrobe:
    set @normal, 5098;
    set @dyeBase, 5088;
    goto L_choose_color;

L_whitelinedsorcererrobe:
    set @normal, 5109;
    set @dyeBase, 5099;
    goto L_choose_color;

L_bowler_hat_brown:
    set @normal, 800;
    set @dyeBase, 2230;
    goto L_choose_color;

L_fine_dress:
    set @normal, 870;
    set @dyeBase, 2240;
    goto L_choose_color;

L_cottoncloth:
    set @normal, 660;
    set @dyeBase, 2250;
    goto L_choose_color;

L_choose_color:
    mes "[Candide]";
    mes "\"And the color?\"";
    next;

    menu
        "Red", -,
        "Green", -,
        "Dark Blue", -,
        "Yellow", -,
        "Light Blue", -,
        "Pink", -,
        "Black", -,
        "Orange", -,
        "Purple", -,
        "Dark Green", -;

    set @del, @dyeBase + @menu - 1;

    if (countitem(@del) == 0) goto L_no_item;

    if (countitem("PileOfAsh") < 3) goto L_no_ash;

    if (Zeny < 5000) goto L_no_money;

    delitem @del, 1;
    getitem @normal, 1;
    delitem "PileOfAsh", 3;
    set Zeny, Zeny - 5000;

L_again:
    mes "[Candide]";
    mes "\"Would you like to bleach something else?\"";
    next;

    menu
        "Yes", L_bleach_menu,
        "No", L_Close;

L_no_item:
    mes "[Candide]";
    mes "\"You don't have one of those.\"";
    next;

    goto L_again;

L_no_ash:
    mes "[Candide]";
    mes "\"You don't have enough ash for me to bleach anything.";
    mes "I need three piles.\"";
    goto L_Close;

L_no_money:
    mes "[Candide]";
    mes "\"You don't have enough gold for me to bleach anything.";
    mes "I need 5,000 GP for supplies.\"";
    goto L_Close;

L_Close:
    mes "[Candide]";
    mes "\"Come again.\"";
    set @normal, 0;
    set @dyeBase, 0;
    set @del, 0;
    close;
}