Change the Converter to use different folder names

And update everything to use it.

11 files changed, 1355 insertions, 0 deletions

diff --git a/npc/021-2/_import.txt b/npc/021-2/_import.txt
new file mode 100644
index 00000000..5e8ae6c6
--- /dev/null
+++ b/npc/021-2/_import.txt
@@ -0,0 +1,13 @@
+// Map 021-2: Tulimshar
+// This file is generated automatically. All manually changes will be removed when running the Converter.
+map: 021-2.gat
+npc: npc/021-2/_mobs.txt
+npc: npc/021-2/_warps.txt
+npc: npc/021-2/bakery.txt
+npc: npc/021-2/furquest.txt
+npc: npc/021-2/government_building.txt
+npc: npc/021-2/heathin.txt
+npc: npc/021-2/inya.txt
+npc: npc/021-2/jhedia.txt
+npc: npc/021-2/mapflags.txt
+npc: npc/021-2/workshop.txt
diff --git a/npc/021-2/_mobs.txt b/npc/021-2/_mobs.txt
new file mode 100644
index 00000000..a390438e
--- /dev/null
+++ b/npc/021-2/_mobs.txt
@@ -0,0 +1,8 @@
+// This file is generated automatically. All manually changes will be removed when running the Converter.
+// Tulimshar mobs
+
+
+
+021-2.gat,0,0,0	script	Mob021-2	-1,{
+	end;
+}
diff --git a/npc/021-2/_warps.txt b/npc/021-2/_warps.txt
new file mode 100644
index 00000000..0af6f275
--- /dev/null
+++ b/npc/021-2/_warps.txt
@@ -0,0 +1,14 @@
+// This file is generated automatically. All manually changes will be removed when running the Converter.
+// Tulimshar warps
+
+021-2.gat,27,30	warp	toOutside	-1,-1,021-1.gat,53,135
+021-2.gat,33,30	warp	toOutside	-1,-1,021-1.gat,55,135
+021-2.gat,39,30	warp	toOutside	-1,-1,021-1.gat,57,135
+021-2.gat,91,28	warp	toOutside	-1,-1,021-1.gat,103,101
+021-2.gat,122,24	warp	toOutside	-1,-1,021-1.gat,103,97
+021-2.gat,118,24	warp	to1stFloor	0,-1,021-2.gat,79,22
+021-2.gat,80,22	warp	to2ndFloor	0,-1,021-2.gat,118,23
+021-2.gat,23,99	warp	toOutside	-1,-1,021-1.gat,52,96
+021-2.gat,25,67	warp	toOutside	-1,-1,021-1.gat,53,100
+021-2.gat,46,97	warp	to1stFloor	0,-1,021-2.gat,45,58
+021-2.gat,46,57	warp	to2ndFloor	0,-1,021-2.gat,46,96
diff --git a/npc/021-2/bakery.txt b/npc/021-2/bakery.txt
new file mode 100644
index 00000000..9a3f1054
--- /dev/null
+++ b/npc/021-2/bakery.txt
@@ -0,0 +1,234 @@
+// The bakery
+
+// The chef
+021-2.gat,95,21,0	script	Riskim	148,{
+
+// lines belong to easter 2011:
+//	set @month, 4;
+//	set @start_day, 15;
+//	set @end_day, 30;
+
+//	if (gettime(6) == @month && gettime(5) >= @start_day && gettime(5) <= @end_day && QUEST_Easter11 == 10) goto L_ChocMouboo;
+//	if (gettime(6) == @month && gettime(5) >= @start_day && gettime(5) <= @end_day && QUEST_Easter11 == 11) goto L_MakeChocMouboo;
+//	if (gettime(6) == @month && gettime(5) >= @start_day && gettime(5) <= @end_day && QUEST_Easter11 == 12) goto L_SeeBunny;
+
+L_Begin:
+	mes "[Riskim]";
+	mes "";
+	mes "\"Welcome to our bakery!\"";
+
+	callfunc "KadiyaSubquestConsts";
+	if ((@Q_kadiya_status == @Q_STATUS_WANTS_CHOCOCAKE) && (countitem ("MopoxCurePotion") > 0))
+		goto L_lace_chococake;
+
+	if ((@Q_kadiya_status == @Q_STATUS_WANTS_ORANGECUPCAKE) && (countitem ("MopoxCurePotion") > 0))
+		goto L_lace_cupcake;
+
+	mes "\"Would you mind bringing me 6 acorns please? I need them to make flour for the chocolate cakes. I will be so delicious!\"";
+	next;
+	mes "\"Um, I mean, the cakes will be delicious...\"";
+	emotion 8;
+	next;
+
+	set @dq_level, 15;
+	set @dq_cost, 3;
+	set @dq_count, 6;
+	set @dq_name$, "Acorn";
+	set @dq_friendly_name$, "acorns";
+	set @dq_money, 250;
+	set @dq_exp, 50;
+
+	callfunc "DailyQuest";
+
+	next;
+
+	mes "\"And don't forget, our bakery is the best!\"";
+
+	close;
+
+L_lace_chococake:
+	next;
+
+	menu
+		"Thanks!  Let me have a look around...", L_end,
+		"Can you put this potion into a [Chocolate Cake]?", -,
+		"Goodbye!", L_end;
+
+	mes "[Riskim]";
+	mes "";
+	mes "As you show Riskim the potion, he leans back, away from it.";
+	mes "\"Ooooh, I remember that smell...\"";
+	mes "\"Elanore's Mopox potion, right?  She made me drink that, too...\"";
+	mes "He chuckles.";
+	mes "\"Yes, well, you do want to hide that somehow.\"";
+	next;
+
+	mes "[Riskim]";
+	mes "";
+	mes "\"We'll need extra chocolate for that one.  If you can give me ten pieces of chocolate and that potion, plus 400 GP, I will bake you a special [Chocolate Cake] that hides the taste.\"";
+	next;
+
+	menu
+		"I will get them for you.", L_end,
+		"Here you are!", -,
+		"Maybe later.", L_end;
+
+	if (countitem("ChocolateBar") < 10)
+		goto L_lacking_ingredients;
+	if (countitem("MopoxCurePotion") < 1)
+		goto L_lacking_ingredients;
+	if (zeny < 400)
+		goto L_lacking_zeny;
+	delitem "MopoxCurePotion", 1;
+	delitem "ChocolateBar", 10;
+	getitem "LacedChocolateCake", 1;
+	set zeny, zeny - 400;
+
+	mes "[Riskim]";
+	mes "";
+	mes "\"Please have a seat!\"";
+	mes "You watch as Riskim melts the chocolate and stirs in the potion, then glazes a cake with the mixture.";
+	mes "\"It's a bit more chocolatey than your average chocolate cake, of course...\"";
+	next;
+
+	mes "[Riskim]";
+	mes "";
+	mes "Riskim hands you the cake.";
+	mes "\"Here you are.  I hope that this works.\"";
+	close;
+
+L_lacking_zeny:
+	mes "[Riskim]";
+	mes "";
+	mes "\"I'm sorry, but I have to charge 400 GP.\"";
+	close;
+
+L_lacking_ingredients:
+	mes "[Riskim]";
+	mes "";
+	mes "\"Sorry, but I need ten [Chocolate Bar]s AND your cure potion for this.  Please come back later when you have everything.\"";
+	close;
+
+L_lace_cupcake:
+	next;
+
+	menu
+		"Thanks!  Let me have a look around...", L_end,
+		"Can you put this potion into an [Orange Cupcake]?", -,
+		"Goodbye!", L_end;
+
+	mes "[Riskim]";
+	mes "";
+	mes "\"[Orange Cupcake]s?  Oh dear... I'm sorry, but I have a very bad orange allergy.\"";
+	next;
+	mes "[Riskim]";
+	mes "";
+	mes "\"Perhaps the Chef at Dimond's Cove can help you?  We get all our cupcakes from him.\"";
+	next;
+
+L_End:
+	close;
+
+L_ChocMouboo:
+	mes "[Riskim]";
+	mes "";
+	mes "\"Welcome to our bakery! Here you will find the best cakes in Tulimshar. And don't leave before you try one of our delicious Chocolate Pinkies!\"";
+	next;
+	menu
+		"Excuse me, sir? Did you say Chocolate Pinkies?", -;
+	mes "\"Yes! But there is no need to be alarmed, it is just plain chocolate molded in the shape of a small pinkie...\"";
+	next;
+	menu
+		"Do you have one in the shape of a mouboo? The Easter Bunny needs one.", -;
+	mes "\"The Easter Bunny? Interesting... I think I can help you make a [Chocolate Mouboo].\"";
+	menu
+		"Nah, I decided not to do that stupid quest.", L_End,
+		"I would really appreciate that!", -;
+	set QUEST_Easter11, 11;
+
+L_MakeChocMouboo:
+	mes "[Riskim]";
+	mes "";
+	mes "\"I will need you to bring me some [Chocolate Bar]s.\"";
+	mes "\"I think 5 bars should be enough.\"";
+	mes "\"Red slimes seem to have those, so try there.\"";
+	mes "\"I will also need a [Mouboo Figurine] to hollow out and use as a mold.\"";
+	mes "\"Any mage should be able to make you one out of a log, if you ask.\"";
+	menu
+		"I have everything you need.", -,
+		"Ok, I will be back soon.", L_End,
+		"I changed my mind, forget about it.", L_End;
+
+	if(countitem("ChocolateBar") < 5 || countitem("MoubooFigurine") < 1) goto L_EasterNotEnough;
+
+L_EasterEnough:
+	getinventorylist;
+	if (@inventorylist_count == 100 && countitem("ChocolateBar") > 5 && countitem("MoubooFigurine") > 1) goto L_EasterTooMany;
+	if(countitem("ChocolateBar") < 5 || countitem("MoubooFigurine") < 1) goto L_EasterNotEnough;
+	delitem "ChocolateBar", 5;
+	delitem "MoubooFigurine", 1;
+	getitem "ChocolateMouboo", 1;
+	set QUEST_Easter11, 12;
+	mes "[Riskim]";
+	mes "";
+	mes "\"Excellent.  You have brought me the chocolate and the mold.\"";
+	mes "He places the chocolate in a pan to melt.";
+	mes "Next, he pours the melted chocolate into the mold.";
+	mes "Finally, he dips the mold in cold water for a moment to solidify the chocolate before skillfully cracking it open and handing you the finished product.";
+	mes "\"Here is your [Chocolate Mouboo].\"";
+	close;
+
+L_EasterNotEnough:
+	mes "[Riskim]";
+	mes "";
+	if(countitem("ChocolateBar") < 5) mes "\"You do not have enough [Chocolate Bar]s for me to work with yet.\"";
+	if(countitem("MoubooFigurine") < 1) mes "\"You do not have the [Mouboo Figurine] to use as a mold.\"";
+	mes "\"Please go get what I asked.\"";
+	close;
+
+L_EasterTooMany:
+	mes "[Riskim]";
+	mes "";
+	mes "\"You don't have enough room for the [Chocolate Mouboo]. Come back later.\"";
+	close;
+
+L_SeeBunny:
+	mes "[Riskim]";
+	mes "";
+	mes "\"You need to return to the Easter Bunny now.\"";
+	close;
+}
+
+// Server?
+021-2.gat,82,23,0	script	Sara	108,{
+	mes "[Sara]";
+	mes "";
+	mes "\"Hello!\"";
+	close;
+}
+
+// The cashier
+021-2.gat,89,21,0	shop	Drabur	112,WhiteCake :-1,ChocolateCake :-1,OrangeCake :-1,AppleCake :-1,Cake :-1,CherryCake :-1,OrangeCupcake :-3,Milk :-5,XmasCake :-1
+
+// Stockroom boy
+021-2.gat,133,21,0	script	Iormo	160,{
+	mes "[Iormo]";
+	mes "";
+	mes "\"This stock room can get messy.\"";
+	close;
+}
+
+// An old couple eating at the bakery
+021-2.gat,71,22,0	script	Rynoh	159,{
+	mes "[Rynoh]";
+	mes "";
+	mes "\"The cakes may be expensive, but they sure are delicious!\"";
+	close;
+}
+
+021-2.gat,73,22,0	script	Ontas	154,{
+	mes "[Ontas]";
+	mes "";
+	mes "\"We come here every week.  This place has some of the best bread I've ever eaten!\"";
+	close;
+}
diff --git a/npc/021-2/furquest.txt b/npc/021-2/furquest.txt
new file mode 100644
index 00000000..04814576
--- /dev/null
+++ b/npc/021-2/furquest.txt
@@ -0,0 +1,338 @@
+//#################################################################################
+// Script by Shaili and QOAL
+//#################################################################################
+
+// Tulimshar Crafting Workshop - Agostine, The Legendary Tailor
+021-2.gat,32,63,0	script	Agostine	137,{
+	if (QUEST_WG_state == 1) goto L_State_0_3;
+	if (QUEST_WG_state == 2) goto L_State_1;
+	if (QUEST_WG_state == 3) goto L_State_2;
+	if (QUEST_WG_state == 4) goto L_State_4;
+	if (QUEST_WG_state == 5) goto L_State_4_success;
+	if (QUEST_WG_state == 6) goto L_State_6;
+	if (QUEST_WG_state == 7) goto L_State_11;
+	if (QUEST_WG_state == 8) goto L_State_12;
+	if (QUEST_WG_state >= 9) goto L_State_13;
+
+	mes "\"This goes up, this goes left...\"";
+	next;
+	mes "\"Mmmm...?\"";
+	next;
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"Oh, a customer! Let me introduce myself! My name is Agostine!";
+	mes "Some people say that I am the best tailor in the world,";
+	mes "but I think I am the best one in the universe!";
+	mes "So, What can I do for you, my friend?\"";
+	next;
+	menu
+		"I want something new for my wardrobe!", L_State_0_1,
+		"Oh, nothing, thanks!", -;
+	close;
+
+// Quest #0 - Beginning - Needed: Iron Potion
+
+L_State_0_1:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"Well.. you know... working so hard makes me so tired!";
+	mes "Can you bring me something tasty to drink, my friend?\"";
+	next;
+	menu
+		"Sure, what kind of drink you like?", L_State_0_2,
+		"I'm not your waiter!", -;
+	close;
+
+L_State_0_2:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"Here we do not have a bar. Let me taste different beverages.";
+	mes "I want something new to drink.\"";
+	next;
+	menu
+		"I'll bring you different drinks to try!", L_State_Accept,
+		"Maybe a bar will open soon, wait for it.", -;
+	close;
+
+L_State_Accept:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"Thanks so much.\"";
+	set QUEST_WG_state, 1;
+	close;
+
+L_State_0_3:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"Well, what have you brought me?\"";
+	next;
+	menu
+		"A Cactus Drink.", L_State_0_4,
+		"A Cactus Potion.", L_State_0_5,
+		"Some milk.", L_State_0_6,
+		"A pint of beer.", L_State_0_7,
+		"An Iron potion.", L_State_0_9,
+		"A Concentration Potion.", L_State_0_8,
+		"Nothing, at the moment.", -;
+	close;
+
+L_State_0_4:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"So, a Cactus Drink?\"";
+	if (countitem("CactusDrink") < 1) goto L_State_neg;
+	delitem "CactusDrink", 1;
+	goto L_State_bad;
+	close;
+
+L_State_0_5:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"So, a Cactus Potion?\"";
+	if (countitem("CactusPotion") < 1) goto L_State_neg;
+	delitem "CactusPotion", 1;
+	goto L_State_bad;
+	close;
+
+L_State_0_6:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"So, some milk for me?\"";
+	if (countitem("Milk") < 1) goto L_State_neg;
+	delitem "Milk", 1;
+	goto L_State_bad;
+	close;
+
+L_State_0_7:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"So, a beer?\"";
+	if (countitem("Beer") < 1) goto L_State_neg;
+	delitem "Beer", 1;
+	goto L_State_bad;
+	close;
+
+L_State_0_8:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"So, a Concentration Potion?\"";
+	if (countitem("ConcentrationPotion") < 1) goto L_State_neg;
+	delitem "ConcentrationPotion", 1;
+	goto L_State_bad;
+	close;
+
+L_State_0_9:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"So, an Iron Potion?\"";
+	if (countitem("IronPotion") < 1) goto L_State_neg;
+	delitem "IronPotion", 1;
+	next;
+	mes "Agostine looks pleased as he drinks the potion.";
+	next;
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"Oh! This is damn good! I feel a new man, my friend!\"";
+	next;
+	set zeny, zeny + 500;
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"This is a little reward for your help. Take 500 GP, my friend!\"";
+	set QUEST_WG_state, 2;
+	close;
+
+L_State_neg:
+	next;
+	mes "\"Seems that you lied. You don't have the drink you told me.\"";
+	close;
+
+L_State_bad:
+	next;
+	mes "\"Well, I don't like it so much. Bring me something else.\"";
+	close;
+
+// First Quest: edited version of Forest Bow Quest - Needed: about 30 White Furs and 15.000 GP
+
+L_State_1:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"Mmmm... Let me see... This year light colours are fashionable!";
+	mes "Would you like a pair of snow-white Winter Gloves?\"";
+	next;
+	menu
+		"No, thanks. I love dark clothes...", -,
+		"You really can do this for me?", L_State_2;
+	close;
+
+L_State_2:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"Well, Winter Gloves are so fashionable for their lovable fur!";
+	mes "Only the best furs can be used for these gloves!";
+	mes "But, as you see, I am a tailor, not a hunter! So, why don't you bring me the best fluffy's fur you can find?\"";
+	set QUEST_WG_state, 3;
+	next;
+	menu
+		"You are crazy! I won't kill any animal for this!", -,
+		"Sure, I will be back soon!", L_State_3;
+	close;
+
+L_State_3:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"Remember, I want the best of fur!\"";
+	set QUEST_WG_state, 4;
+	close;
+
+L_State_4:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"Oh, my friend! Have you brought me some good furs?\"";
+	if (countitem("WhiteFur") < 1) close;
+	next;
+	menu
+		"Here, take a look!", L_State_4_try,
+		"Yes, but I need it for something else.", -;
+	close;
+
+L_State_4_try:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"Let me see, my friend! It needs to be perfect for my gloves!\"";
+	mes "Agostine examines the patch of fur.";
+	next;
+	if (countitem("WhiteFur") < 1) goto L_No_Fur;
+	delitem "WhiteFur", 1;
+	set @Temp1,rand(30);
+	if (@Temp1 == 0) goto L_State_4_success;
+	mes "Agostine throws away the white fur.";
+	next;
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"It was awfully cut! You should pay more attention when you kill fluffies!\"";
+	if (countitem("WhiteFur") < 1) close;
+	next;
+	menu
+		"Here I have another one!", L_State_4_try,
+		"Sorry, I will be careful...", -;
+	close;
+
+L_State_4_success:
+	mes "Agostine breaks into a smile";
+	next;
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"It's perfect! Perfect! Good job, my friend! I will prepare your gloves right now!\"";
+	next;
+	set QUEST_WG_state, 5;
+	goto L_State_5;
+
+L_State_5:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"Ehm, my friend, my work is not free. I need 15,000 GP for the work.\"";
+	next;
+	menu
+		"You are not a tailor, you are a thief!!", -,
+		"I think it's a reasonable price...", L_State_5_pay;
+	close;
+
+L_State_5_pay:
+	if (zeny < 15000) goto L_State_5_nocash;
+	getinventorylist;
+	if (@inventorylist_count == 100) goto L_TooMany;
+	set zeny, zeny - 15000;
+	getitem "WinterGloves", 1;
+	set QUEST_WG_state, 6;
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"Here they are. You will have the most fashionable hands in the world!\"";
+	close;
+
+L_State_5_nocash:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"Seems like you are out of cash. Come back when you have the money.\"";
+	close;
+
+L_State_6:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"Oh, I remember you! Your gloves are sooo fashionable, my friend!";
+	mes "Well, I have a good news for you. In this issue of 'TMW Fashion'";
+	mes "I saw a pretty accessory, a pair of Furry Boots, my friend.";
+	mes "I can make your own pair, if you want!\"";
+	next;
+	menu
+		"It's a great idea!", L_State_10,
+		"I'm glamourous enough, thanks", -;
+	close;
+
+// Start of Second Quest: Furry Boots - Needed: About 30 White Furs, 1 pair of Boots and 15.000 GP
+L_State_10:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"Perfect! For satisfying your request I need another perfect White Fur";
+	mes "and a pair of Boots, like those you can find in the mines.";
+	mes "They will make you lovely, my friend!\"";
+	set QUEST_WG_state, 7;
+	close;
+
+L_State_11:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"So, my friend, have you brought me the right Fur?\"";
+	if (countitem("WhiteFur") < 1) close;
+	next;
+	menu
+		"Sure, I'm a fluffy hunter!", L_State_11_try,
+		"Not yet, sorry.", -;
+	close;
+
+L_State_11_try:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"I'd rather see the patch of fur, first.\"";
+	next;
+	mes "Agostine examines the patch of fur.";
+	next;
+	if (countitem("WhiteFur") < 1) goto L_No_Fur;
+	delitem "WhiteFur", 1;
+	set @Temp2,rand(30);
+	if (@Temp2 == 0) goto L_State_11_success;
+	mes "Agostine rips the white fur.";
+	next;
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"That fur was terrible. I won't work with it!\"";
+	if (countitem("WhiteFur") < 1) close;
+	next;
+	menu
+		"Well, maybe this is better!", L_State_11_try,
+		"I will hunt other fluffies...", -;
+	close;
+
+L_State_11_success:
+	mes "Agostine breaks into a smile";
+	next;
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"This one is good enough, my friend. Good job.\"";
+	set QUEST_WG_state, 8;
+	goto L_State_12;
+
+L_State_12:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"I need also a pair of Boots for the work.";
+	mes "And my payment, obviously. 15,000 GP is right.\"";
+	next;
+	menu
+		"Sure, here it all is.", L_State_12_pay,
+		"I missed something, I will be back soon!", -;
+	close;
+
+L_State_12_pay:
+	if (zeny < 15000) goto L_State_12_missing;
+	if (countitem("Boots") < 1) goto L_State_12_missing;
+	// No inventory check needed, as boots are removed, opening a slot
+	set zeny, zeny - 15000;
+	delitem "Boots", 1;
+	getitem "FurBoots", 1;
+	set QUEST_WG_state, 9;
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"Enjoy your new boots, my friend!\"";
+	close;
+
+L_State_12_missing:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"Seems you have forgotten something. Check your inventory";
+	mes "and your pockets!\"";
+	close;
+
+L_State_13:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"You are so glamourous, my dear friend!";
+	mes "I have done a very good job on your clothes!\"";
+	close;
+
+L_TooMany:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"You don't have anywhere to put them. Come back when you do.\"";
+	close;
+
+L_No_Fur:
+	mes "[Agostine, The Legendary Tailor]";
+	mes "\"You don't have any white fur! Stop talking nonsense.\"";
+	close;
+}
diff --git a/npc/021-2/government_building.txt b/npc/021-2/government_building.txt
new file mode 100644
index 00000000..f4f9d0de
--- /dev/null
+++ b/npc/021-2/government_building.txt
@@ -0,0 +1,220 @@
+// The government builing in the south west
+
+// A clerk
+021-2.gat,27,17,0	script	Estard	107,{
+	mes "[Estard]";
+	mes "\"Hello what can I do for you?\"";
+	next;
+
+L_main:
+	if (getpartnerid2(0))
+		goto L_main_married;
+
+	menu
+		"I'm looking at getting married.", L_marry,
+		"Nothing, I guess.", -;
+	close;
+
+L_main_married:
+	menu
+		"I'd like a divorce.", L_divorce,
+		"Nothing, I guess.", -;
+	close;
+
+L_marry:
+	if (BaseLevel < WEDDING_MIN_LEVEL)
+		goto L_marry_too_young;
+	if (zeny < WEDDING_FEE)
+		goto L_marry_too_poor;
+	
+	mes "[Estard]";
+	mes "\"Are you sure you want to get married? It'll cost " + WEDDING_FEE + " GP.\"";
+	
+	menu
+		"Yes", L_marry_do,
+		"No", -;
+	close;
+
+L_marry_do:
+	callsub S_give_rings;
+	
+	mes "[Estard]";
+	mes "\"Here are your rings. You can get married by standing in one of the designated places (like that small rug over there) with your partner, give them their ring, and say 'marry (their name here)'. You both need to have your rings on.\"";
+	close;
+
+L_marry_too_young:
+	mes "[Estard]";
+	mes "\"I'm sorry, but you are too young to get married. You must be atleast " + WEDDING_MIN_LEVEL + " levels old.\"";
+	next;
+	
+	menu
+		"Can I at least get wedding rings?", L_get_rings,
+		"Thanks anyways.", -;
+	close;
+
+L_marry_too_poor:
+	mes "[Estard]";
+	mes "\"You need " + WEDDING_FEE + " GP to get married. That covers all administrative fees for the marriage and provides two wedding rings.\"";
+	close;
+
+L_get_rings:
+	mes "[Estard]";
+	mes "\"Yes. They are " + WEDDING_FEE + " GP. That covers all administrative fees for the marriage.\"";
+	
+	if (zeny < WEDDING_FEE)
+		menu
+			"Thanks anyways. I don't have enough with me.", -;
+	    
+	if (zeny >= WEDDING_FEE)
+		menu
+			"I'll buy a pair.", L_get_rings_pay,
+			"Thanks anyways.", -;
+	close;
+
+L_get_rings_pay:
+	callsub S_give_rings;
+	
+	mes "[Estard]";
+	mes "\"There you go. Come again.\"";
+	close;
+
+L_divorce:
+	set @divorce_cost, DIVORCE_FEE_PER_LEVEL * BaseLevel;
+	
+	if (zeny < @divorce_cost)
+		goto L_divorce_not_enough;
+	
+	mes "[Estard]";
+	mes "\"If you're sure you want a divorce, it'll cost you " + @divorce_cost + " GP.\"";
+	next;
+	
+	menu
+		"I am sure I want it.", L_do_divorce,
+		"I don't want it.", -;
+	close;
+
+L_do_divorce:
+	if (zeny < @divorce_cost)
+		goto L_not_enough_money;
+	
+	if divorce(0) goto L_divorce_done;
+	
+	mes "[Estard]";
+	mes "\"I'm having trouble finding the record. \"";
+
+	mes "[Server]";
+	mes "Try again when your partner is online too.";
+	close;
+
+L_divorce_done:
+	set zeny, zeny - @divorce_cost;
+	
+	mes "[Estard]";
+	mes "\"You have been divorced. Come again.\"";
+	close;
+
+L_divorce_not_enough:
+	mes "[Estard]";
+	mes "\"I'm sorry , but you don't have enough money to get a divorce. You need " + @divorce_cost + " GP.\"";
+	close;
+
+L_not_enough_money:
+	mes "[Estard]";
+	mes "\"Seems you don't have enough money.\"";
+	close;
+
+L_no_room_for_rings:
+	mes "[Estard]";
+	mes "\"You don't have enough room to carry these rings.\"";
+	close;
+
+S_give_rings:
+	if (zeny < WEDDING_FEE)
+		goto L_not_enough_money;
+	getinventorylist;
+	if (@inventorylist_count > 98) goto L_no_room_for_rings;
+	
+	set zeny, zeny - WEDDING_FEE;
+	getitem "WeddingRing", 1;
+	getitem "WeddingRing", 1;
+	return;
+}
+
+021-2.gat,36,17,0	script	Tathin	107,{
+	set @PARTY_SKILL, 3;
+
+	mes "[Tathin]";
+	mes "\"Hello what Can I do for you?\"";
+	next;
+
+	if (getskilllv(@PARTY_SKILL) == 2 ) goto L_Base_Menu;
+	if (BaseLevel >= 15 && getskilllv(@PARTY_SKILL) == 1) goto L_Can_Make_Party;
+	if (getskilllv(@PARTY_SKILL) == 1) goto L_Base_Menu;
+	if (BaseLevel >= 10) goto L_Can_Party;
+
+L_Base_Menu:
+	menu
+		"Nothing, I guess.", -;
+	close;
+
+L_Can_Party:
+	menu
+		"I'd like to get a party permit.", L_Get_Party,
+		"Nothing, I guess.", -;
+	close;
+
+L_Can_Make_Party:
+	menu
+		"I'd like to get a party creator permit.", L_Get_Make_Party,
+		"Nothing, I guess.", -;
+	close;
+
+L_Get_Party:
+	mes "[Tathin]";
+	mes "\"A permit to join parties costs 10 GP.\"";
+	next;
+	menu
+		"OK", L_Give_Party,
+		"No thank you", -;
+	close;
+
+L_Give_Party:
+	if (zeny < 10) goto L_NotEnoughMoney;
+	set zeny, zeny - 10;
+	setskill @PARTY_SKILL, 1;
+	mes "[Tathin]";
+	mes "\"Here's your permit. You'll need to be invited by an existing member of a party to join it.\"";
+	next;
+	mes "[Tathin]";
+	mes "\"Remember, parties cannot share experience if any members are more than 10 levels apart.\"";
+	close;
+
+L_Get_Make_Party:
+	mes "[Tathin]";
+	mes "\"A permit to create parties costs 50 GP.\"";
+	next;
+	menu
+		"OK", L_Give_Make_Party,
+		"No thank you", -;
+	close;
+
+L_Give_Make_Party:
+	if (zeny < 50) goto L_NotEnoughMoney;
+	set zeny, zeny - 50;
+	setskill @PARTY_SKILL, 2;
+	mes "[Tathin]";
+	mes "\"Here's your permit. You can create parties with the 'new' or 'create' commands on the Party tab in the client. Parties need to have unique names.\"";
+	close;
+
+L_NotEnoughMoney:
+	mes "[Tathin]";
+	mes "\"You don't have enough GP\"";
+	close;
+}
+
+// Guard
+021-2.gat,20,19,0	script	Guard	123,1,1,{
+	mes "[Guard]";
+	mes "\"You can't come back here.\"";
+	close;
+}
diff --git a/npc/021-2/heathin.txt b/npc/021-2/heathin.txt
new file mode 100644
index 00000000..270d510a
--- /dev/null
+++ b/npc/021-2/heathin.txt
@@ -0,0 +1,287 @@
+//Items for NPC are incomplete.  Makes "simple ring" which can be crafted into a useful ring by Inya and terranite armor.
+
+021-2.gat,29,55,0	script	Heathin	147,{
+
+	set @TARROW_REQ_TERRA_ORE, 1;
+	set @TARROW_REQ_COAL, 5;
+	set @TARROW_REQ_GP, 3000;
+
+	if (HEATHIN_QUEST == 14) && (baselevel >= 80) goto L_Heathin_Terranite_Arrows_Trade;
+	if (HEATHIN_QUEST == 13) && (baselevel >= 80) goto L_Heathin_Terranite_Arrows_Ready;
+	if (HEATHIN_QUEST == 12) && (baselevel >= 80) goto L_Heathin_Terranite_Arrows_Forge;
+	if (HEATHIN_QUEST == 11) && (baselevel >= 80) goto L_Heathin_Terranite_Arrows;
+	if (HEATHIN_QUEST == 10) && (baselevel >= 80) goto L_Heathin_Terranite_Chest_Armor_Ready;
+	if (HEATHIN_QUEST == 9) && (baselevel >= 80) goto L_Heathin_Terranite_Chest_Armor_Forge;
+	if (HEATHIN_QUEST == 8) && (baselevel >= 80) goto L_Heathin_Terranite_Chest_Armor;
+	if (HEATHIN_QUEST == 7) && (baselevel >= 80) goto L_Heathin_Terranite_Legs_Ready;
+	if (HEATHIN_QUEST == 6) && (baselevel >= 80) goto L_Heathin_Terranite_Legs_Forge;
+	if (HEATHIN_QUEST == 5) && (baselevel >= 80) goto L_Heathin_Terranite_Legs;
+	if (HEATHIN_QUEST == 4) && (baselevel >= 80) goto L_Heathin_Terranite_Hood_Ready;
+	if (HEATHIN_QUEST == 3) && (baselevel >= 80) goto L_Heathin_Terranite_Hood_Forge;
+	if (HEATHIN_QUEST == 2) && (baselevel >= 80) goto L_Heathin_Terranite_Hood;
+	if (HEATHIN_QUEST == 2) && (baselevel >= 60)goto L_Heathin_Ring_Thanks;
+	if (HEATHIN_QUEST == 1) && (baselevel >= 60) goto L_Heathin_Ring_Award;
+	if (baselevel >= 60) goto L_Heathin_Start;
+
+	mes "[Heathin]";
+	mes "\"Hello, friend.  I am Heathin, a smith of exotic metals. \"";
+	close;
+
+L_Heathin_Start:
+	mes "[Heathin]";
+	mes "\"Hello, friend.  I am Heathin, a smith of exotic metals. \"";
+	next;
+	mes "\"By the order of the Wizard's Council, I've been commissioned to forge gold ingots from gold pieces.  I need to collect as many gold pieces as I can manage, forge them and give the ingots to the Council.  However, I am but a simple smith and cannot complete this effort by myself.\"";
+	next;
+	mes "\"Forging gold ingots is not just a simple matter of gold falling from the sky!  I need individuals that can gather not just the gold, but also help collect [Coal] to heat my forge.\"";
+	next;
+	mes "\"Of course it would make little sense for me to gather gold pieces from helpers just to pass them back out. However, I am willing to smith an award for any who would put an effort in towards completing my goal.\"";
+	next;
+	mes "\"Perhaps you would be interested in helping me out?  Would you be willing to help me gather [Coal] and gold to fulfill my commission?  I am asking any and all willing souls to get me 50 coal and 100,000 gold pieces, as that would put a significant dint in my goal.\"";
+	menu
+		"Sure, I'll help!", L_Heathin_Help,
+		"I'd rather keep my gold for my own purposes, thank you very much.", L_Heathin_No,
+		"Wait, what kind of award are we talking about?", L_Heathin_Interested;
+
+L_Heathin_Help:
+	set HEATHIN_QUEST, 1;
+	mes "[Heathin]";
+	mes "\"Excellent!  I am always glad when someone can be of service not just to me, but to all of Tulimshar.  Please get me 50 [Coal] and 100,000 gold pieces, and you will be compensated for your efforts.\"";
+	close;
+
+L_Heathin_No:
+	mes "[Heathin]";
+	mes "\"That is too bad.  If you change your mind, I shall still be here, attempting to get my commission done.\"";
+	close;
+
+L_Heathin_Interested:
+	mes "[Heathin]";
+	mes "\"Well, when I am crafting these ingots, there are always stray metals left over.  Surely I could forge them into ingots again, but I'd rather ensure that my commission be completed.  I am willing to forge a [Simple Ring] for you, which could be made more beautiful by a skilled jeweler.\"";
+	next;
+	mes "\"What you do with the ring after I am done forging it is your own business, but it could come in handy.\"";
+	next;
+	mes "\"Does this sound like something you might be interested in?\"";
+	menu
+		"Sure, I'll help!", L_Heathin_Help,
+		"I'd rather keep my gold.", L_Heathin_No,
+		"Can you repeat that again?", L_Heathin_Interested;
+	close;
+
+L_Heathin_Ring_Award:
+	if ( (zeny < 100000) | (countitem ("Coal") < 50) ) goto L_Heathin_Ring_Wait;
+	set HEATHIN_QUEST, 2;
+	set zeny, zeny - 100000;
+	delitem "Coal", 50;
+	getitem "RingSimple", 1;
+	mes "[Heathin]";
+	mes "\"You have brought the [Coal] and gold pieces.  This is most excellent!  As promised, I have crafted a ring for you.  Hopefully you will find it useful.\"";
+	next;
+	mes "\"Time to smelt these gold pieces into ingots.  The Council will be pleased.  Thank you for your efforts!\"";
+	close;
+
+L_Heathin_Ring_Wait:
+	mes "[Heathin]";
+	mes "\"Hello again.  Making golden ingots keeps me pretty busy.  I certainly hope I can fulfill my commission soon so that I can move on to bigger and better things.\"";
+	next;
+	mes "\"The pay is good, certainly, but I am a far better smith than this.  If you can bring me 100,000 gold pieces and 50 [Coal], it would surely get me to my goal faster.\"";
+	next;
+	mes "\"I will be sure to provide an apt award once you are done.\"";
+	close;
+
+L_Heathin_Ring_Thanks:
+	mes "[Heathin]";
+	mes "\"Thank you again for helping me fulfil my commission.  It has made a signficant dint in what the Council requires of me.  Perhaps I may be of service to you again one day!\"";
+	close;
+
+L_Heathin_Terranite_Hood:
+	mes "[Heathin]";
+	mes "\"Hello again friend, I just found out about this great metal called terranite.\"";
+	next;
+	mes "\"This metal is almost as strong as steel, but is also very ductile.\"";
+	next;
+	mes "\"With some effort, I can make this metal form rings tighter than any chain mail.  It isn't the prettiest in hue, but its uses can be many.\"";
+	next;
+	mes "\"Unfortunately, it seems to be difficult to gather.  Most that have searched for [Terranite Ore] either cannot find it or have never returned...\"";
+	next;
+	mes "\"I may be an excellent smith, but I certainly am no combatant.  However, I would enjoy turning this ore into something useful, perhaps some type of armor to help those that may be braver.\"";
+	next;
+	mes "\"So, what do you say?  Are you interested?\"";
+	menu
+		"No, thank you.  Maybe later.", L_Heathin_Terranite_No,
+		"Armor, you say?  Definitely!", L_Heathin_Terranite_Yes;
+	close;
+
+L_Heathin_Terranite_No:
+	mes "[Heathin]";
+	mes "\"Ah, that is too bad.  Come by again anytime.\"";
+	close;
+
+L_Heathin_Terranite_Yes:
+	set HEATHIN_QUEST, 3;
+	mes "[Heathin]";
+	mes "\"Great, this is going to be fun!  As I have not had much practice with this armor, I'd like to get started soon.\"";
+	next;
+	mes "Heathin thinks for a moment.";
+	next;
+	mes "\"Ah, I know!  I will make a helm...  Well, more like a hood, since it will be woven.\"";
+	next;
+	mes "\"It will require a great amount of heat, if the rumors are to be believed.  For this, I will need 100 [Coal] to keep my forge burning hot.  I will also need 10 [Terranite Ore] to make the armor.  Of course, such work does not come cheap.  While I may enjoy my work, my time and effort is very valuable.  To compensate my efforts I will need 200,000 gold pieces.  Please come back with the gold, [Coal] and ore and I'll make this hood for you.\"";
+	close;
+
+L_Heathin_Terranite_Hood_Forge:
+	if ( (zeny < 200000) | (countitem("Coal") < 100) | (countitem("TerraniteOre") < 10) ) goto L_Heathin_Terranite_Hood_Wait;
+	set HEATHIN_QUEST, 4;
+	delitem "Coal", 100;
+	delitem "TerraniteOre", 10;
+	set zeny, zeny - 200000;
+	mes "[Heathin]";
+	mes "\"Great, you brought everything!  Come back later and I'll have the helm ready for you.\"";
+	close;
+
+L_Heathin_Terranite_Hood_Wait:
+	mes "[Heathin]";
+	mes "\"I am very busy right now.  If you could bring me 10 [Terranite Ore], 100 [Coal] and 200,000 gold pieces, I will make that terranite hood for you.\"";
+	close;
+
+L_Heathin_Terranite_Hood_Ready:
+	set HEATHIN_QUEST, 5;
+	getitem "TerraniteHelmet", 1;
+	mes "[Heathin]";
+	mes "\"I am all done with your terranite hood.  I hope you enjoy it!  I have some work to wrap up for the Council, but come back later and I might be able to assist you again.\"";
+	close;
+
+L_Heathin_Terranite_Legs:
+	set HEATHIN_QUEST, 6;
+	mes "[Heathin]";
+	mes "\"I am glad you are back!  I've just finished up some more of my commission.  Now I can get back to making terranite armor for you.  This time I will make some pants, but they need more ore, more [Coal] to heat my forge and of course, more gold for my efforts.\"";
+	next;
+	mes "\"To make terranite pants, I need 200 [Coal], 30 [Terranite Ore] and 400,000 gold pieces.  The faster you bring this to me, the faster I can have your terranite pants ready.\"";
+	close;
+
+L_Heathin_Terranite_Legs_Forge:
+	if ( (zeny < 400000) | (countitem("Coal") < 200) | (countitem("TerraniteOre") < 30) ) goto L_Heathin_Terranite_Legs_Wait;
+	set HEATHIN_QUEST, 7;
+	delitem "Coal", 200;
+	delitem "TerraniteOre", 30;
+	set zeny, zeny - 400000;
+	mes "[Heathin]";
+	mes "\"Great, you have brought everything!  Come back later and I will have those terranite pants ready for you.\"";
+	close;
+
+L_Heathin_Terranite_Legs_Wait:
+	mes "[Heathin]";
+	mes "\"I am very busy right now.  If you could bring me 30 [Terranite Ore], 200 [Coal] and 400,000 gold pieces, I will make those terranite pants for you.\"";
+	close;
+
+L_Heathin_Terranite_Legs_Ready:
+	set HEATHIN_QUEST, 8;
+	getitem "TerraniteLegsArmor", 1;
+	mes "[Heathin]";
+	mes "\"I am all done with your terranite pants.  Hope you enjoy them!  I have some more work to complete for the Council.  Come back later and I might be able to assist you again.\"";
+	close;
+
+L_Heathin_Terranite_Chest_Armor:
+	set HEATHIN_QUEST, 9;
+	mes "[Heathin]";
+	mes "\"Good to see you again.  I have just finished up some more of my commission.  Now I can get back to making terranite armor for you.  This time, I will make some terranite chest armor, but it needs more ore, more [Coal] for my forge and of course, more gold to compensate for my efforts.\"";
+	next;
+	mes "\"To make terranite chest armor, I need 250 [Coal], 40 [Terranite Ore] and 500,000 gold pieces.  The faster you bring this to me, the faster I can have your terranite armor ready.\"";
+	close;
+
+L_Heathin_Terranite_Chest_Armor_Forge:
+	if ( (zeny < 500000) | (countitem("Coal") < 250) | (countitem("TerraniteOre") < 40) ) goto L_Heathin_Terranite_Chest_Armor_Wait;
+	set HEATHIN_QUEST, 10;
+	delitem "Coal", 250;
+	delitem "TerraniteOre", 40;
+	set zeny, zeny - 500000;
+	mes "[Heathin]";
+	mes "\"Splendid, you have brought everything!  Come back later and I will have the terranite chest armor ready for you.\"";
+	close;
+
+L_Heathin_Terranite_Chest_Armor_Wait:
+	mes "[Heathin]";
+	mes "\"I am very busy right now.  If you could bring me 40 [Terranite Ore], 250 [Coal] and 500,000 gold pieces, I will make that chest armor for you.\"";
+	close;
+
+L_Heathin_Terranite_Chest_Armor_Ready:
+	set HEATHIN_QUEST, 11;
+	getitem "TerraniteChestArmor", 1;
+	mes "[Heathin]";
+	mes "\"I have completed your terranite chest armor.  I hope you enjoy it!  I have some work to wrap up for the Council again, but come back later and I might be able to assist you once more.\"";
+	close;
+
+L_Heathin_Terranite_Arrows:
+	mes "[Heathin]";
+	mes "\"How good to see you.  I have experimented a little with [Terranite Ore] to see what else can be done with it.  It seems to have some qualities suitable for weapons, but I have only tested it with arrows.  If you would like, I can make [Terranite Arrow]s, but as as with the armor, I need [Coal], [Terranite Ore] and payment for my efforts.\"";
+	next;
+	mes "\"Also, it might be a while until I have time to see what else I can make with terranite other than arrows, as right now the Council is keeping me rather busy with my commission.  So, would you like some [Terranite Arrow]s?\"";
+	menu
+		"No, thank you.", L_Heathin_Terranite_Arrows_No,
+		"Sure, I could use some arrows.", L_Heathin_Terranite_Arrows_Yes;
+	close;
+
+L_Heathin_Terranite_Arrows_No:
+	mes "[Heathin]";
+	mes "\"Well, if you change your mind, I'm not going anywhere.\"";
+	close;
+
+L_Heathin_Terranite_Arrows_Yes:
+	set HEATHIN_QUEST, 12;
+	mes "[Heathin]";
+	mes "\"Good, good.  I shall begin crafting these arrows as soon as you come back.  However, I cannot just make small handfuls as it would not be worth my time and effort to have my concentration interrupted for small tasks.  I will make 1,000 [Terranite Arrow]s per request, for which I will need "+@TARROW_REQ_TERRA_ORE+" [Terranite Ore], "+@TARROW_REQ_COAL+" [Coal] and "+@TARROW_REQ_GP+" gold pieces.\"";
+	next;
+	mes "\"See you soon!\"";
+	close;
+
+L_Heathin_Terranite_Arrows_Forge:
+	if ( (zeny < @TARROW_REQ_GP) | (countitem("Coal") < @TARROW_REQ_COAL) | (countitem("TerraniteOre") < @TARROW_REQ_TERRA_ORE) ) goto L_Heathin_Terranite_Arrows_Wait;
+	set HEATHIN_QUEST, 13;
+	delitem "Coal", @TARROW_REQ_COAL;
+	delitem "TerraniteOre", @TARROW_REQ_TERRA_ORE;
+	set zeny, zeny - @TARROW_REQ_GP;
+	mes "[Heathin]";
+	mes "\"Wonderful! You have everything I asked for.  I will start working on the arrows right away.\"";
+	close;
+
+L_Heathin_Terranite_Arrows_Wait:
+	mes "[Heathin]";
+	mes "\"If you want [Terranite Arrow]s, please get me "+@TARROW_REQ_TERRA_ORE+" [Terranite Ore], "+@TARROW_REQ_COAL+" [Coal] and "+@TARROW_REQ_GP+" gold pieces.\"";
+	close;
+
+L_Heathin_Terranite_Arrows_Ready:
+	getitem "TerraniteArrow", 1000;
+	set HEATHIN_QUEST, 14;
+	mes "[Heathin]";
+	mes "\"All done, here you go!  I hope you like them.  I am still working on my commission, but if you ever need any more [Terranite Arrow]s, just come on by with "+@TARROW_REQ_COAL+" [Coal], "+@TARROW_REQ_TERRA_ORE+" [Terranite Ore] and "+@TARROW_REQ_GP+" gold pieces and I will make another 1,000 arrows for you.  By now I have enough [Terranite Ore] in reserve that you can just trade me my requirements to keep my resources up.  Thank you for all your efforts!\"";
+	close;
+
+L_Heathin_Terranite_Arrows_Trade:
+	mes "[Heathin]";
+	mes "\"Hello, there.  If you have "+@TARROW_REQ_COAL+" [Coal], "+@TARROW_REQ_TERRA_ORE+" [Terranite Ore] and "+@TARROW_REQ_GP+" gold pieces, I will trade you 1,000 [Terranite Arrow]s.  Would you like some [Terranite Arrow]s?\"";
+	menu
+		"No.", L_Heathin_Terranite_Arrows_Trade_No,
+		"Yes.", L_Heathin_Terranite_Arrows_Trade_Yes;
+	close;
+
+L_Heathin_Terranite_Arrows_Trade_No:
+	mes "[Heathin]";
+	mes "\"Come back again if you would like to get [Terranite Arrow]s.\"";
+	close;
+
+L_Heathin_Terranite_Arrows_Trade_Yes:
+	if ( (zeny < @TARROW_REQ_GP) | (countitem("Coal") < @TARROW_REQ_COAL) | (countitem("TerraniteOre") < @TARROW_REQ_TERRA_ORE) ) goto L_Heathin_Terranite_Arrows_Trade_Wait;
+	delitem "Coal", @TARROW_REQ_COAL;
+	delitem "TerraniteOre", @TARROW_REQ_TERRA_ORE;
+	set zeny, zeny - @TARROW_REQ_GP;
+	set @lucky, 5 * rand(readparam(bLuk));
+	getitem "TerraniteArrow", 1000 + @lucky;
+	mes "[Heathin]";
+	mes "\"Here you go! You are lucky, I could forge "+@lucky+" more arrows than expected. Come back again if you want more [Terranite Arrow]s.\"";
+	close;
+
+L_Heathin_Terranite_Arrows_Trade_Wait:
+	mes "[Heathin]";
+	mes "\"It seems that you do not have the necessary resources for me to trade you.  Please come back with "+@TARROW_REQ_COAL+" [Coal], "+@TARROW_REQ_TERRA_ORE+" [Terranite Ore] and "+@TARROW_REQ_GP+" gold pieces if you want another 1,000 [Terranite Arrow]s.\"";
+	close;
+
+}
diff --git a/npc/021-2/inya.txt b/npc/021-2/inya.txt
new file mode 100644
index 00000000..4d95bfb0
--- /dev/null
+++ b/npc/021-2/inya.txt
@@ -0,0 +1,174 @@
+//Gemstones: Diamond (white) , Ruby (red), Emerald (green), Sapphire (blue), Topaz (yellow), Amethyst (purple)
+//The power of the gems is important to future balance of these rings.  Are they related to stats, tiers of power, schools of magic?
+
+021-2.gat,43,62,0	script	Inya	106,{
+
+	mes "[Inya]";
+	mes "\"I am Inya, a jeweler of fine rings.  If you have a [Simple Ring] and a gem, I can make a nice ring for you for 1,000,000 gold pieces.\"";
+	next;
+	mes "\"Also, if you have a ring with gems on it, I can remove the gems and return the [Simple Ring] to you for 500,000 gold pieces.\"";
+	next;
+	mes "\"So, how can I help you?\"";
+	menu
+		"I have a wedding ring, will that do?", L_Inya_Wedding_Ring,
+		"I'd like to remove a gem (500000 GP).", L_Inya_Remove_RingGem,
+		"I'd like to add a gem (1000000 GP).", L_Inya_Add_RingGem,
+		"Not interested.", L_Inya_NotInterested;	
+	close;
+
+L_Inya_Wedding_Ring:
+	mes "[Inya]";
+	mes "\"No, sorry.  I do not alter wedding rings at this time.\"";
+	close;
+
+L_Inya_Remove_RingGem:
+	mes "[Inya]";
+	mes "\"What kind of gem would you like to have removed?\"";
+	menu
+		"Diamond.", L_Inya_Remove_Diamond,
+		"Ruby.", L_Inya_Remove_Ruby,
+		"Emerald.", L_Inya_Remove_Emerald,
+		"Sapphire.", L_Inya_Remove_Sapphire,
+		"Topaz.", L_Inya_Remove_Topaz,
+		"Amethyst.", L_Inya_Remove_Amethyst,
+		"I've changed my mind.", L_Inya_NotInterested;
+	close;
+
+L_Inya_Add_RingGem:
+	mes "[Inya]";
+	mes "\"What kind of gem would you like to add?\"";
+	menu
+		"Diamond.", L_Inya_Add_Diamond,
+		"Ruby.", L_Inya_Add_Ruby,
+		"Emerald.", L_Inya_Add_Emerald,
+		"Sapphire.", L_Inya_Add_Sapphire,
+		"Topaz.", L_Inya_Add_Topaz,
+		"Amethyst.", L_Inya_Add_Amethyst,
+		"I've changed my mind.", L_Inya_NotInterested;
+	close;
+
+L_Inya_Remove_Diamond:
+	if ( (zeny < 500000) | (countitem ("RingGemWhite") < 1) ) goto L_Inya_Not_Enough;
+	set zeny, zeny - 500000;
+	delitem "RingGemWhite", 1;
+	getitem "RingSimple", 1;
+	mes "[Inya]";
+	mes "\"Here you go.\"";
+	close;
+
+L_Inya_Remove_Ruby:
+	if ( (zeny < 500000) | (countitem ("RingGemRed") < 1) ) goto L_Inya_Not_Enough;
+	set zeny, zeny - 500000;
+	delitem "RingGemRed", 1;
+	getitem "RingSimple", 1;
+	mes "[Inya]";
+	mes "\"Here you go.\"";
+	close;
+
+L_Inya_Remove_Emerald:
+	if ( (zeny < 500000) | (countitem ("RingGemGreen") < 1) ) goto L_Inya_Not_Enough;
+	set zeny, zeny - 500000;
+	delitem "RingGemGreen", 1;
+	getitem "RingSimple", 1;
+	mes "[Inya]";
+	mes "\"Here you go.\"";
+	close;
+
+L_Inya_Remove_Sapphire:
+	if ( (zeny < 500000) | (countitem ("RingGemBlue") < 1) ) goto L_Inya_Not_Enough;
+	set zeny, zeny - 500000;
+	delitem "RingGemBlue", 1;
+	getitem "RingSimple", 1;
+	mes "[Inya]";
+	mes "\"Here you go.\"";
+	close;
+
+L_Inya_Remove_Topaz:
+	if ( (zeny < 500000) | (countitem ("RingGemYellow") < 1) ) goto L_Inya_Not_Enough;
+	set zeny, zeny - 500000;
+	delitem "RingGemYellow", 1;
+	getitem "RingSimple", 1;
+	mes "[Inya]";
+	mes "\"Here you go.\"";
+	close;
+
+L_Inya_Remove_Amethyst:
+	if ( (zeny < 500000) | (countitem ("RingGemPurple") < 1) ) goto L_Inya_Not_Enough;
+	set zeny, zeny - 500000;
+	delitem "RingGemPurple", 1;
+	getitem "RingSimple", 1;
+	mes "[Inya]";
+	mes "\"Here you go.\"";
+	close;
+
+L_Inya_Add_Diamond:
+	if ( (zeny < 1000000) | (countitem ("RingSimple") < 1) | (countitem ("GemRawWhite") < 1) ) goto L_Inya_Not_Enough;
+	set zeny, zeny - 1000000;
+	delitem "RingSimple", 1;
+	delitem "GemRawWhite", 1;
+	getitem "RingGemWhite", 1;
+	mes "[Inya]";
+	mes "\"Here you go.\"";
+	close;
+
+L_Inya_Add_Ruby:
+	if ( (zeny < 1000000) | (countitem ("RingSimple") < 1) | (countitem ("GemRawRed") < 1) ) goto L_Inya_Not_Enough;
+	set zeny, zeny - 1000000;
+	delitem "RingSimple", 1;
+	delitem "GemRawRed", 1;
+	getitem "RingGemRed", 1;
+	mes "[Inya]";
+	mes "\"Here you go.\"";
+	close;
+
+L_Inya_Add_Emerald:
+	if ( (zeny < 1000000) | (countitem ("RingSimple") < 1) | (countitem ("GemRawGreen") < 1) ) goto L_Inya_Not_Enough;
+	set zeny, zeny - 1000000;
+	delitem "RingSimple", 1;
+	delitem "GemRawGreen", 1;
+	getitem "RingGemGreen", 1;
+	mes "[Inya]";
+	mes "\"Here you go.\"";
+	close;
+
+L_Inya_Add_Sapphire:
+	if ( (zeny < 1000000) | (countitem ("RingSimple") < 1) | (countitem ("GemRawBlue") < 1) ) goto L_Inya_Not_Enough;
+	set zeny, zeny - 1000000;
+	delitem "RingSimple", 1;
+	delitem "GemRawBlue", 1;
+	getitem "RingGemBlue", 1;
+	mes "[Inya]";
+	mes "\"Here you go.\"";
+	close;
+
+L_Inya_Add_Topaz:
+	if ( (zeny < 1000000) | (countitem ("RingSimple") < 1) | (countitem ("GemRawYellow") < 1) ) goto L_Inya_Not_Enough;
+	set zeny, zeny - 1000000;
+	delitem "RingSimple", 1;
+	delitem "GemRawYellow", 1;
+	getitem "RingGemYellow", 1;
+	mes "[Inya]";
+	mes "\"Here you go.\"";
+	close;
+
+L_Inya_Add_Amethyst:
+	if ( (zeny < 1000000) | (countitem ("RingSimple") < 1) | (countitem ("GemRawPurple") < 1) ) goto L_Inya_Not_Enough;
+	set zeny, zeny - 1000000;
+	delitem "RingSimple", 1;
+	delitem "GemRawPurple", 1;
+	getitem "RingGemPurple", 1;
+	mes "[Inya]";
+	mes "\"Here you go.\"";
+	close;
+
+L_Inya_NotInterested:
+	mes "[Inya]";
+	mes "\"Come back later and I will try to be of assistance.\"";
+	close;
+
+L_Inya_Not_Enough:
+	mes "[Inya]";
+	mes "\"I am sorry, you simply do not seem to have the necessary items for me to help you.  Please come back when you do, and I would be more than happy to help you out.\"";
+	close;
+
+}
diff --git a/npc/021-2/jhedia.txt b/npc/021-2/jhedia.txt
new file mode 100644
index 00000000..2677a099
--- /dev/null
+++ b/npc/021-2/jhedia.txt
@@ -0,0 +1,54 @@
+// Ingot maker takes iron ore, gives ingots for future crafting purposes.
+
+021-2.gat,23,55,0	script	Jhedia	160,{
+
+	set @Cost_Per_Ingot, 1000;
+	set @Iron_Ore_Per, 5;
+	set @Coal_Per, 10;
+
+	mes "[Jhedia]";
+	mes "\"I forge [Iron Ore] into ingots.  Ingots are more useful for skilled smiths, like armorers, because the ore is refined and made into useful units which can be worked with.  To make ingots, I need " + @Iron_Ore_Per + " [Iron Ore] and " + @Cost_Per_Ingot + " gp per ingot. I also need " + @Coal_Per + " [Coal] for my forge.\"";
+	next;
+	mes "[Jhedia]";
+	mes "\"How many ingots would you like?\"";
+	input @ingot_count;
+
+	if (@ingot_count == 0) goto L_Jhedia_Bye;
+	set @Zeny_cost, @ingot_count * @Cost_Per_Ingot;
+	if (countitem("IronOre") < @Iron_Ore_Per * @ingot_count) goto L_Jhedia_NotEnough_Ore;
+	if (countitem("Coal") < @Coal_Per * @ingot_count) goto L_Jhedia_NotEnough_Coal;
+	if (zeny < @Zeny_cost) goto L_Jhedia_NotEnough_Zeny;
+	getinventorylist;
+	if (@inventorylist_count == 100 && countitem("IngotIron") == 0 && countitem("IronOre") > @ingot_count * @Iron_Ore_Per | countitem("Coal") > @ingot_count * @Coal_Per) goto L_Jhedia_NotEnoughSlots;
+	set zeny, zeny - @Zeny_cost;
+	delitem "IronOre", @ingot_count * @Iron_Ore_Per;
+	delitem "Coal", @ingot_count * @Coal_Per;
+	getitem "IngotIron", @ingot_count;
+	close;
+
+L_Jhedia_Bye:
+	mes "[Jhedia]";
+	mes "\"Goodbye then.\"";
+	close;
+
+L_Jhedia_NotEnough_Ore:
+	mes "[Jhedia]";
+	mes "\"You do not seem to have enough [Iron Ore].\"";
+	close;
+
+L_Jhedia_NotEnough_Coal:
+	mes "[Jhedia]";
+	mes "\"You do not seem to have enough [Coal].\"";
+	close;
+
+L_Jhedia_NotEnough_Zeny:
+	mes "[Jhedia]";
+	mes "\"You do not seem to have enough gold pieces.\"";
+	close;
+
+L_Jhedia_NotEnoughSlots:
+	mes "[Jhedia]";
+	mes "\"You do not seem to have enough room to carry this many ingots.\"";
+	close;
+
+}
diff --git a/npc/021-2/mapflags.txt b/npc/021-2/mapflags.txt
new file mode 100644
index 00000000..8f4a9dcd
--- /dev/null
+++ b/npc/021-2/mapflags.txt
@@ -0,0 +1,2 @@
+021-2.gat mapflag no_player_drops
+021-2.gat mapflag town
diff --git a/npc/021-2/workshop.txt b/npc/021-2/workshop.txt
new file mode 100644
index 00000000..ffe732b4
--- /dev/null
+++ b/npc/021-2/workshop.txt
@@ -0,0 +1,11 @@
+// Tulimshar's main workshop
+
+// The receptionist
+021-2.gat,22,63,0	script	Sonir	118,{
+	mes "[Sonir]";
+	mes "\"This is Tulimshar's main workshop. Much crafting happens here.\"";
+	next;
+	mes "[Sonir]";
+	mes "\"We also have limited housing on the second floor.\"";
+	close;
+}