path: root/npc/020-3/mede.txt

// TMW2 Script
// Author:
//    Saulc
//    Vasily_Makarov (original from Evol)
//    Jesusalva
// Dye Quest added by Povo
// Description:
//    Status Reset

020-3,26,28,2	script	Mede	NPC_PLAYER,{

    speech S_LAST_NEXT,
        l("I am @@, an alchemist specialized in reset potions.", .name$);

L_Menu:
    .@plush_count = BaseLevel*220-(9*220);
    // Lv 10: 220 GP
    // Lv 90: 1.782 GP
    if (BaseLevel > 10)
        .@plush_count = .@plush_count/(BaseLevel/9);

    select
        l("Can you reset my stats please?"),
        rif(MONSTERPOT >= 1, l("Can you make me a Monster Potion?")),
         l("Do you make anything else?"),
        lg("You are weird, I have to go sorry.");

    switch (@menu)
    {
        case 1:
            goto L_ResetStats;
        case 2:
            goto L_MonsterPot;
        case 3:
            goto L_Dye; 
        case 4:
            goto L_Quit;
    }

L_ResetStats:
    mesn;
    mesq l("Status point reset can't be undone. Do you really want this?");

L_ConfirmReset:
    ConfirmStatusReset();
    goto L_Quit;

L_MonsterPot:
    mesn;
    mesq l("Not yet, I'm waiting @@ to deliver me the @@ reagent.", any("Saulc", "Jesusalva", "Demure"), any(l("Red"), l("Green"), l("Blue"), l("White")));
    next;
    mesn;
    mesq l("But if you want, you can farm @@ already. Good luck!", getitemlink(GoldenScorpionClaw));
    next;
    goto L_Quit;

L_Dye:
    mesn;
    mesq l("I used to make dyes for Agostine but he hasn't bought any in a while. I could make you a %s if you bring me the right items.", 
                      getitemlink(TealDye));
    next;
    if (BaseLevel < 35) {
        mesn;
        mesq l("But the monsters around here must be pretty scary for someone like you.");
        next;
        mesq l("Come back when you are a higher level.");
        next;
        goto L_Menu;
    }
    mesq l("Bring me %d %s, %d %s, %d %s, and %d %s, and I will make it for you. I also charge %d GP as commission.",
                      1, getitemlink(IcedBottle),
                      25, getitemlink(BlueCoral),
                      60, getitemlink(CobaltHerb), 
                      5, getitemlink(IceCube),
                      1500); 
    compareandsetq NivalisQuest_Mede, 0, 1;
    next;
    select
        l("Yeah, I need one."),
        l("Thanks for the help, but no."),
        l("Actually, nevermind. Good bye!");
    mes "";
    if (@menu == 2)
        goto L_Menu;

    if (@menu == 3)
        goto L_Quit;

L_DyeLoop:
    if (countitem(IcedBottle) >= 1 &&
          countitem(BlueCoral) >= 25 &&
          countitem(CobaltHerb) >= 60 &&
          countitem(IceCube) >= 5 &&
          Zeny >= 1500) {
        inventoryplace TealDye, 1, EmptyBottle, 1;
        delitem IcedBottle, 1;
        delitem BlueCoral, 25;
        delitem CobaltHerb, 60;
        delitem IceCube, 5;
        Zeny-=1500;
        getitem TealDye, 1;
        getitem EmptyBottle, 1;
        if (getq(NivalisQuest_Mede) == 1) {
            setq NivalisQuest_Mede, 2;
            getexp 1500, 0;
        }   
        mesn;
        mesq l("Thanks! Here you go. Perhaps you want another one?");
        next;
        if (askyesno() == ASK_YES)
            goto L_DyeLoop;
    } else {
        mesn;
        mesq l("Sorry, you don't seem to have everything I need.");
    }
    close;


L_Quit:
    closedialog;
    goodbye;
    close;

OnInit:
    .@npcId = getnpcid(.name$);
    setunitdata(.@npcId, UDT_HEADTOP, BrimmedHat);
    setunitdata(.@npcId, UDT_HEADMIDDLE, TneckSweater);
    setunitdata(.@npcId, UDT_HEADBOTTOM, BromenalPants);
    setunitdata(.@npcId, UDT_WEAPON, LousyMoccasins); // Boots
    setunitdata(.@npcId, UDT_HAIRSTYLE, 7);
    setunitdata(.@npcId, UDT_HAIRCOLOR, 17);

    .sex = G_MALE;
    .distance = 4;
    npcsit;
    end;
}