path: root/world/map/npc/001-1/adrian.txt

001-1,113,64,0|script|Adrian|213
{
    mes "[Adrian]";
    mes "\"Hello. Are you here to pick up some luggage?\"";
    if (QL_KYLIAN == 1)
        menu
            "Yes. Kylian sent me to get his luggage.",L_Get,
            "No.",L_No;
    menu
        "No.",L_No;
L_No:
    next;
    mes "[Adrian]";
    mes "\"Too bad. I'd like to go get a beer, but I have to wait here until all the luggage is picked up.\"";
    mes "He sighs.";
    goto L_Close;

L_Get:
    next;
    mes "[Adrian]";
    mes "\"Wonderful! Please show me your ticket.\"";
    mes "He checks the paper Kylian gave you and then gives you a critical look.";
    next;
    getinventorylist;
    if ((checkweight("LeatherSuitcase", 1) == 0) || (@inventorylist_count == 100))
        goto L_Inventory;
    mes "[Adrian]";
    mes "\"Alright. Here it is. Good luck carrying that thing.\"";
    mes "Adrain hands you a very heavy suitcase.";
    getitem "LeatherSuitcase", 1;
    set QL_KYLIAN, 2;
    goto L_Close;

L_Inventory:
    mes "[Adrian]";
    mes "\"The suitcase is rather heavy. No offense, but you don't look like you can carry it.\"";
    mes "Maybe you should get rid of some of the other stuff you're carrying.\"";
    goto L_Close;

L_Close:
    set @inventorylist_count, 0;
    close;
}