1 files changed, 116 insertions, 0 deletions
diff --git a/npc/024-1/erlan.txt b/npc/024-1/erlan.txt
new file mode 100644
index 000000000..05f14ce56
--- /dev/null
+++ b/npc/024-1/erlan.txt
@@ -0,0 +1,116 @@
+// TMW2 scripts.
+// Authors:
+//    Jesusalva
+// Description:
+//    Questmaker Handbook 14.0 (F = Favorable)
+
+024-1,114,45,0	script	Erlan	NPC_ELF,{
+    .@q = getq(FrostiaQuest_Erlan);
+    if (BaseLevel < 50) {
+        mesc l("The elf seems busy. He ignores you.");
+        close;
+    }
+    if (.@q == 0) {
+        if (frally()) goto L_Start_F;
+        else goto L_Start_U;
+    }
+    else if (.@q == 1) {
+        if (frally()) goto L_Submit_F;
+        else goto L_Submit_U;
+    }
+    else if (.@q == 2) {
+        if (frally()) goto L_Done_F;
+        else goto L_Done_U;
+    }
+    Exception("Invalid quest state - "+str(.@q));
+    end;
+
+L_Start_F:
+    mesn;
+    mesq lg("Hey gal, could you do me a little favor?", "Hey pal, could you do me a little favor?");
+    next;
+    mesn;
+    mesq l("You see, I am Erlan, a researcher. I'm currently developing strong poison to rival with the legendary %s. For that end, I need raw, untreated sewerage, but there is no such thing here. Could you bring me %d %s? Thanks!", getitemlink(NymphPoison), 7, getitemlink(BottleOfSewerWater));
+    setq FrostiaQuest_Erlan, 1;
+    close;
+
+L_Submit_F:
+    mesn;
+    mesq l("Did you got the %d %s I've asked?", 7, getitemlink(BottleOfSewerWater));
+    next;
+    if (askyesno() == ASK_YES) {
+        if (countitem(BottleOfSewerWater) < 7) {
+            mesn;
+            mesq l("You've been spending too much time with humans. You are picking up bad habits from them like lying. Be careful.");
+            close;
+        }
+        delitem BottleOfSewerWater, 7;
+        getexp 24000, 0;
+        setq FrostiaQuest_Erlan, 2;
+        mesn;
+        mesq lg("Thanks, my friend.");
+    }
+    close;
+
+L_Done_F:
+    mesn;
+    mesq l("Thanks for the help earlier. Unfortunately, I had no luck yet.");
+    next;
+    mesn;
+    mesq l("There are rumors about a sacred elf land, where our antecessors lived in peacefully somewhere close to here, but the path was lost. That's why we now live with dwarves.");
+    close;
+/////////////////////////////////////////////////////////////////////////////////
+L_Start_U:
+    mesn;
+    mesq l("Uh, a %s? How odd.", get_race());
+    next;
+    mesn;
+    mesq l("You see, I am Erlan, a researcher. I'm currently developing strong poison to rival with the legendary %s. For that end, I need raw, untreated sewerage, but there is no such thing in a civilized town like ours.", getitemlink(NymphPoison));
+    next;
+    mesn;
+    mesq l("But you seem to have come from more savage and barbaric towns, so if you could bring me %d %s, that would be truly helpful.", 7, getitemlink(BottleOfSewerWater));
+    setq FrostiaQuest_Erlan, 1;
+    close;
+
+L_Submit_U:
+    mesn;
+    mesq l("Did you got the %d %s I've asked?", 7, getitemlink(BottleOfSewerWater));
+    next;
+    if (askyesno() == ASK_YES) {
+        if (countitem(BottleOfSewerWater) < 7) {
+            mesn;
+            mesq l("You think you can fool me and lie? I'll teach you a lesson you won't forget!");
+            mesc l("%s slaps you!", .name$);
+            percentheal -30, 0;
+            close;
+        }
+        delitem BottleOfSewerWater, 7;
+        getexp 24000, 0;
+        setq FrostiaQuest_Erlan, 2;
+        mesn;
+        mesq l("Heh, thanks %s.", get_race());
+    }
+    close;
+
+L_Done_U:
+    mesn;
+    mesq l("No, I don't have any poison for your sampling yet.");
+    next;
+    mesn;
+    mesq l("Our antecessors used to live peacefully in a sanctuary somewhere close to here, but the path was lost. That's why we now live with dwarves.");
+    close;
+
+OnInit:
+    .@npcId = getnpcid(.name$);
+    setunitdata(.@npcId, UDT_HEADBOTTOM, CottonTrousers);
+    setunitdata(.@npcId, UDT_HEADMIDDLE, LeatherShirt);
+    setunitdata(.@npcId, UDT_HEADTOP, Beard);
+    setunitdata(.@npcId, UDT_HAIRSTYLE, 26);
+    setunitdata(.@npcId, UDT_HAIRCOLOR, 3);
+    npcsit;
+
+    .sex = G_MALE;
+    .distance = 5;
+    end;
+}
+