path: root/npc/003-0/recepcionist.txt

// TMW2 Scripts.
// Author:
//  Jesusalva
// Description:
//  Magic School receptionist (TODO: Give S. Badge)

003-0,61,44,4	script	Recepcionist#003-0	NPC_FEMALE,{
    mesn;
    mesq l("Hello, and welcome to the Magic School of Tulimshar.");
    next;
    mesn;
    mesq l("Actually I'm responsible of dispatching mages to the Magic Academy.");
    next;
    select
        l("What is the Magic Academy?"),
        l("I am a mage. How do I get to Academy?"),
        l("What magic classes are there?"),
        l("Erm... Good bye.");
    mes "";
    switch (@menu) {
    case 1:
        goto L_Prologue;
    case 2:
        goto L_Academy;
    case 3:
        goto L_Classes;
    }
    closeclientdialog;
    goodbye;
    close;

//////////////
/* Prologue */
//////////////
L_Prologue:
    next;
    mesn l("Magic Academy Tutorial");
    mesc l("The Magic Academy System is responsible for learning most skills ingame. For that, you need two things: Magic Skill Points and a reagent.");
    next;
    mesn l("Magic Academy Tutorial");
    mesc l("The reagent is always the same for the same class. If you do not have enough reagents but have an @@, it'll be used to continue.", getitemlink(ScholarshipBadge));
    next;
    mesn l("Magic Academy Tutorial");
    mesc l("Magic Skill Points can be obtained in three ways: By touching a Mana Stone, by signing up in a Special Class (if you have enough magic power) and by having high amounts of Job Level.");
    next;
    mesn l("Magic Academy Tutorial");
    mesc l("Upgrading a skill level can be done the same away and will always cost a single Magic Skill Point. Job Level points are obtained only after Lv @@, and is a single point each @@ levels.", 15+12, 12);
    next;
    if (!MGQUEST) {
        inventoryplace ScholarshipBadge, 1;
        mesn;
        mesq l("That being said, I'll give you an @@, which allows you to learn a skill even if you can't pay for it.", getitemlink(ScholarshipBadge));
        next;
    }
    mesn;
    mesq l("Please note unless you have Magic Powers, obtained from the Mana Seed, all you will be able to learn are small tricks, so please make a wise choice.");
    if (!MGQUEST) {
        MGQUEST=true;
        getitem ScholarshipBadge, 1;
    }
    tutmes l("Magic skills allows for a more advanced gameplay, but they are meant for level 30 onward.");
    tutmes l("If you follow %s's quest, you will eventually reach the requirements for here.", b("Lua"));
    close;


//////////////
/* Academy  */
//////////////
L_Academy:
    if (!MAGIC_LVL) {
        mesn;
        mesq l("Oh please. Even if you know a trick or two, you don't have real magic.");
        next;
        mesn;
        mesq l("You need to touch a Mana Stone to get magic. Certainly the only Mana Stone on Tulimshar is highly protected by the Council, so no chances here.");
        next;
        mesn;
        mesq l("Well, the biggest mana stones mine was in %s, but I'm afraid it has already depleted... Besides, it is very dangerous.", b("Halinarzo"));
    } else {
        mesn;
        mesq l("Oh, just walk on the dock, and you'll be warped there.");
        next;
        mesn;
        mesq l("I mean, a ship should come to pick you up, but the arch-wizards said they were too lazy to take care of those small details. So you'll be warped.");
    }
    close;


//////////////
/* Classes  */
//////////////
L_Classes:
    mesn;
    mesq l("We have four classes, but you can make a mix between them.");
    next;
    mesc ".:: "+l("Physical Science")+" ::.", 3;
    mes l("They use magic to boost their bodies, allowing them to do very, VERY powerful physical attacks.");
    mes l("They also don't need much intelligence or magic equipment.");
    mes "";
    mes l("Physical Science Institute is on the %s area of the campus.", b(l("west")));
    next;
    mesc ".:: "+l("Wizardry")+" ::.", 3;
    mes l("They use mana to create magic attacks and blast their foes away.");
    mes l("They rely entirely in intelligence and magic equipment.");
    mes "";
    mes l("Wizardry Institute is on the %s area of the campus.", b(l("north")));
    next;
    mesc ".:: "+l("Scholarship Science")+" ::.", 3;
    mes l("Training to be sages, their knowledge is unparalleled. They're masters of boosting skills.");
    mes l("Most of their skills are stat-independent, but not all of them.");
    mes "";
    mes l("Scholarship Institute is on the %s area of the campus.", b(l("north")));
    next;
    mesc ".:: "+l("Tricks")+" ::.", 3;
    mes l("They cheat! They make silly tricks which look like magic.");
    mes "";
    mes l("The trickster can be found right here.");
    close;


/// Core code
OnTimer1000:
    domovestep;

OnInit:
    .@npcId = getnpcid(.name$);
    setunitdata(.@npcId, UDT_HEADTOP, FancyHat);
    setunitdata(.@npcId, UDT_HEADMIDDLE, SorcererRobe);
    //setunitdata(.@npcId, UDT_HEADBOTTOM, NPCEyes);
    //setunitdata(.@npcId, UDT_WEAPON, JeansShorts);
    setunitdata(.@npcId, UDT_HAIRSTYLE, any(8,11,20));
    setunitdata(.@npcId, UDT_HAIRCOLOR, 5);

    // Small movement
    initpath "move", 61, 44,
             "dir", UP, 0,
             "wait", 7, 0,
             "move", 62, 46,
             "dir", DOWN, 0,
             "wait", 7, 0,
             "move", 63, 44,
             "dir", UP, 0,
             "wait", 7, 0,
             "move", 61, 44;
    initialmove;
    initnpctimer;

    .sex=G_FEMALE;
    .distance=5;
    end;
}