path: root/npc/007-1/skydg.txt

// TMW2 Script
// Author:
//    SkyDragon!
// Reviewer:
//    Jesusalva
// Description:
//    Miner

007-1,165,144,0	script	Miner#SkyDG	NPC_PLAYER,{
    .@Miner = getq(MineQuests_Miner);
    if (BaseLevel < 25) goto L_TooWeak;
    if (.@Miner == 1) goto L_Check;
    if (.@Miner == 2) goto L_Complete;

L_GiveTask:
    mesn;
    mesq lg("Hello, wanderer!");
    next;
    mesq l("How did you end up here?");
    next;

    menu
        l("To be honest, I don't know. I was only walking, seeking for adventure!"), L_Quest,
        l("It's none of your business."), L_Quit;


L_Quest:
    mes "";
    mesn;
    mesq l("You perchance said in adventure? Then you've came to the right place! I can ask you for some stuff, and in exchange, I'll give some useful gloves!");
    next;

    menu
        l("Really? What do you need?"), L_Start,
        l("Better do this some other time..."), L_Quit;


L_Start:
    setq MineQuests_Miner, 1;
    mes "";
    mesn;
    mesq l("Ok, what I need is:");
    goto L_Lista;

L_Quit:
    mes "";
    mesn;
    mesq l("Alright.");
    close;

L_Lista:
    mes "";
    mesn;
    mes " * 25 " + getitemlink(MaggotSlime);
    mes " * 20 " + getitemlink(BugLeg);
    mes " * 08 " + getitemlink(RedScorpionStinger);
    mes " * 15 " + getitemlink(BatWing);
    mes " * 10 " + getitemlink(BatTeeth);
    mes " * 10 " + getitemlink(CactusDrink);
    mes " * 03 " + getitemlink(ScorpionClaw);
    close;

L_Check:
    mesn;
    mesq l("Did you brought me everything I asked for?");
    next;
    menu
        l("Yes!"), L_Give,
        l("I forgot what you need!"), L_Lista,
        l("No!"), L_Quit;

L_Give:
    if (
        countitem(MaggotSlime)          < 25 ||
        countitem(BugLeg)               < 20 ||
        countitem(RedScorpionStinger)   < 8  ||
        countitem(BatWing)              < 15 ||
        countitem(BatTeeth)             < 10 ||
        countitem(CactusDrink)          < 10 ||
        countitem(ScorpionClaw)         < 3
        ) goto L_Lying;

    inventoryplace MinerGloves, 1;

    delitem(MaggotSlime, 25);
    delitem(BugLeg, 20);
    delitem(RedScorpionStinger, 8);
    delitem(BatWing, 15);
    delitem(BatTeeth, 10);
    delitem(CactusDrink, 10);
    delitem(ScorpionClaw, 3);

    getitem(MinerGloves, 1);
    getexp(150, 0);
    setq(MineQuests_Miner, 2);

    mes "";
    mesn;
    mesq l("Here, all yours. Thank you.");
    close;

L_Complete:
    mesn;
    mesq l("Wandering too much? Take care to don't get lost.");
    close;

// Funnier to write than to read, but the player lied. :angel:
L_Lying:
    mesn;
    mesq l("No no no, that's wrong.");
    next;
    mes col("The miner goes to count your stuff again.", 9);
    next;
    mes col("And again.", 9);
    next;
    mes col("And again, and again.", 9);
    next;
    mes col("And again, and again, again.", 9);
    next;
    mes col("You wonder, maybe he entered on an infinite loop? Hellooo, anybody home?", 9);
    next;
    mesn;
    mesq l("No no no, you don't have everything I've asked for!");
    next;
    goto L_Lista;

OnInit:
    .@npcId = getnpcid(0, .name$);
    setunitdata(.@npcId, UDT_HEADTOP, MinerHat);
    setunitdata(.@npcId, UDT_HEADMIDDLE, LeatherShirt);
    setunitdata(.@npcId, UDT_HEADBOTTOM, BromenalPants);
    setunitdata(.@npcId, UDT_WEAPON, DeepBlackBoots);
    setunitdata(.@npcId, UDT_HAIRSTYLE, 4);
    setunitdata(.@npcId, UDT_HAIRCOLOR, 3);

    .sex = G_MALE;
    .distance = 4;

    end;
}