path: root/npc/functions/treasure.txt

// TMW2 functions.
// Author:
//    Jesusalva
// Description:
//    Random Treasure Box Utils

function	script	TreasureBox	{
        mesc l("Open the chest?");
        mesc l("Cost: 1 @@", getitemlink(TreasureKey)), 1;
        if (!countitem(TreasureKey))
            close;
        next;
        if (askyesno() == ASK_NO)
            close;

        delitem TreasureKey, 1;
        mesc l("You open the chest!");

        .@empty=getvariableofnpc(.empty, strnpcinfo(0));
        if (!.@empty) {
            TREASURE_OPEN=TREASURE_OPEN+1;
            .@t=TREASURE_OPEN;
            .@r=rand(0,10000);

            // Select treasure list
            // You're warranted an ultra rare (0.1%) every 149 open chests
            // You're warranted a super rare (1%) every 50 open chests
            // There's also rares (10%), uncommons (40%) and commons (60%)
            .@ur_rate=min(10, (TREASURE_OPEN/10));
            if (.@t % 149 == 0 || .@r < .@ur_rate)
                .@loot=any(AtroposMixture, GoldenApple, DivineApple, MercBoxA, SilverGift, Shemagh, EverburnPowder, IridiumOre, PlatinumOre);
            else if (.@t % 50 == 0 || .@r < 100)
                .@loot=any(Grenade, SnakeEgg, LachesisBrew, ArrowAmmoBox, CoinBag, BronzeGift, TerraniteOre, LeadOre, TinOre, SilverOre, GoldOre, TitaniumOre, FluoPowder);
            else if (.@r < 1000)
                .@loot=any(MoubooSteak, ClothoLiquor, Coal, SmallMushroom, HastePotion, StrengthPotion, Dagger, StrangeCoin, IronOre, CopperOre);
            else if (.@r < 4000)
                .@loot=any(Croconut, Potatoz, MoubooSteak, ClothoLiquor, Coal, SmallMushroom, HastePotion, StrengthPotion, StrangeCoin);
            else
                .@loot=any(FatesPotion, ChocolateBar, Plushroom, Chagashroom, RawLog, LeatherPatch, BugLeg, ScorpionStinger, SmallKnife);


            inventoryplace .@loot, 1;
            mesc l("You find @@ inside!", getitemlink(.@loot));
            getitem .@loot, 1;
        } else {
            mesc l("You find @@ inside!", l("nothing"));
        }

}