path: root/npc/003-0/colin.txt

// TMW2 script.
// Author:
//    Saulc
//    Jesusalva
// Description:
//    Colin, of Destructive Magic Class.

003-0,58,29,0	script	Colin	NPC_PLAYER,{
    if (!MAGIC_LVL) goto L_NoMagic;
    mes l(".:: Trickster Class ::.");
    mesc l("Specialized in miscellaneous skills.");
    next;
    mesn;
    mesc l("You have @@/@@ magic skill points available.", sk_points(), sk_maxpoints());
    mesc l("Trickster uses an experimental window, you might need to resize it to see all skills.");
    do {
    next;
    mesc l("Healing - The most basic healing skill, requires no items to use.");
    mesc l("Mana Wisdom - Raise Mana EXP Gain rate");
    menuint
        "Healing", AL_HEAL,
        "Mana Wisdom", TMW2_SAGE,
        "Cancel", 0;
    mes "";

    switch (@menuret) {
        case AL_HEAL:
            if (!mlearn(AL_HEAL, 1, 1, SpellBookPage, 1))
                mesc l("You do not meet all requisites for this skill."), 1;
            break;
        case TMW2_SAGE:
            if (!mlearn(TMW2_SAGE, 1, 1, SpellBookPage, 1))
                mesc l("You do not meet all requisites for this skill."), 1;
            break;
        default:
            if (@menuret)
                Exception("ERROR skill not implemented", RB_DEFAULT|RB_SPEECH);
            else
                closeclientdialog;
            break;
    }
    } while (@menuret);
    close;

L_NoMagic:
    next;
    mesn;
    mesq l("Your lack of magical power is critical. I dare say, you might never in your life get access to a Mana Stone.");
    next;
    mesn;
    mesq l("Besides the Magic Council, Andrei Sakar have his own Mana Stone, but I doubt he would train the likes of you, or share his Mana Stone.");
    next;
    mesn;
    mesq l("Perhaps, in the city, someone knows rumors about Mana Stones and can teach you. Other than that, you're on your own.");
    close;

OnInit:
    .@npcId = getnpcid(.name$);
    setunitdata(.@npcId, UDT_HEADTOP, NPCEyes);
    setunitdata(.@npcId, UDT_HEADMIDDLE, SorcererRobe);
    setunitdata(.@npcId, UDT_HEADBOTTOM, JeansShorts);
    setunitdata(.@npcId, UDT_WEAPON, DeepBlackBoots);
    setunitdata(.@npcId, UDT_HAIRSTYLE, 21);
    setunitdata(.@npcId, UDT_HAIRCOLOR, 20);

    .sex = G_MALE;
    .distance = 5;
    end;
}