path: root/npc/018-2-1/warps.txt

// Map 018-2-1: Heroes' Hold - Castle manual warps
// LoFQuest_HH
//   1- Accepted
//   2 - Master Finished
//
// Field 2
//  BITWISE:
//      1 - Novice
//      2 - Intermediary
//      4 - Advanced
//      8 - Expert
//     16 - Master
//     32 - Ultimate
//     64 - Supreme
//    128 - Saulc's Madness
//    256 - The Mouboo Realm
//    512 - The Moubootaur Dungeon

018-2-1,26,27,0	script	#018-2-1_26_27	NPC_HIDDEN,2,0,{
    end;

OnTouch:
    .@hh=getq(LoFQuest_HH);
    if (.@hh <= 0) {
        npctalk3 l("The stairs lead to nowhere. However, there is a magic sigil on the bottom.");
        end;
    }
        .@q=getq2(LoFQuest_HH);
        mesn l("Heroes Hold");
        mes l("This is only for the skilled players. Newbies, KEEP OUT!");
        mes l("Time Limit: 20 minutes on any dungeon.");
        mes l("Please select target dungeon:");
        mes "";
        select
            l("Sorry, I am a newbie."),
            rif(BaseLevel >= 40, l("Novice Dungeon (Lv 40+)")), // Level 0-40
            rif(.@q & HH_NOVICE, l("Intermediary Dungeon (Lv 60+)")), // Level 21-60
            rif(.@q & HH_INTERMEDIARY, l("Advanced Dungeon (Lv 80+)")), // Level 41-80
            rif(.@q & HH_ADVANCED, l("Expert Dungeon (Lv 100+)")), // Level 61-100
            rif(.@q & HH_REQUISITE, l("Master Dungeon (BOSS)")), // Boss Only (HH_EXPERT)
            rif(.@q & HH_NOVICE, l("Heroes Hold - Great Hall")),
            l("Information");
        mes "";
        switch (@menu) {
            case 2:
                @HH_LEVEL=HH_NOVICE;
                @HH_TIMER=0;
                warp "018-2-2@No", 37, 196;
                addtimer(500, "#HH_CONTROLLER01::OnPlayerCycle");
                closedialog;
                break;
            case 3:
                @HH_LEVEL=HH_INTERMEDIARY;
                @HH_TIMER=0;
                warp "018-2-3@In", 204, 40;
                addtimer(500, "#HH_CONTROLLER01::OnPlayerCycle");
                closedialog;
                break;
            case 4:
                @HH_LEVEL=HH_ADVANCED;
                @HH_TIMER=0;
                warp "018-2-2@Ad", 209, 178;
                addtimer(500, "#HH_CONTROLLER01::OnPlayerCycle");
                closedialog;
                break;
            case 5:
                @HH_LEVEL=HH_EXPERT;
                @HH_TIMER=0;
                warp "018-2-3@Ex", 51, 40;
                addtimer(500, "#HH_CONTROLLER01::OnPlayerCycle");
                closedialog;
                break;
            case 6:
                @HH_LEVEL=HH_MASTER;
                @HH_TIMER=0;
                warp "018-2-3", 132, 92;
                addtimer(500, "#HH_CONTROLLER01::OnPlayerCycle");
                closedialog;
                break;
            case 7:
                mes "";
                mesn;
                mesc l("Currently under development.", 1);
                break;
            case 8:
                mes "";
                mesn l("Heroes Hold");
                mes l("The Heroes Hold is divided in seven dungeons level: Novice, Intermediary, Advanced, Expert, Master, Ultimate and Supreme.");
                next;
                mesn;
                mes l("It is NOT designed for noobs. It is for the pain-seeking pro adventurers who laugh at death, and see danger as fun.");
                next;
                mesn;
                mes l("The monsters on each Heroes Hold Dungeon will drop @@, a coin which can only be found here.", getitemlink(StrangeCoin));
                next;
                mesn;
                mes l("Use these coins to exchange for stuff. But beware: Each dungeon difficulty will increase the coin drop in a order of magnitude.");
                next;
                mes l("This means that if you drop a coin on Advanced Dungeon, 100 coins will be dropped instead.");
                next;
                mesn;
                mes l(".:: Victory Conditions ::.");
                mes l("- Defeat the BOSS on each dungeon!");
                mes "";
                mes l(".:: Withdraw Conditions ::.");
                mes l("- Time runs out (20m).");
                mes l("- Get killed yourself.");
                mes l("- Teleport yourself away.");
                next;
                mes l("Dying inside the Heroes Hold Main Dungeon does not have a penalty. However, dying outside have.");
                break;

        }
    close;
}