path: root/npc/003-0/enzo.txt

// TMW2 Script
// Author:
//  Jesusalva
// Description:
//  Forgetful

003-0,68,25,0	script	Enzo	NPC_BLACKWIZARD,{
    mesn l("Enzo, the Forgetful");
    mesq l("What was I doing before...? I forgot!");
    next;
    mesc l("Teaching Enzo your skills will make you both forget them."), 1;
    mesc l("Once your skill is forgotten, the Magic Skill Points used will be freed."), 1;
    mesc l("But be careful: Only 1MSP-costed skills can be forgotten, and learning fees WON'T be given back!"), 1;
    do
    {
        next;
        mesc l("Which skill will you FORGET permanently today?"), 1;
        menuint
            l("Uhm... Bye?"), 0,
            rif(getskilllv(AL_HEAL),        l("Healing")), AL_HEAL,
            rif(getskilllv(TMW2_SAGE),      l("Mana Wisdom")), TMW2_SAGE,
            rif(getskilllv(HW_MAGICPOWER),  l("Accumulate Power")), HW_MAGICPOWER,
            rif(getskilllv(SM_PROVOKE),     l("Provoke")), SM_PROVOKE,
            rif(getskilllv(SA_FREECAST),    l("Free Casting")), SA_FREECAST,
            rif(getskilllv(TF_BACKSLIDING), l("Tactical Retreat")), TF_BACKSLIDING,
            rif(getskilllv(MG_FIREWALL),    l("Nature Wall")), MG_FIREWALL,
            rif(getskilllv(ALL_FULL_THROTTLE), l("Last Resort")), ALL_FULL_THROTTLE,
            rif(getskilllv(SM_BASH),        l("Falkon Punch!")), SM_BASH,
            rif(getskilllv(MC_MAMMONITE),   l("Supreme Attack")), MC_MAMMONITE,
            rif(getskilllv(AC_SHOWER),      l("Arrow Shower")), AC_SHOWER,
            rif(getskilllv(MG_FIREBALL),    l("Fireball")), MG_FIREBALL,
            rif(getskilllv(AL_HOLYLIGHT),   l("Holy Light")), AL_HOLYLIGHT,
            rif(getskilllv(MG_SOULSTRIKE),  l("Magic Strike")), MG_SOULSTRIKE,
            l("None at the moment!"), 0;
        mes "";
        mesc l("Skill @@ will be permanently lost!", @menuret), 1;
        mesc l("Continue anyway?"), 1;
        if (askyesno() == ASK_YES) {
            .@lv=getskilllv(@menuret);
            skill @menuret, 0, 0;
            MAGIC_PTS-=.@lv;
            mesc l("Skill @@ has been lost", @menuret), 3;
            mesc l("You recovered @@ magic skill points", .@lv), 3;
        } else {
            mesn l("Enzo, the Forgetful");
            mesq l("Uh, what?");
        }
    } while (@menuret);
    close;

OnInit:
    .sex = G_MALE;
    .distance = 5;
    end;

}