path: root/npc/functions/game-rules.txt

// Evol scripts.
// Authors:
//    gumi
//    Qwerty Dragon
//    Reid
//    WildX
//    Jesusalva
// Description:
//    Main Rules of TMW2.

function	script	GameRules	{
    if (checkweight(BookOfLaws, 1) == true && countitem(BookOfLaws) < 1)
        getitem BookOfLaws, 1; // give the book if the player lost it

    narrator getarg(0, 0),
        l("1. ##BDo not bot nor multibox##b, this means you are not allowed to perform any AFK (away from keyboard) activity, apart from standing idle. And you are not allowed to engage in combat while controlling more than one character at a time, either."),
        l("2. ##BDo not use offensive/rude language##b in the chats or in your character(s) name(s)."),
        l("3. ##BDo not spam/flood other players.##b This includes chat spam and spam by trade requests."),
        l("4. ##BPrefer English in public areas.##b You can speak whatever language you want through whispers or whenever everyone in the area can speak said language. But otherwise, prefer english."),
        l("5. ##BDo not beg others##b for money, items or favours of any kind. If you want to ask for something, do it politely and only once. Try not to annoy other players."),
        l("6. ##BFollow the [@@http://wiki.evolonline.org/rules/esc|ESC@@]##b (Evol Social Convention)."),
        l("7. ##BAs long as you have an account, you agree with the [@@https://gitlab.com/TMW2/TheManaWorld_Wiki/wikis/Rules|Terms Of Service@@]##b. Shall any rule conflict with these terms, the Terms Of Service provided on that link shall prevail.");
    return;
}


-	script	@rules	32767,{
    end;

    function read_book {
        narrator S_FIRST_BLANK_LINE | S_LAST_NEXT,
            l("This book outlines the laws which applies everywhere in the World Of Mana."),
            l("The first page contains the universal rules that have been agreed upon throughout the land.");

        GameRules S_NO_NPC_NAME | S_LAST_NEXT;

        narrator S_NO_NPC_NAME,
            l("The next page begins to list the complex trading laws and political rules."),
            l("All this seems unimportant to you right now.");
        close;
    }

OnCall:
    GameRules;
    close;

OnUseBook:
    if (openbook())
        read_book;
    bye;

OnShelfUse:
    if (openbookshelf())
        read_book;
    bye;

OnInit:
    .book_name$ = "The Book of Laws";
    bindatcmd "rules", "@rules::OnCall", 0, 2, 0;
}