path: root/npc/018-4-2/susanne.txt

// TMW2/LoF scripts.
// Authors:
//    TMW-LoF Team
//    Jesusalva
// Description:
//    Slay the Fafi Dragon quest. Due the OP monster, you better find yourself a good team!

018-4-2,31,26,0	script	Susanne	NPC_FAIRY_A,{
    .@q=getq(LoFQuest_Fairy);

    if(BaseLevel < 50) goto L_Noob;
    if(.@q == 1) goto L_Coward;
    if(.@q == 2) goto L_Complete;
    if(.@q >= 3) goto L_Thanks;

    mesn;
    mesq l("Do you like fairies? Well, you should love them! We play with humans all the time, it is usually pretty fun...");
    next;
    mesc l("(The girl now looks away sadly, thinking about what to say next.)");
    next;
    mesn;
    mesq l("But dragons came and started roaming this island. My friends are now either dead or missing. You look big and strong, do you want to avenge me?");
    goto L_Menu;

L_Menu:
    menu
        l("Sure, I'd love to help! What can I do?"), L_Yes,
        l("Nah, I've got more serious matters to attend to..."), L_No;

L_Yes:
    mesn;
    mesq l("Thank you so much! That might not bring my friends back, but will make this island much safer!");
    next;
    mesn;
    mesq l("The Fafi Dragon are really really bad guys. I don't know how they came here, as they're not from the Lands Of Fire, nor from Mana World.");
    next;
    mesn;
    mesq l("But this is not important. They are dangerous. They must be stop at any cost!");
    next;
    mesn;
    mesq l("So if you can help, go kill at least one on this island. They take a long time to respawn.");
    next;
    mesn;
    mesq l("Thank you...");
    setq LoFQuest_Fairy, 1;
    close;

OnKillFafi:
    message strcharinfo(0), "You killed the Fafi Dragon.";
    .@q=getq(LoFQuest_Fairy);
    if (.@q == 1) {
        setq LoFQuest_Fairy, 2;
        mapannounce "018-4-2", "" +strcharinfo(0)+ " has killed the Fafi Dragon!", 0;
        mapannounce "018-4", "" +strcharinfo(0)+ " has killed the Fafi Dragon!", 0;
        mapannounce "017-1", "" +strcharinfo(0)+ " has killed the Fafi Dragon!", 0;
        message strcharinfo(0), "Cheers are being heard throughout the land!";
    }
    end;

L_Complete:
    mesn;
    mesq l("Many thanks for killing it. Maybe more humans come here now, and play with me.");
    next;
    inventoryplace SkullMask, 1;
    getitem SkullMask, 1;
    setq LoFQuest_Fairy, 3;
    mesn;
    mesq l("By the way, I found this Helmet after you killed the Fafi Dragon, Maybe you can use it some day.");
    close;

L_Thanks:
    mesn;
    mesq l("Sometimes humans come here and play with me. Many thanks for the help!");
    close;

L_No:
    mesn;
    mesq l("Ok...please come back when you aren't busy...");
    next;
    mesc l("The girl turns around and you hear her sniffing, she is probably crying...");
    close;

L_Noob:
    mesn;
    mesq l("Hey, have you come to play with me? I love playing with humans! Usually so few show in, it must be the dragons...");
    //mesq l("I need some help with something, but I don't think you're strong enough. Come back later please when you're stronger.");
    close;

L_Coward:
    mesn;
    mesq l("What are you doing talking to me? Go fight, you coward!");
    close;
}