path: root/npc/014-2/woodywife.txt

// TMW2 Script
// Author:
//      Saulc
//      Jesusalva
// Description:
//    Woody wife in old shaman girl. She kept house entrance from years.
// id:100  HurnscaldQuest_Woody
//      0 - Not aware of the quest
//      1 - Know about winter
//      2 - Quest Acepted
//      3 - Quest Complete
//      4+ - see woody

014-2,104,31,0	script	Woody Wife	NPC_RAIJIN_FEMALE_WAITRESS,{
    .@quest = getq(HurnscaldQuest_Woody);
    if (BaseLevel < 25) goto L_TooWeak;
    if (.@quest == 1) goto L_Start;
    if (.@quest == 2) goto L_Check;
    if (.@quest >= 3) goto L_Complete;

L_GiveTask:
    mesn;
    mesq lg("Hello, new wanderer!");
    next;
    mesq l("Be careful to don't get lost in this forest.");
    next;

    menu
        l("Hey do not take me as a child."), L_Quit,
        l("Hello, I'm looking for bandit hoods!"), L_Hood,
        l("Hey! I want to enter in this house!"), L_Force,
        l("Hello, who are you?"), L_Quest,
        l("I don't have time sorry."), L_Quit;


L_Quest:
    mes "";
    mesn;
    mesq l("I'm Woody Wife, I live here with Woody since a lot of years! We decided to leave away from civilization, hunter and shaman life is way better.");
    next;
    mesn;
    mesq l("But now, we are quite old, I remember the time when I was your age. My generation don't do stupid things like yours!");
    next;

    menu
        l("Isn't hard to live alone?"), L_Start,
        l("Where is Woody?"), L_Woody,
        l("Ok grandma CYA!"), L_Quit;


L_Start:
    setq HurnscaldQuest_Woody, 1;
    mes "";
    mesn;
    mesq l("No, we do this during our whole life, And we survive!");
    next;
    mesn;
    mesq l("My shaman skill protect us, against monsters and thiefs!");
    next;

    menu
        l("Hey if you want I can do some physical work for you!"), L_Ask,
        l("Can you teach me a basic shaman skill? please?"), L_Skill,
        l("Oh no! I will miss my bus! Gotta go!"), L_Quit;

L_Ask:
    setq HurnscaldQuest_Woody2, 2;
        mes "";
    mesn;
    mesq l("Oh yeah some work are really painful, especially for my back, and I cant bother Woody to do it, he have so many difficulties to move.");
    next;
    mesn;
    if (season() != WINTER)
        mesq l("I need you to bring me some basic item to face Winter! Fire is most important for us.");
    else
        mesq l("Winter this year is being really harsh! Fire is most important for us.");
    next;
    goto L_List;

L_Quit:
    mes "";
    mesn;
    mesq l("Alright.");
    close;

L_List:
    mes "";
    mesn;
    mes l("Could be nice if you could bring me this:");
    mes l("@@/40 @@", countitem(RawLog), getitemlink(RawLog));
    mes l("@@/5 @@", countitem(Coal), getitemlink(Coal));
    close;

L_Check:
    mesn;
    mesq l("Hey,did you brought me everything I asked for?");
    next;
    menu
        l("Yes! It is heavy."), L_Give,
        l("humm... Sorry, I forgot what you need!"), L_List,
        l("I don't have them, actually."), L_Quit;

L_Give:
    if (
        countitem(RawLog)            < 40  ||
        countitem(Coal)              < 5
        ) goto L_Nope;

    inventoryplace RedApple, 3;

    delitem(RawLog, 40);
    delitem(Coal, 5);

    getitem(RedApple, 3);
    getexp(2500, 50);
    setq(HurnscaldQuest_Woody, 3);

    mes "";
    mesn;
    mesq l("Thank you, We are now friends, You can visit us when you want!");
    close;

L_Complete:
    mesn;
    mesq l("Wandering too much? Take care to don't get lost.");
    close;

L_Woody:
    mesn;
    mesq l("Woody is inside, he probably craft some stuff with animals pelts.");
    close;

L_Hood:
    mesn;
    mesq l("You search for Bandit hoods.");
    next;
    mesn;
    mesq l("You could found some bandit in Bandit cave. Yeah this name isen't give for nothing.");
    next;
    mesn;
    mesq l("To go there you need to go left, follow rock wall and go up when you can, entrance of Bandit cave is at left side of waterfall.");
    next;
    close;

L_Force:
    mesn;
    mesq l("Stranger and monsters aren't allowed to enter in MY house!");
    next;
    mesn;
    mesq l("Anyway, my herb mixture keep monsters away.");
    next;
    close;

L_Skill:
    mesn;
    //mesq l("I don't know if jesusalva allow me to teach you a basic chaman skill!? .");
    // I don't, but a monster repellent would be nice. Does such skill exist/work?
    mesq l("Well, I know a mixture to keep monsters away. I just can't share it with you now.");
    next;
    mesn;
    mesq l("You see, it need certain special items... Oh, just blame Jesusalva for this one.");
    next;
    close;

L_Nope:
    mesn;
    mesc l("humm... You don't have everything I've asked for!");
    next;
    mesn;
    mesq l("Can you come back with all the items I asked for? Please.");
    next;
    goto L_List;

L_TooWeak:
    mesn;
    mesq l("You should not be there! This forest is home to monsters.");
    close;

OnInit:
    .sex = G_FEMALE;
    .distance = 4;
    end;
}

014-2,103,29,0	script	Woody Barrier	NPC_HIDDEN,0,0,{
    end;

OnTouch:
    .@q=getq(HurnscaldQuest_Woody);
    if (.@q >= 3)
        warp "014-2-1", 33, 44;
    else
        npctalk3 l("The door is locked, you should speak to Woody's Wife about it.");
    end;
}