path: root/npc/002-1/billybons.txt

// TMW2 Script
// Evol scripts.
// Author:
//    Reid
// Description:
//    Drunk easteregg telling about the player's past.
//    For TMW2 it is just to provide a bottle

002-1,29,33,0	script	Billy Bons#TMW2	NPC_BILLY_BONS,{
    if (rand(5) == 2) goto L_Hic;
    .@q = getq(ShipQuests_Bottle);
    if (.@q == 1) goto L_Hic;

    mesn;
    mesq l("You? Here?");
    mesq l("How is *hic* it possible?");
    next;

    mesn "Narrator";
    mesc l("The sailor chugs his beer.");
    next;

    select
        lg("Excuse me? Do you know who I am?");

    mes "";
    mesn;
    mesq l("Don't do theee... *hic* with me eh!");
    next;

    menu
        l("Are you ok?"), L_Quit,
        l("Take the bottle?"), L_Give,
        l("Alright... Bye."), -;

    mes "";
    mesn;
    mesq lg("No and *hic*... No, you and you and your... *burp* stup*hic* guild!");
    next;
    mesq l("You tried to get rid of me, eeh? But surprise! I'm still here... *hic* Or there...");
    next;
    mesq l("But you won't *hic* me this time...");
    next;

    menu
        l("What are you talking about? What guild?"), L_Quit,
        l("You are full of wine, my friend..."), -,
        l("You should go and get some sleep."), L_Quit;

    mes "";
    mesn;
    mesq l("If I saw *hic* who you were... *hic* Would not have helped you! ");
    next;

    menu
        l("But who am I?"), -,
        l("What am I supposed to say?"), L_Quit,
        l("You should go and get some sleep."), L_Secret;

    mes "";
    mesn;
    mesq l("The giant boogeyman!");

    close;

L_Secret:
    mes "";
    mesn;
    mesq l("Hear me *hic* well, what ever, whatididever you will *hic* said ab... uhm... out what?! You saw there, the Guild won't let it get public.");
    next;
    mesq l("Nobody can know! *burp*");
    next;

    close;

L_Hic:
    npctalk3 l("*Hic*");

    close;

L_Quit:
    mes "";
    mesn;
    mesq l("Yeah you're all like *hic* that, but you won't get me! *burp*");
    next;
    mesq l("I'm not that numb eeh *hic* what did ever yous disco... ...vered there, the Guild won't get me!");
    mesq l("*burp*");
    next;

    mesn "Narrator";
    mesc l("The sailor turns his back to you.");

    close;

L_Give:
    mes "";
    inventoryplace EmptyBottle, 1;

    setq ShipQuests_Bottle, 1;
    getitem EmptyBottle, 1;

    close;

OnInit:
    .sex = G_MALE;
    .distance = 3;
    end;
}