path: root/npc/005-4/tolchi.txt

// TMW2 scripts.
// Author:
//    Saulc
//    Jesusalva
// Variables:
//    CandorQuest_Tolchi
// Description:
//   Tolchi crafts weapons at Rosen & Tolchi shop
// Values:
//    0    Default.
//    1    BlackSmith quest ask for 1 iron oore
//    2    BlackSmith quest ask for 3 coal
//    3    BlackSmith quest ask for 1 iron ingot
//    4    Quest is Complete


005-4,42,37,0	script	Tolchi	NPC_RAIJIN_FEMALE_LEGION_ARTIS,{

    .Item1 = IronOre;
    .Item2 = Coal;
    .Item3 = IronIngot;

    function quest_close {
        speech S_FIRST_BLANK_LINE,
            l("Maybe next time, then.");
        close2;
        goodbye;
    }

    function quest_giveitem {
    .@tolchi = getq(CandorQuest_Tolchi);
        if (.@tolchi == 2)
        {
            if (countitem("Iron Ingot") == 0)
            {
                speech S_FIRST_BLANK_LINE,
                    l("You don't have the Iron Ingot.");
                close2;
                goodbye;
            }
            delitem .Item3, 1;
            Zeny = Zeny + 16000; // Real worth: 12100 GP (profit of 1k to 2.5k GP - two travels included)
            getexp 1575,0;
            setq CandorQuest_Tolchi, 3;
            speech S_FIRST_BLANK_LINE,
            l("Thanks mate, that is everything I need! Have a good day!");
        }
        if (.@tolchi == 1)
        {
            if (countitem("Coal") <= 2)
            {
                speech S_FIRST_BLANK_LINE,
                    l("You don't have the three Coal lumps.");
                close2;        
                goodbye;
            }
            delitem .Item2, 3;
            Zeny = Zeny + 800; // Real worth: 400 gp (status: +200gp)
            getexp 105,0; 
            setq CandorQuest_Tolchi, 2;
        }
        if (.@tolchi == 0)
        {
            if (countitem("Iron Ore") == 0)
            {
                speech S_FIRST_BLANK_LINE,
                    l("You don't have the Iron Ore.");
                close2;
                goodbye;
            }
            delitem .Item1, 1;
            Zeny = Zeny + 200; // Real worth: 400 gp (status: -200gp)
            getexp 52,0;
            setq CandorQuest_Tolchi, 1;
        }
        close;
    }

    function quest_first {
        speech S_FIRST_BLANK_LINE | S_LAST_NEXT,
            l("Well, it is terrible! How can I make armours if I ran out of Iron? Shall the citizens of Candor Island perish in a monster attack?!"), // NOTE: I really prefer EN_US (eg. armor vs armour)
            l("They shouldn't. Could you perhaps, kindly bring me 1 @@?", getitemlink(.Item1));
        do
        {
            //l("Do not worry, I'll seek and bring it to you."),
            select
                l("Do not worry, I have them right here."),
                l("I am not a citizen of Candor.");

            switch (@menu)
            {
                case 1:
                    quest_giveitem;
                    break;
                case 2:
                    quest_close;
                    break;
            }
        } while (@menu != 2);
    }

    function quest_second {
        speech  S_FIRST_BLANK_LINE | S_LAST_NEXT,
            l("Thanks for helping my shop earlier. I forge weapons, but unfortunately, I need more than just iron to forge them."),
            l("Can you bring me 3 @@? Of course, you'll be rewarded.", getitemlink(.Item2));
        do
        {
            // l("Hey, I like rewards. Wait me, I'll be back!"),
            select
                l("You better have it ready, because I have the Coal with me!"),
                l("Eh, that seems too problematic. Sorry.");

            switch (@menu)
            {
                case 1:
                    quest_giveitem;
                    break;
                case 2:
                    quest_close;
                    break;
            }
        } while (@menu != 2);
    }

    function quest_third {
        speech S_FIRST_BLANK_LINE | S_LAST_NEXT,
            l("Ok, this will be my last request. The Trainer asked me for a fine weapon, to protect our village."),
            l("Problem is, I do not have the knowledge to make it without @@. If you bring me one, I'll reward you with one quarter of my commission.", getitemlink(.Item3));
        do
        {
            // l("Do not worry, I'll be back in a jiffy."),
            select
                l("No problem is too big for me. I have them right here!"),
                l("Sorry, I am busy...");

            switch (@menu)
            {
                case 1:
                    quest_giveitem;
                    break;
                case 2:
                    quest_close;
                    break;
            }
        } while (@menu != 2);
    }

    .@tolchi = getq(CandorQuest_Tolchi);

    if (BaseLevel <= 4 || BaseLevel <= 9 && .@tolchi == 1 || BaseLevel <= 14 && .@tolchi == 2)
    {
        speech 0x0,
        l("I need help, but you aren't strong enough. Please come back later.");
        close2;
        goodbye;
    }

    if (.@tolchi == 3)
    {
        speech 0x0,
        l("Hey! How are you today? Thanks again for your help.");
        close2;
        goodbye;
    }

    speech S_LAST_NEXT,
        l("Hello! You seem strong enough, could take a request from me? Of course, not for free.");

    do
    {
        select
            rif(.@tolchi == 0, l("Yes.")),
            rif(.@tolchi == 1, l("Yes.")),
            rif(.@tolchi == 2, l("Yes.")),
            l("No.");

        switch (@menu)
        {
            case 1:
                quest_first;
                setq CandorQuest_Tolchi, 0; // TODO: Suspicious piece of code
                break;
            case 2:
                quest_second;
                break;
            case 3:
                quest_third;
                break;
            case 4:
                quest_close;
                goodbye;
                break;
        }
    } while (@menu != 4);

    closedialog;
    goodbye;
    close;

OnTimer1000:
    domovestep;

OnInit:
    initpath "move", 44, 35,
             "dir", UP, 0,
             "wait", 30, 0,
             "move", 43, 40,
             "dir", UP, 0,
             "wait", 30, 0,
             "move", 40, 35,
             "dir", UP, 0,
             "wait", 30, 0,
             "dir", LEFT, 0,
             "wait", 30, 0,
             "move", 42, 37,
             "dir", DOWN, 0,
             "dir", UP, 0,
             "wait", 30, 0,
             "move", 45, 37,
             "dir", DOWN, 0,
             "wait", 30, 0,
             "move", 33, 37,
             "dir", LEFT, 0,
             "wait", 30, 0,
             "move", 33, 37,
             "dir", RIGHT, 0,
             "wait", 30, 0;

    initialmove;
    initnpctimer;
    .distance = 5;
}