path: root/world/map/npc/048-2/helperCleaning5.txt

// Part of Blue Sage quests
// author: Jenalya
// see bluesageConfig for detailed quest description
// Mirjami is searching for some cleaning supplies
// can give second hint about visitor in investigation subquest

048-2,100,125,0|script|Mirjami|363
{
    set @slimes, ((QUEST_BlueSage & $@Q_BlueSageSlimes_MASK) >> $@Q_BlueSageSlimes_SHIFT);

    if (@slimes == 255) goto L_Thank;

    mes "[Mirjami]";
    mes "\"Where is it? Everything's upside down. These terrible slimes.\"";
    menu
        "What are you doing?",L_Next;

L_Next:
    mes "[Mirjami]";
    mes "\"Oh? I'm just searching for some cleaning supplies. They must be somewhere around here, but everything went upside down when the slimes escaped.\"";
    goto L_Investigate;

L_Thank:
    mes "[Mirjami]";
    mes "\"I heard you fought the slimes that were still roaming between the bookshelves. Thank you!\"";
    next;
    mes "\"I was a bit worried that they might ruin our efforts by messing everything up again after we just cleaned.\"";
    goto L_Investigate;

L_Investigate:
    if ((QL_BSAGE_INVESTIGATE == 3) || (QL_BSAGE_INVESTIGATE == 4)) goto L_Ask_Visitor;
    if ((QL_BSAGE_INVESTIGATE == 5) || (QL_BSAGE_INVESTIGATE == 8)) goto L_Ask_Helper;
    if ((QL_BSAGE_INVESTIGATE == 6) || (QL_BSAGE_INVESTIGATE == 7) || (QL_BSAGE_INVESTIGATE == 9) || (QL_BSAGE_INVESTIGATE == 10)) goto L_Ask_Both;
    goto L_Close;

L_Ask_Visitor:
    menu
        "Can you tell me anything about the visitor with the mask?",L_Visitor,
        "I need to leave.",L_Close;

L_Ask_Helper:
    menu
        "What's your opinion of Peetu and how he does his work?",L_Helper,
        "See you later.",L_Close;

L_Ask_Both:
    menu
        "Can you tell me anything about the visitor with the mask?",L_Visitor,
        "What's your opinion of Peetu and how he does his work?",L_Helper,
        "Bye.",L_Close;

L_Visitor:
    mes "[Mirjami]";
    mes "\"Ohh, I think I know who you mean. That was a strange guy. He always came over here in the workshop, said he's very interested in the research. I suppose that's ok, but he didn't keep his hands to himself, and touched some experiments and I caught him near some storage racks.\"";
    next;
    mes "\"Visitors should keep away from those!\"";
    if ((QL_BSAGE_INVESTIGATE != 3) && (QL_BSAGE_INVESTIGATE != 6) && (QL_BSAGE_INVESTIGATE != 9))
        goto L_Close;
    set QL_BSAGE_INVESTIGATE, QL_BSAGE_INVESTIGATE + 1;
    goto L_Close;

L_Helper:
    mes "[Mirjami]";
    mes "\"Oh, eh, why are you asking me? I've only been here a short while and don't really know all of the people well enough yet.\"";
    goto L_Close;

L_Close:
    set @slimes, 0;
    close;
}