path: root/npc/003-1/mahoud.txt

// Author:
//    Saulc
//    Jesusalva

003-1,46,79,0	script	Mahoud	NPC_PLAYER,{

    .@COST_PER_BOTTLE = 50;

    mes l("I can fill your bottle with water for only @@ gp the bottle.", .@COST_PER_BOTTLE);
    mes l("After all, I am the Well Master!");
    input .@count;

    if (.@count == 0)
        close;
    .@Cost = .@count * .@COST_PER_BOTTLE;
    .@empty = countitem("EmptyBottle");

    if (.@empty < .@count)
        goto L_NotEnoughBottles;
    if (Zeny < .@Cost)
        goto L_NotEnoughMoney;
    getinventorylist;
    if (@inventorylist_count == 100
        && countitem("BottleOfSweaWater") == 0
        && .@empty > .@count)
            goto L_NotEnoughSlots;

    set Zeny, Zeny - .@Cost;
    delitem "EmptyBottle", .@count;
    getitem "BottleOfSweaWater", .@count; // TODO FIXME: "Swea" water? Also, this is not sea water...
    close;

L_NotEnoughBottles:
    mes l("You don't have that many empty bottles!");
    close;

L_NotEnoughMoney:
    mes l("You don't have enough gp! You need @@ gp.", .@Cost);
    close;

L_NotEnoughSlots:
    mes l("You don't have room for these bottles!");
    close;

OnInit:
    .sex = G_MALE;
    .distance = 7;

    .@npcId = getnpcid(0, "Mahoud");
    // Check items.xml for info about this
    setunitdata(.@npcId, UDT_HEADTOP, 2906);
    setunitdata(.@npcId, UDT_HEADMIDDLE, 1304);
    setunitdata(.@npcId, UDT_HEADBOTTOM, 2201);
    setunitdata(.@npcId, UDT_HAIRSTYLE, 7);
    setunitdata(.@npcId, UDT_HAIRCOLOR, 17);

    end;
}