path: root/world/map/npc/009-7/debug.txt

function|script|fightclub_Debug|,
{
    goto L_Menu;

L_Menu:
    next;
    set @bme,0; if(($fightclub_enabled % 6) == 3) set @bme,1;
    set @due,0; if(($fightclub_enabled % 5) == 3) set @due,1;
    mes "[Global]";
    mes "$Duel_Enabled: " + @due;
    mes "$fightclub_bm_enabled: " + @bme;
    mes "$@fightclub_password$: " + $fightclub_password$;
    mes "$@Duel_TimeBeforeNext: " + $@Duel_TimeBeforeNext;
    mes "$@Duel_TimeBeforeWarp: " + $@Duel_TimeBeforeWarp;
    mes "$@Duel_TimeBeforeStart: " + $@Duel_TimeBeforeStart;
    mes "$@Duel_TimeLimit: " + $@Duel_TimeLimit;
    mes "$@Duel_QueueLimit: " + $@Duel_QueueLimit;
    mes "$@Duel_PlayerQueueLimit: " + $@Duel_PlayerQueueLimit;
    mes "$Duel_LastDuel: " + $Duel_LastDuel;
    mes "";
    mes "[User]";
    mes "@Duel_Fighter: " + @Duel_Fighter;
    next;
    menu
        "[G] Toggle $Duel_Enabled", L_DuelEnabled,
        "[G] Toggle $fightclub_bm_enabled", L_BmEnabled,
        "[G] Set $@fightclub_password$", L_FightclubPassword,
        "[G] Set $@Duel_TimeBeforeNext", L_TimeBeforeNext,
        "[G] Set $@Duel_TimeBeforeWarp", L_TimeBeforeWarp,
        "[G] Set $@Duel_TimeBeforeStart", L_TimeBeforeStart,
        "[G] Set $@Duel_TimeLimit", L_TimeLimit,
        "[G] Set $@Duel_QueueLimit", L_QueueLimit,
        "[G] Set $@Duel_PlayerQueueLimit", L_PlayerQueueLimit,
        "[G] Set $Duel_LastDuel", L_LastDuel,
        "[U] Toggle @Duel_Fighter", L_DuelFighter,
        "Restart fightclub.", L_Restart,
        "Nevermind.", L_End;

L_DuelEnabled:
    if(@due < 1) goto L_DuelEnabled2;
    set $fightclub_enabled, 9;
    if(@bme < 1) set $fightclub_enabled, 1;
    goto L_Menu;
L_DuelEnabled2:
    set $fightclub_enabled, 8;
    if(@bme == 1) set $fightclub_enabled, 3;
    goto L_Menu;

L_BmEnabled:
    if(@bme < 1) goto L_BmEnabled2;
    set $fightclub_enabled, 8;
    if(@due < 1) set $fightclub_enabled, 1;
    goto L_Menu;
L_BmEnabled2:
    set $fightclub_enabled, 9;
    if(@due == 1) set $fightclub_enabled, 3;
    goto L_Menu;

L_DuelFighter:
    if(@Duel_Fighter < 1) goto L_DuelFighter2;
    set @Duel_Fighter, 0;
    goto L_Menu;
L_DuelFighter2:
    set @Duel_Fighter, 1;
    goto L_Menu;

L_TimeBeforeNext:
    mes "range: 1~500";
    input @time;
    if((@time < 1) || (@time > 500)) goto L_OutOfRange;
    set $@Duel_TimeBeforeNext, @time;
    goto L_Menu;

L_TimeBeforeWarp:
    mes "range: 1~500";
    input @time;
    if((@time < 1) || (@time > 500)) goto L_OutOfRange;
    set $@Duel_TimeBeforeWarp, @time;
    goto L_Menu;

L_TimeBeforeStart:
    mes "range: 1~500";
    input @time;
    if((@time < 1) || (@time > 500)) goto L_OutOfRange;
    set $@Duel_TimeBeforeStart, @time;
    goto L_Menu;

L_TimeLimit:
    mes "range: 1~900";
    input @time;
    if((@time < 1) || (@time > 900)) goto L_OutOfRange;
    set $@Duel_TimeLimit, @time;
    goto L_Menu;

L_QueueLimit:
    mes "range: 1~20";
    input @limit;
    if((@limit < 1) || (@limit > 20)) goto L_OutOfRange;
    set $@Duel_QueueLimit, @limit;
    goto L_Menu;

L_PlayerQueueLimit:
    mes "range: 1~5";
    input @limit;
    if((@limit < 1) || (@limit > 5)) goto L_OutOfRange;
    set $@Duel_PlayerQueueLimit, @limit;
    goto L_Menu;

L_LastDuel:
    mes "range: 1+";
    mes "[R] This will trigger a reboot";
    input @last;
    if(@last < 1) goto L_OutOfRange;
    set $Duel_LastDuel, @last;
    next;
    goto L_Restart;

L_FightclubPassword:
    input @pass$;
    if(@pass$ == "") goto L_OutOfRange;
    set $@fightclub_password$, @pass$;
    goto L_Menu;

L_OutOfRange:
    mes "Value out of range or empty.";
    goto L_Menu;

L_Restart:
    callfunc "fightclub_EmergencyWipe";
    mes "The temporary variables have been reset.";
    goto L_Menu;

L_End:
    return;
}

009-7.gat,41,45,0|script|Debug#Duels|181,
{
    mes "The debug menu can also be accessed by wearing a dev cap while talking to Rouge.";
    mes "For the documentation, @@https://wiki.themanaworld.org/index.php/User:Meko/FightClub/debug|click here@@##0";
    callfunc "fightclub_Debug";
    end;

OnInit:
    if(!debug) disablenpc "Debug#Duels";
    end;

    // debug messages below
OnKillerNotInDuel:
    npctalk "WARNING: The victim was not killed by its adversary. Aborting duel...";
    end;

OnVictimNotInDuel:
    npctalk "WARNING: The victim is not part of the duel";
    end;

OnVictimInDuelNoDuel:
    npctalk "WARNING: The victim is part of the duel but no duel is ongoing at the moment.";
    end;
}