path: root/npc/009-3/kevin.txt

// TMW2 Script
// Author:
//    Saulc
//    Vasily_Makarov (original from Evol)
//    Jesusalva
// Description:
//    Status Reset

009-3,39,48,0	script	Kevin	NPC_PLAYER,{

    speech S_LAST_NEXT,
        l("I am @@, an alchemist specialized in reset potions.", .name$);

L_Menu:
    .@plush_count = BaseLevel*210-(9*210);
    // Lv 10: 210 GP
    // Lv 90: 1.890 GP
    if (BaseLevel > 10)
        .@plush_count = .@plush_count/(BaseLevel/10);

    select
        l("Can you reset my stats please?"),
        l("Can you mix Gem Powder?"),
        lg("You are weird, I have to go sorry.");

    switch (@menu)
    {
        case 1:
            goto L_ResetStats;
        case 2:
            goto L_Powder;
        case 3:
            goto L_Quit;
    }

L_ResetStats:
    mesn;
    mesq l("Status point reset can't be undone. Do you really want this?");

L_ConfirmReset:
    ConfirmStatusReset();
    goto L_Quit;

L_Powder:
	.@price=POL_AdjustPrice(800);
    mes "";
    mesn;
    mesq l("To make @@ I need one from each gem powders, and @@ GP for commission.", getitemlink(GemPowder), .@price);
    next;
    select
        l("Yeah, I need one."),
        l("Thanks for the help, but no."),
        l("Actually, nevermind. Good bye!");
    if (@menu == 2)
        goto L_Menu;

    if (@menu == 3)
        goto L_Quit;

    if (
        countitem(DiamondPowder) &&
        countitem(RubyPowder) &&
        countitem(EmeraldPowder) &&
        countitem(SapphirePowder) &&
        countitem(TopazPowder) &&
        countitem(AmethystPowder) &&
        Zeny >= .@price) {

        inventoryplace GemPowder, 1;
        delitem DiamondPowder, 1;
        delitem RubyPowder, 1;
        delitem EmeraldPowder, 1;
        delitem SapphirePowder, 1;
        delitem TopazPowder, 1;
        delitem AmethystPowder, 1;
		POL_PlayerMoney(.@price);
        getitem GemPowder, 1;
        getexp rand2(6,18), rand2(6,18);

        mesn;
        mesq l("Thanks! Here you go. Perhaps you need another one?");
        next;
        goto L_Powder;
    } else {
        mesn;
        mesq l("Sorry, but I need one of each gem powder, and %d GP.", .@price);
        next;
    }
    goto L_Menu;

L_Quit:
    closedialog;
    goodbye;
    close;

OnInit:
    .@npcId = getnpcid(.name$);
    setunitdata(.@npcId, UDT_HEADTOP, FancyHat);
    setunitdata(.@npcId, UDT_HEADMIDDLE, SailorShirt);
    setunitdata(.@npcId, UDT_HEADBOTTOM, BromenalPants);
    setunitdata(.@npcId, UDT_WEAPON, LousyMoccasins); // Boots
    setunitdata(.@npcId, UDT_HAIRSTYLE, 7);
    setunitdata(.@npcId, UDT_HAIRCOLOR, 17);

    .sex = G_MALE;
    .distance = 4;
    end;
}