1 files changed, 124 insertions, 0 deletions
diff --git a/npc/012-4/wyara.txt b/npc/012-4/wyara.txt
new file mode 100644
index 000000000..a287a5128
--- /dev/null
+++ b/npc/012-4/wyara.txt
@@ -0,0 +1,124 @@
+// TMW2 Script
+// Author:
+//    Saulc
+//    Vasily_Makarov (original from Evol)
+//    Jesusalva
+// Description:
+//    Still Unused NPC
+// Notes:
+//    Reset must be turned in function
+
+012-4,29,28,0	script	Wyara	NPC_FEMALE,{
+
+    speech S_LAST_NEXT,
+        l("I am @@, an alchemist specialized in reset potions.", .name$);
+
+L_Menu:
+    .@plush_count = BaseLevel*210-(10*210);
+    // Lv 10: 210 GP
+    if (BaseLevel > 10)
+        .@plush_count = .@plush_count/(BaseLevel/10);
+
+    select
+        l("Can you reset my stats please?"),
+        rif($ARKIM_ST >= 1200,l("I want Piberries Infusion!")),
+        lg("You are weird, I have to go sorry.");
+
+    mes "";
+    switch (@menu) {
+        case 1:
+            goto L_ResetStats;
+        case 2:
+            goto L_Piberries;
+        case 3:
+            goto L_Quit;
+    }
+
+L_ResetStats:
+    mesn;
+    mesq l("Status point reset can't be undone. Do you really want this?");
+
+L_ConfirmReset:
+    switch (select(lg("Yes, I am sure."),
+                   lg("I need to think about it..."),
+                   lg("I won't need it, thank you.")))
+    {
+        case 1:
+            speech S_FIRST_BLANK_LINE | S_LAST_NEXT,
+                l("Let me just have a quick look at you. Hm... I will need @@ GP to reset your stats.", .@plush_count);
+
+            select
+                rif(Zeny >= .@plush_count, l("Here, take as much as you need, I have plenty!")),
+                rif(Zeny > 0 && Zeny < .@plush_count, l("I don't have enough money...")),
+                rif(Zeny == 0, l("Oh no, I don't have any money on me right now.")),
+                l("I have to go, sorry.");
+
+            if (@menu > 1) {
+                goto L_Quit;
+            }
+
+            // TODO: I think there were functions to deal with GP
+            set Zeny, Zeny-.@plush_count;
+
+            speech S_FIRST_BLANK_LINE | S_LAST_NEXT,
+                l("Thank you."),
+                l("Now stand still... It should not take much time...");
+
+            .@wasSP = StatusPoint;
+            resetstatus;
+            if (StatusPoint == .@wasSP) {
+                speech S_LAST_NEXT,
+                    l("It seems that you have no status points to reset!"),
+                    l("But the money you brought was really awesome you know."),
+                    l("Come back when you will really need me.");
+            } else {
+                speech S_LAST_NEXT,
+                    l("Let's see... @@ of your status points have just been reset!", StatusPoint - .@wasSP),
+                    l("Spend it wisely this time."),
+                    l("But you are welcome to reset your stats again! I need the money.");
+            }
+            goto L_Quit;
+
+        case 2:
+            goto L_Quit;
+        case 3:
+            goto L_Quit;
+    }
+
+
+L_Piberries:
+    mesn;
+    mesq l("For (another) one @@, I'll need 3~4 @@ and 50 GP.", getitemlink(PiberriesInfusion), getitemlink(Piberries));
+    next;
+    select
+        rif(Zeny >= 50 && countitem(Piberries) >= 4, l("Do it!")),
+        l("Not now, sorry.");
+    if (@menu == 2)
+        goto L_Quit;
+
+    mes "";
+    inventoryplace PiberriesInfusion, 1;
+
+    Zeny=Zeny-50;
+    delitem Piberries, rand(3,4);
+    getitem PiberriesInfusion, 1;
+    getexp 10, 0;
+    goto L_Piberries;
+
+L_Quit:
+    goodbye;
+    close;
+
+OnInit:
+    .@npcId = getnpcid(0, .name$);
+    setunitdata(.@npcId, UDT_HEADTOP, FancyHat);
+    setunitdata(.@npcId, UDT_HEADMIDDLE, SailorShirt);
+    setunitdata(.@npcId, UDT_HEADBOTTOM, BromenalPants);
+    setunitdata(.@npcId, UDT_WEAPON, LousyMoccasins); // Boots
+    setunitdata(.@npcId, UDT_HAIRSTYLE, 8);
+    setunitdata(.@npcId, UDT_HAIRCOLOR, 18);
+
+    .sex = G_FEMALE;
+    .distance = 4;
+    end;
+}