path: root/npc/003-1/neko.txt

// TMW-2 Script
// Author:
//    Saulc
//    Jesusalva
// Description:
//    Another shopkeeper which babbles about Jean Shorts, how Cave Snake drops them
//    and encourage players to find it. He pays 6.000 GP and gives 1620 xp for one.
//    In future, this could grant you discounts on his shop, or allow a quest with
//    a family member from his.

003-1,103,106,0	script	Neko	NPC_M_SHOPKEEPER,{
    .@q=getq(TulimsharQuest_Neko);
    mesn;
    mesq l("Only finest wares!");
    mes "";
    select
        l("Trade"),
        rif(BaseLevel > 20 && .@q == 0, l("Why do you only use the silk robe? Don't you have a shorts or something?")),
        rif(.@q == 1 && countitem(JeansShorts) >= 1, l("I've brought a Jean Shorts for you.")),
        l("Leave");

    if (@menu == 2) {
        mesn;
        mesq l("Oh, that's a long story.");
        next;
        mesn;
        mesq l("You see, I was walking on the secret caves near Ched, and... well...");
        next;
        mesn;
        mesq l("The @@ stole my @@. Hahah. I can't find anywhere else to buy it.", getmonsterlink(CaveSnake), getitemlink(JeansShorts));
        next;
        setq TulimsharQuest_Neko, 1;
        mesn;
        mesq l("If you bring friends, I'm sure they'll be no match. I'll pay you handsomely if you bring me one, too!");
        next;
    }
    if (@menu == 3) {
        delitem JeansShorts, 1;
        Zeny=Zeny+6000;
        getexp 1620, 0; // Level 20 maximum experience
        setq TulimsharQuest_Neko, 2;
        mesn;
        mesq l("Oh... Thank you! Here is @@ GP for it.", "6000");
        next;
        mesn;
        mesq l("I'm surprised, though. It is a very good defensive item, and players can buy it for pretty high sums of money.");
        next;
        mesn;
        mesq l("Well, profit for me! Thanks for your help. I'll tell all my family how you help me. %%1");
        next;
    }

    closedialog;
    if (@menu == 1)
        shop .name$;
    goodbye;
    close;

OnInit:
    .@npcId = getnpcid(0, .name$);
    setunitdata(.@npcId, UDT_HEADTOP, NPCEyes);
    setunitdata(.@npcId, UDT_HEADMIDDLE, SilkRobe);
    //setunitdata(.@npcId, UDT_HEADBOTTOM, LeatherTrousers); // FIXME: LeatherTrousers are BROKEN!
    setunitdata(.@npcId, UDT_WEAPON, AssassinBoots);
    setunitdata(.@npcId, UDT_HAIRSTYLE, 26);
    setunitdata(.@npcId, UDT_HAIRCOLOR, 2);

    tradertype(NST_MARKET);
    sellitem LeatherShirt, 120000, 1;
    sellitem ShortTankTop, 80000, 1;
    sellitem TrainingBow, 990, 2;
    sellitem Arrow, -1, rand(10000,30000);
    sellitem CroconutBox, rand(2650,3000), 4;

    .sex = G_MALE;
    .distance = 5;
    end;

OnClock2359:
    restoreshopitem LeatherShirt, 120000, 1;
    restoreshopitem TrainingBow, 990, 2;
    restoreshopitem ShortTankTop, 80000, 1;
    restoreshopitem Arrow, -1, rand(10000,30000);
    restoreshopitem CroconutBox, rand(2650,3000), 4;
    end;

}