path: root/npc/003-1/sailors.txt

// TMW2 scripts.
// Authors:
//    Jesusalva
// Description:
//    The major reward from this one is knowledge about secret passages on Tulimshar.
//    The quest pays what you spend, except for travel fees. The real reward here
//    is knowledge, the fishing rod you'll need to make anyway, 150 XP and 20 JExp.

003-1,112,93,0	script	Sailors#003-1	NPC_ELVEN_MAN_TRADER_SITTING,{
    if (BaseLevel < 12) goto L_Complete;
    .@q = getq(TulimsharQuest_Sailors);
    if (.@q == 1)
        goto L_Report;
    if (.@q == 2)
        goto L_Complete;
    mesn;
    mesq lg("Hey, pal. This spot is very good, I can see the whole town from here.");
    next;
    mesn;
    mesq lg("I am a trader from Nard's ship. We actually need supplies. Help us, and I'll help you.");
    next;
    mesn strcharinfo(0);
    menu
        l("What do you need?"), L_Quest,
        l("Maybe another time."), -;
    close;

L_Complete:
    hello;
    end;

L_Quest:
    mes "";
    mesn;
    mesq l("You're willing to help? Perfect. We need 3 @@, 4 @@ and 10 @@ for travel.", getitemlink(FishBox), getitemlink(CroconutBox), getitemlink(CottonCloth));
    next;
    mesn;
    mesq l("Cotton Cloth is sold at Candor, Croconut Boxes can be bought at the market. Fish, however, is a little more tricky.");
    next;
    mesn;
    mesq l("If you hug the wall, there's a secret passage somewhere there. Well, there are many secret passages at Tulimshar.");
    next;
    mesn;
    mesq l("You will find a fisher, maybe he is having a good time and can sell you a few boxes. And remember to keep your eye open.");
    setq TulimsharQuest_Sailors, 1;
    next;
    mesn;
    mesq l("There are secret caves on this city. In fact, Tulimshar holds many misteries.");
    mesc l("Take care: Secret passages can be dangerous places (or not).");
    close;

L_Report:
    mesn;
    mes l("@@/3 @@", countitem(FishBox), getitemlink(FishBox));
    mes l("@@/4 @@", countitem(CroconutBox), getitemlink(CroconutBox));
    mes l("@@/10 @@", countitem(CottonCloth), getitemlink(CottonCloth));
    if (countitem(FishBox) < 3 ||
        countitem(CroconutBox) < 4 ||
        countitem(CottonCloth) < 10)
            close;
    next;
    select
        l("[Deliver all goods.]"),
        l("[Maybe another time.]");
    mes "";
    if (@menu == 2)
        close;
    if (countitem(FishBox) < 3 ||
        countitem(CroconutBox) < 4 ||
        countitem(CottonCloth) < 10) {
            mesn;
            mesq l("Liar. Where are the goods? Are you trying to cheat me?!");
            next;
            mesn;
            mesq l("You know Jesus Saves hates cheaters, right? If Saulc didn't asked me to double-check stuff...");
            next;
            mesn;
            mesq l("For short, you would have lost all your items, wouldn't get anything, and there would be no refunds.");
            next;
            mesn;
            mesq l("That's just a friendly advise. That's how things works around here.");
            close;
    }
    inventoryplace Dagger, 1, CottonShirt, 1;
    delitem FishBox, 3;      // 7.500 GP → 3.750 GP
    delitem CroconutBox, 4;  // 12.000 GP → 10.600~11.800 GP
    delitem CottonCloth, 10; // 2.000 GP
    getexp 1508, 15;
    Zeny=Zeny+18750;   // Profit: 1800 GP → 2.400~1.200 GP
    getitem Dagger, 1;
    getitem CottonShirt, 1;
    setq TulimsharQuest_Sailors, 2;
    mesn;
    mesq lg("Many thanks, your help has been invaluable. We're now capable to travel at ease.");
    next;
    mesn;
    mesq l("Take care. Here, take this @@. You can sell it for some quick-spot cash, or use it as a weapon.", getitemlink(Dagger));
    close;

OnInit:
    .sex = G_OTHER;
    .distance = 5;
    end;
}