Easter 2011

2 files changed, 218 insertions, 0 deletions

diff --git a/npc/008-1_Hurnscald_outskirts/_import.txt b/npc/008-1_Hurnscald_outskirts/_import.txt
index 6520f76d..dc6dcb65 100644
--- a/npc/008-1_Hurnscald_outskirts/_import.txt
+++ b/npc/008-1_Hurnscald_outskirts/_import.txt
@@ -7,3 +7,4 @@ npc: npc/008-1_Hurnscald_outskirts/diryn.txt
 npc: npc/008-1_Hurnscald_outskirts/dock.txt
 npc: npc/008-1_Hurnscald_outskirts/george.txt
 npc: npc/008-1_Hurnscald_outskirts/hinnak.txt
+npc: npc/008-1_Hurnscald_outskirts/bunny.txt
diff --git a/npc/008-1_Hurnscald_outskirts/bunny.txt b/npc/008-1_Hurnscald_outskirts/bunny.txt
new file mode 100644
index 00000000..00c3c9e3
--- /dev/null
+++ b/npc/008-1_Hurnscald_outskirts/bunny.txt
@@ -0,0 +1,217 @@
+//Easter Quest 2011
+//conceived and scripted by Tiana
+//Reviewed by alastrim, Jenalya, Kandiman
+
+
+
+
+008-1.gat,45,23, 0	script	Easter Bunny	173,{
+	set @month, 4;
+	set @start_day, 15;
+	set @end_day, 30;
+
+	if (gettime(6) != @month) goto no_event;
+	if (gettime(5) < @start_day) goto no_event;
+	if (gettime(5) > @end_day) goto no_event;
+	if (gettimetick(2)-TUT_var < 2*7*86400) goto L_TooSoon;
+
+	if (QUEST_Easter11 == 1 || QUEST_Easter11 == 2) goto L_GetBasket;
+	if (QUEST_Easter11 == 3) goto L_BasketCheck;
+	if (QUEST_Easter11 == 4 || QUEST_Easter11 == 5) goto L_GetGrass;
+	if (QUEST_Easter11 == 6) goto L_GrassCheck;
+	if (QUEST_Easter11 == 7 || QUEST_Easter11 == 8) goto L_GetJelly;
+	if (QUEST_Easter11 == 9) goto L_JellyCheck;
+	if (QUEST_Easter11 == 10 || QUEST_Easter11 == 11) goto L_GetChoco;
+	if (QUEST_Easter11 == 12) goto L_ChocoCheck;
+	if (QUEST_Easter11 == 13) goto L_GetPrizes;
+	if (QUEST_Easter11 == 14) goto L_Done;
+	if (BaseLevel < 40) goto L_TooYoung;
+
+	mes "[Easter Bunny]";
+	mes "";
+	mes "\"Hi there!  Would you like to help me with this year's Easter Quest?\"";
+	next;
+
+	menu
+		"What kind of help do you need?", -,
+		"No way, these holiday quests suck.", L_End;
+
+	mes "[Easter Bunny]";
+	mes "";
+	mes "\"I need you to help me by getting an easter basket ready for me.\"";
+	next;
+
+	menu
+		"I should be able to help with that, what do I need to do?", -,
+		"That doesn't sound very exciting, no thanks.", L_End;
+
+	mes "[Easter Bunny]";
+	mes "";
+	mes "\"Thank you! Here is what you need to do:\"";
+	mes "\"I need you to get me a basket, the grass to line it, and some stuff to put in the basket. Some people should be able to help you get those items.\"";
+	next;
+	mes "\"I cannot remember who though. Maybe you should start with the Basket. You should look for someone with good handicraft abilities, someone who knows how to work with reeds... Do you have any idea who could do this? \"";
+	next;
+
+	menu
+		"Ok, I'll ask around and see what I can find.", -,
+		"You can't give me more help than that?  Then go do it yourself.", L_End;
+
+	set QUEST_Easter11, 1;
+	close;
+
+L_GetBasket:
+	mes "[Easter Bunny]";
+	mes "";
+	mes "\"I see that you haven't found anyone who can make the basket yet... hmm... a reed basket... Who could make such an item?\"";
+	set @tip, rand(10);
+	if (@tip != 9) close;
+	next;
+	mes "[Easter Bunny]";
+	mes "";
+	mes "\"Hey... I just remembered. I heard there is an indian fellow living in the mountains who comes from a tribe that is famous for its beautiful craftwork. Maybe he can make the basket...\"";
+	close;
+
+L_BasketCheck:
+	if(countitem("EasterBasket") < 1) goto L_BasketNoitem;
+        delitem "EasterBasket", 1;
+	set QUEST_Easter11, 4;
+	mes "[Easter Bunny]";
+	mes "";
+	mes "\"Very good. This basket is perfect. Now I need some grass to line it. But please, do not pull it from the ground, because it makes the basket really ugly and dirty. I am sure there must be someone who can help you grow a nice, clean patch of grass.\"";
+	close;
+
+L_BasketNoitem:
+	mes "[Easter Bunny]";
+	mes "";
+	mes "\"I heard you talked to that indian in the mountains. That was very smart! But you do not have the basket... That is too bad.\"";
+	close;
+
+L_GetGrass:
+	mes "[Easter Bunny]";
+	mes "";
+	mes "\"I see you didn't find the [Grass Liner]... If only I could help you find someone who can do this...\"";
+	set @tip, rand(10);
+	if (@tip != 9) close;
+	next;
+	mes "[Easter Bunny]";
+	mes "";
+	mes "\"Wait... ohh... Now I remember. Last year there was a woman who helped me with a perfect and clean [Grass Liner] for my easter basket. She used to live near the magic school in Tulimshar. Maybe she is still there.\"";
+	close;
+
+L_GrassCheck:
+	if(countitem("GrassLiner") < 1) goto L_GrassNoitem;
+        delitem "GrassLiner", 1;
+	set QUEST_Easter11, 7;
+	mes "[Easter Bunny]";
+	mes "";
+	mes "\"Perfect. This basket is going to be beautiful. Now I need some stuff to put in the basket. I think we should start with some [Jelly Beans]. But I have no idea where you can find any. I looked in all of Hurnscald's shops and no one sells them! Maybe you will need to find someone who can cook them.\"";
+	close;
+
+L_GrassNoitem:
+	mes "[Easter Bunny]";
+	mes "";
+	mes "\"You talked to Eomie, the woman who maintains that little spot of grass in the desert. You are really smart! But what happened? I was expecting that you would come back with the [Grass Liner]...\"";
+	close;
+
+L_GetJelly:
+	mes "[Easter Bunny]";
+	mes "";
+	mes "\"Hi... Sorry to cause you so much trouble. This candy is so hard to find... One time I tried to make some myself and it was really bad... I'm sure there must be a secret ingredient I didn't know.\"";
+	set @tip, rand(10);
+	if (@tip != 9) close;
+	next;
+	mes "[Easter Bunny]";
+	mes "";
+	mes "\"Hey, maybe you can ask a skilled chef to make some [Jelly Beans] for you.\"";
+	close;
+
+L_JellyCheck:
+	if(countitem("JellyBeans") < 1) goto L_JellyNoitem;
+        delitem "JellyBeans", 1;
+	set QUEST_Easter11, 10;
+	mes "[Easter Bunny]";
+	mes "";
+	mes "\"Ohh. You got a lot of [Jelly Beans]! This is way better than I expected. Now I there is only one more thing that we need... Chocolate! But not the usual [Chocolate Bar].  I need the chocolate shaped in the form of a mouboo. Sadly, I also have no idea how to get it. I am sure that a brilliant person like you can find a way to get it... \"";
+	close;
+
+L_JellyNoitem:
+	mes "[Easter Bunny]";
+	mes "";
+	mes "\"I see you talked with the Chef at Dimond's Cove but you came back with no [Jelly Beans]... What happened?\"";
+	close;
+
+L_GetChoco:
+	mes "[Easter Bunny]";
+	mes "";
+	mes "\"Hello. I was thinking... Maybe someone could melt down some [Chocolate Bar]s and pour it into a mouboo shaped mold...\"";
+	set @tip, rand(10);
+	if (@tip != 9) close;
+	next;
+	mes "[Easter Bunny]";
+	mes "";
+	mes "\"Hmm... A bakery! I am sure there must be someone in a bakery that can do this.\"";
+	close;
+
+L_ChocoCheck:
+	if(countitem("ChocolateMouboo") < 1) goto L_ChocoNoitem;
+        delitem "ChocolateMouboo", 1;
+	set QUEST_Easter11, 13;
+
+L_GetPrizes:
+	mes "[Easter Bunny]";
+	mes "";
+	mes "\"Great, now the basket is perfect!\"";
+	mes "\"I really appreciate your help.  With everyone helping I was able to have enough time to do some crafts.\"";
+	mes "\"Here, accept this simple gift as a thank you!\"";
+	getinventorylist;
+	if (@inventorylist_count == 100) goto L_EasterTooMany;
+	setarray @reward$, "BunnyEars", "TopHat", "MushHat", "ShroomHat", "FunkyHat";
+	getitem @reward$[rand(getarraysize(@reward$))], 1;
+	set QUEST_Easter11, 14;
+	close;
+
+L_ChocoNoitem:
+	mes "[Easter Bunny]";
+	mes "";
+	mes "\"Some people told me you were in a bakery in Tulimshar... I was hoping you would come back with the [Chocolate Mouboo].\"";
+	close;
+
+L_TooYoung:
+	mes "[Easter Bunny]";
+	mes "";
+	mes "\"Hello there young one!\"";
+	mes "\"Gain some more strength and I have a quest for you.\"";
+	close;
+
+L_TooSoon:
+	mes "[Easter Bunny]";
+	mes "";
+	mes "\"Hello there!\"";
+	mes "\"I need some help with Easter this year,\"";
+	mes "\"however you are not experienced enough in this world to properly assist yet.\"";
+	mes "\"Thank you for your interest though!\"";
+	close;
+
+L_EasterTooMany:
+	mes "[Riskim]";
+	mes "";
+	mes "\"You don't have enough room for my gift. Come back later.\"";
+	close;
+
+L_Done:
+	mes "[Easter Bunny]";
+	mes "";
+	mes "\"Thank you for getting that basket together for me!\"";
+	close;
+
+no_event:
+	mes "[Easter Bunny]";
+	mes "";
+	mes "\"Easter is the greatest holiday ever!!!\"";
+	set QUEST_Easter11, 0;
+	close;
+
+L_End:
+	close;
+}