path: root/npc/024-5/saevel.txt

// TMW2 scripts.
// Authors:
//    Jesusalva
// Description:
//    Questmaker Handbook 14.0 (F = Favorable)

024-5,38,23,0	script	Saevel	NPC_ELF,{
    .@q = getq(FrostiaQuest_Saevel);
    if (BaseLevel < 47) {
        mesc l("The elf seems busy. He ignores you.");
        close;
    }
    if (.@q == 0) {
        if (frally()) goto L_Start_F;
        else goto L_Start_U;
    }
    else if (.@q == 1) {
        if (frally()) goto L_Submit_F;
        else goto L_Submit_U;
    }
    else if (.@q == 2) {
        if (frally()) goto L_Done_F;
        else goto L_Done_U;
    }
    Exception("Invalid quest state - "+str(.@q));
    end;

L_Start_F:
    mesn;
    mesq l("I'm am about to make myself some powerful equipment... But I ran out of material to refine it!");
    next;
    mesn;
    mesq l("Could you, perhaps, bring me %d %s? That'll help me to finish this.", 1, getitemlink(Arcanum));
    setq FrostiaQuest_Saevel, 1;
    close;

L_Submit_F:
    mesn;
    mesq l("Did you got the %d %s I've asked?", 1, getitemlink(Arcanum));
    next;
    if (askyesno() == ASK_YES) {
        if (countitem(Arcanum) < 1) {
            mesn;
            mesq l("You've been spending too much time with humans. You are picking up bad habits from them like lying. Be careful.");
            close;
        }
        inventoryplace EquipmentBlueprintB, 1, EquipmentBlueprintA, 1;
        delitem Arcanum, 1;
        getexp 7000, 0;
        getitem EquipmentBlueprintB, 1;
        getitem EquipmentBlueprintA, 1;
        setq FrostiaQuest_Saevel, 2;
        mesn;
        mesq l("Muahahaha, I'll be SO strong thanks to you! Here, I don't need these weak recipes anymore. You can have them!");
    }
    close;

L_Done_F:
    mesn;
    mesq l("POWER!");
    next;
    mesn;
    mesq l("Reminds me, but they say the Aethyr is a place where powerful elves of old live. But nobody has been there on the past century... Or if they were, nobody said anything about it! Hahahah!");
    close;
/////////////////////////////////////////////////////////////////////////////////
L_Start_U:
    mesn;
    mesq l("I'm am about to make myself some powerful equipment... But I ran out of material to refine it!");
    next;
    mesn;
    mesq l("Could you bring me %d %s? That'll help me to finish this.", 1, getitemlink(Arcanum));
    setq FrostiaQuest_Saevel, 1;
    close;

L_Submit_U:
    mesn;
    mesq l("Did you got the %d %s I've asked?", 1, getitemlink(Arcanum));
    next;
    if (askyesno() == ASK_YES) {
        if (countitem(Arcanum) < 1) {
            mesn;
            mesq l("You liar, I'll teach you a lesson you won't forget!");
            mesc l("%s slaps you!", .name$);
            percentheal -30, 0;
            close;
        }
        inventoryplace EquipmentBlueprintB, 1, EquipmentBlueprintA, 1;
        delitem Arcanum, 1;
        getexp 7000, 0;
        getitem EquipmentBlueprintB, 1;
        getitem EquipmentBlueprintA, 1;
        setq FrostiaQuest_Saevel, 2;
        mesn;
        mesq l("Muahahaha, I'll be SO strong thanks to you! Here, these recipes should be useful for ya. You can have them!");
    }
    close;

L_Done_U:
    mesn;
    mesq l("POWER!");
    next;
    mesn;
    mesq l("Reminds me, but they say the Aethyr is a place where powerful elves of old live. But nobody has been there on the past century... Or if they were, nobody said anything about it! Hahahah!");
    close;

OnInit:
    .@npcId = getnpcid(.name$);
    setunitdata(.@npcId, UDT_HEADBOTTOM, BromenalPants);
    setunitdata(.@npcId, UDT_HEADMIDDLE, GoldenWarlordPlate);
    setunitdata(.@npcId, UDT_HEADTOP, SamuraiHelmet);
    setunitdata(.@npcId, UDT_HAIRSTYLE, 2);
    setunitdata(.@npcId, UDT_HAIRCOLOR, 8);

    .sex = G_MALE;
    .distance = 5;
    end;
}