path: root/npc/017-6/axzell.txt

// TMW2/LoF scripts.
// Authors:
//    Jesusalva
// Dye Quest added by:
//    Povo
// Description:
//    Status Reset. Formely named Bobby

017-6,25,30,0	script	Axzell the Alchemist	NPC_PLAYER,{

    speech S_LAST_NEXT,
        l("I am @@, an alchemist specialized in reset potions.", .name$);

L_Menu:
    .@plush_count = BaseLevel*190-(9*210);
    // Lv 10: 10 GP
    // Lv 90: 1.690 GP
    if (BaseLevel > 10)
        .@plush_count = .@plush_count/(BaseLevel/10);

    select
        l("Can you reset my stats please?"),
        l("Hey, nice hat! Can I have it?"),
        l("Do you make anything else?"),
        lg("You are weird, I have to go sorry.");

    mes "";
    switch (@menu) {
        case 1:
            goto L_ResetStats;
        case 2:
            mesn;
            mesq l("Maybe.");
            next;
            mesn strcharinfo(0);
            mes l("*_* \"Pretty please?\"");
            next;
            mesn;
            mesq l("Well, I and my brother could make another one, but they are being checked for safety.");
            next;
            mesn;
            mesq l("After all, what would you do if it open a black hole on your head by accident? %%4");
            next;
            mesn strcharinfo(0);
            mesq l("Welp, no, please!");
            next;
            mesn;
            mesq l("%%@ Then wait until Saulc says they are safe!");
            next;
            goto L_Menu;
        case 3:
            goto L_Dye;
        case 4:
            goto L_Quit;
    }

L_ResetStats:
    mesn;
    mesq l("Status point reset can't be undone. Do you really want this?");

L_ConfirmReset:
    ConfirmStatusReset();
    goto L_Quit;

L_Dye:
    mesn;
    mesq l("Since red is the official color of Land of Fire Village, I craft dye for players who will properly represent our town.",
                      getitemlink(RedDye));
    if (BaseLevel < 50) {
        mesn;
        mesq l("Right now you are too weak.");
        mesq l(" What would people think of our village if they come accross a defeated noob wearing our proud colors!");
        next;
        mesq l("Come back when you are at a higher level.");
        next;
        goto L_Menu;
    }
    next;
    mesq l("Bring me %d %s, %d %s, %d %s, and %d %s, and I will make it for you. I also charge %d GP commission.",
        1, getitemlink(BottleOfSewerWater),
        200, getitemlink(AlizarinHerb),
        20, getitemlink(Coral),
        10, getitemlink(SulfurPowder), 3500);
    mesq l("Do you want one?");
    compareandsetq LoFQuest_Axzell, 0, 1;
   next;
    select
        l("Yeah, I need one."),
        l("Thanks for the help, but no."),
        l("Actually, nevermind. Good bye!");
    mes "";
    if (@menu == 2)
        goto L_Menu;

    if (@menu == 3)
        goto L_Quit;

    L_DyeLoop:
    if (countitem(BottleOfSewerWater) >= 1 &&
          countitem(AlizarinHerb) >= 200 &&
          countitem(Coral) >= 20 &&
          countitem(SulfurPowder) >= 10 &&
          Zeny >= 3500) {
        inventoryplace RedDye, 1, EmptyBottle, 1;
        delitem BottleOfSewerWater, 1;
        delitem AlizarinHerb, 200;
        delitem Coral, 20;
        delitem SulfurPowder, 10;
        Zeny-=3500;
        getitem RedDye, 1;
        getitem EmptyBottle, 1;
        if (getq(LoFQuest_Axzell) == 1) {
            setq LoFQuest_Axzell, 2;
            getexp 15000, 0;
        }
        mesn;
        mesq l("Thanks! Here you go. Perhaps you want another one?");
        next;
        if (askyesno() == ASK_YES)
            goto L_DyeLoop;
    } else {
        mesn;
        mesq l("Sorry, you don't seem to have everything I need.");
    }
    close;

L_Quit:
    closedialog;
    goodbye;
    close;

OnTimer1000:
    domovestep;

OnInit:
    .@npcId = getnpcid(.name$);
    setunitdata(.@npcId, UDT_HEADTOP, ChemistHelmet);
    setunitdata(.@npcId, UDT_HEADMIDDLE, AlchemistArmor);
    setunitdata(.@npcId, UDT_HEADBOTTOM, RaidTrousers);
    setunitdata(.@npcId, UDT_WEAPON, LousyMoccasins); // Boots
    setunitdata(.@npcId, UDT_HAIRSTYLE, 14);
    setunitdata(.@npcId, UDT_HAIRCOLOR, 17);

    initpath "move", 25, 30,
             "dir", DOWN, 0,
             "wait", 15, 0,
             "move", 29, 21,
             "dir", LEFT, 0,
             "wait", 5, 0,
             "dir", DOWN, 0,
             "wait", 15, 0,
             "move", 28, 34,
             "dir", RIGHT, 0,
             "wait", 15, 0,
             "move", 22, 37,
             "dir", RIGHT, 0,
             "wait", 30, 0,
             "move", 22, 48,
             "dir", UP, 0,
             "wait", 15, 0,
             "move", 28, 62,
             "dir", UP, 0,
             "wait", 15, 0,
             "move", 29, 47,
             "dir", UP, 0,
             "wait", 15, 0;
    initialmove;
    initnpctimer;

    .sex = G_MALE;
    .distance = 5;
    end;
}