path: root/npc/007-1/naem.txt

// TMW2 Script
// Author:
//      Jesusalva
// Description:
//    Naem is... I'm not sure.

007-1,180,46,2	script	Naem	NPC_PLAYER,0,0,{
    .@q = getq(MineQuest_Naem);
    mesn;
    mesq l("My name is Naem and I guard the tunnels in this direction. You shall not pass. Now leave.");
    if (BaseLevel < 28)
        close;
    if (.@q < 2)
        close;
    if (.@q == 2) {
        if (!checkbound(IcedBottle)) close;
        next;
        inventoryplace MinerTankTop, 1;
        delitem IcedBottle, 1;
        getitem MinerTankTop, 1;
        getexp 440, 0;
        setq MineQuest_Naem, 3;
        mesn;
        mesq l("Oh, %s, thanks! The tunnels behind me are very hot, this will help if I have to go inside them.", getitemlink(IcedBottle));
        next;
        mesn;
        mesq l("You can have this %s as a token of gratitude. But no, you cannot pass, so keep going!", getitemlink(MinerTankTop));
        close;
    }
    if (.@q > 3)
        close;
    next;
    mesn;
    mesq l("Actually, you look strong...ish. Still, maybe you can help me.");
    next;
    mesn;
    mesq l("I need groceries. %d %s, %d %s, %d %s, %d %s and %d %s. Give it to my wife, Silvia.",
           7, Aquada,
           6, PiouLegs,
           3, Cheese,
           3, HalfCroconut,
           1, PurpleBlobime);
    next;
    mesn;
    mesq l("You can collect croconuts by killing any tree with it. Then you can break it in half from the inventory screen.");
    compareandsetq MineQuest_Naem, 0, 1;
    close;

// TODO: If you walk past him having the requisite, warp
OnTouch:
    npctalk3 l("Hey, I said NO ENTRY! Get moving!");
    end;

OnInit:
    .@npcId = getnpcid(.name$);
    setunitdata(.@npcId, UDT_HEADTOP, MinerHat);
    setunitdata(.@npcId, UDT_HEADMIDDLE, MinerTankTop);
    setunitdata(.@npcId, UDT_HEADBOTTOM, BromenalPants);
    setunitdata(.@npcId, UDT_WEAPON, DeepBlackBoots);
    setunitdata(.@npcId, UDT_HAIRSTYLE, 4);
    setunitdata(.@npcId, UDT_HAIRCOLOR, 3);

    .sex = G_MALE;
    .distance = 4;
    end;

}