path: root/npc/024-1/taenya.txt

// TMW2 scripts.
// Authors:
//    Jesusalva
// Description:
//    Questmaker Handbook 14.0 (F = Favorable)

024-1,58,28,0	script	Taenya	NPC_ELF_F,{
    .@q = getq(FrostiaQuest_Taenya);
    if (BaseLevel < 52) {
        mesc l("The elf seems busy. She ignores you.");
        close;
    }
    if (.@q == 0) {
        if (frally()) goto L_Start_F;
        else goto L_Start_U;
    }
    else if (.@q == 1) {
        if (frally()) goto L_Submit_F;
        else goto L_Submit_U;
    }
    else if (.@q == 2) {
        if (frally()) goto L_Done_F;
        else goto L_Done_U;
    }
    Exception("Invalid quest state - "+str(.@q));
    end;

L_Start_F:
    mesn;
    mesq lg("Hey friend, could you do me a little favor?");
    next;
    mesn;
    mesq l("I always wanted to taste a %s! But they don't grow anywhere, and I've heard the only way to obtain one is from %s. Unfortunately, I do not favor violence, so... Could you get one for me?", getitemlink(Manapple), getitemlink(BronzeBossGift));
    next;
    mesn;
    mesq l("Thanks, I owe you one!");
    setq FrostiaQuest_Taenya, 1;
    close;

L_Submit_F:
    mesn;
    mesq l("Did you got the %d %s I've asked?", 1, getitemlink(Manapple));
    next;
    if (askyesno() == ASK_YES) {
        if (countitem(Manapple) < 1) {
            mesn;
            mesq l("You've been spending too much time with humans. You are picking up bad habits from them like lying. Be careful.");
            close;
        }
        inventoryplace EquipmentBlueprintC, 1;
        delitem Manapple, 1;
        getitem EquipmentBlueprintC, 1;
        getexp 12000, 0;
        setq FrostiaQuest_Taenya, 2;
        mesn;
        mesq l("Yay! Many thanks! I'll enjoy it! Here, you can keep this.");
    }
    close;

L_Done_F:
    mesn;
    mesq l("Hey, the %s you gave me was quite tasty, thanks!", getitemlink(Manapple));
    next;
    mesn;
    mesq l("%s is known as the Wizard of Aethyr. They say the elves which lived in Aethyr have became fairies, but contact has been lost long ago... I've heard it was a very pretty town north of here, though.", b("Tametomo"));
    close;
/////////////////////////////////////////////////////////////////////////////////
L_Start_U:
    mesn;
    mesq l("Hey %s, could you do me a little favor?", get_race());
    next;
    mesn;
    mesq l("I always wanted to taste a %s! But they don't grow anywhere, and I've heard the only way to obtain one is from %s. Unfortunately, I do not favor violence, so... Could you get one for me?", getitemlink(Manapple), getitemlink(BronzeBossGift));
    next;
    mesn;
    mesq l("I'll be waiting!");
    setq FrostiaQuest_Taenya, 1;
    close;

L_Submit_U:
    mesn;
    mesq l("Did you got the %d %s I've asked?", 1, getitemlink(Manapple));
    next;
    if (askyesno() == ASK_YES) {
        if (countitem(Manapple) < 1) {
            mesn;
            mesq l("You liar, I'll teach you a lesson you won't forget!");
            mesc l("%s stabs you with a dagger!", .name$);
            percentheal -55, 0;
            close;
        }
        inventoryplace EquipmentBlueprintC, 1;
        delitem Manapple, 1;
        getitem EquipmentBlueprintC, 1;
        getexp 12000, 0;
        setq FrostiaQuest_Taenya, 2;
        mesn;
        mesq l("Thanks! I'll enjoy it! Here, you can keep this.");
    }
    close;

L_Done_U:
    mesn;
    mesq l("Sorry, but I already ate the %s you gave me!", getitemlink(Manapple));
    next;
    mesn;
    mesq l("%s is known as the Wizard of Aethyr. They say the elves which lived in Aethyr have became fairies, but contact has been lost long ago... I've heard it was a very pretty town north of here, though.", b("Tametomo"));
    close;

OnInit:
    .@npcId = getnpcid(.name$);
    setunitdata(.@npcId, UDT_HEADBOTTOM, CottonSkirt);
    setunitdata(.@npcId, UDT_HEADMIDDLE, LeatherShirt);
    setunitdata(.@npcId, UDT_HEADTOP, TrapperHat);
    setunitdata(.@npcId, UDT_HAIRSTYLE, 9);
    setunitdata(.@npcId, UDT_HAIRCOLOR, 18);
    npcsit;

    .sex = G_FEMALE;
    .distance = 5;
    end;
}