path: root/npc/magic/cuteheart.txt

// TMW2 script
// Author: Jesusalva <admin@tmw2.org>
//
// Magic Script: TMW2_CUTEHEART
//
// Summons mouboo

-	script	sk#cuteheart	32767,{
    end;

OnCall:
    // Other requeriments: 1x WhiteFur
    if (countitem(WhiteFur) < 1) {
        dispbottom l("You need 1x @@ to cast this skill.", getitemlink(WhiteFur));
        end;
    }

    // Check cooldown
    if (@cuteheart_at > gettimetick(2)) {
        dispbottom l("Skill is in cooldown for @@.", FuzzyTime(@cuteheart_at));
        end;
    }

    // Setup
    @sk=TMW2_CUTEHEART;
    @mp=235;
    @amp=45;

    // Check if you have mana to cast
    // MagicCheck(SkillID, Mana{, MP per level})
    if (!MagicCheck(@sk, @mp, @amp))
        end;

    // Destroy reagents
    delitem WhiteFur, 1;

    // set cooldown
    @cuteheart_at=gettimetick(2);
    @cuteheart_at=@cuteheart_at+44;

    // As usual, magic profeciency affects success ratio
    if (rand(1,6) < abizit()+1) {
        .@mobId=Fluffy;
        // Summon Magic
        // SummonMagic(SkillID, MobID{, SkillLevelPerMob=2{, Level Override}})
        SummonMagic(@sk, .@mobId, 4, MAGIC_LVL+getskilllv(@sk)-1);
    } else {
        dispbottom l("The spell fails!");
    }

    // Get 4~5 mana experience point (this is NOT used by Mana Stone)
    GetManaExp(@sk, rand(4,5));

    end;

OnInit:
    bindatcmd "sk-cuteheart", "sk#cuteheart::OnCall", 0, 100, 0;
    end;
}