########################################################################################
#     This file is part of Spheres.
#     Copyright (C) 2019  Jesusalva

#     This library is free software; you can redistribute it and/or
#     modify it under the terms of the GNU Lesser General Public
#     License as published by the Free Software Foundation; either
#     version 2.1 of the License, or (at your option) any later version.

#     This library is distributed in the hope that it will be useful,
#     but WITHOUT ANY WARRANTY; without even the implied warranty of
#     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
#     Lesser General Public License for more details.

#     You should have received a copy of the GNU Lesser General Public
#     License along with this library; if not, write to the Free Software
#     Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
########################################################################################
# Game Story labels

label SQ00001_prologue:
    python:
        while persistent.nickname is None:
            nick=renpy.call_screen("input_box",
    "Please insert an unique nickname (max 8 alphanumeric chars): ")
            if len(nick) > 8 or not nick.isalnum():
                renpy.call_screen("msgbox", "ERROR\nERRONEOUS NICKNAME DETECTED")
            else:
                persistent.nickname=nick

    play music MUSIC_PROLOGUE01.id() fadein 0.5
    scene black with None
    window hide
    centered "{cps=36}{b}Somewhere distant{/b}{/cps}"
    scene bg darklands with Dissolve(2.0)
    centered "{b}Somewhere distant{/b}\n\n{fast}{cps=36}Darklands{/cps}"
    show dialog_detective at center with Dissolve(1.0)
    window show
    "???" "..."
    "???" "This high peak... This dark cloud..."
    "???" "So, these are the darklands."
    "???" "I didn't realize they were real. If it is here..."
    "???" "...Then there can be only one meaning. I have to report this at once!"
    show dialog_deadlyshadow at offscreenright with None
    show dialog_detective at prologue_right1
    show dialog_deadlyshadow at prologue_right2
    with move
    "???" "Uh oh..."
    show dialog_assassinshadow at offscreenright with None

    show dialog_detective at prologue_center
    show dialog_deadlyshadow at right
    show dialog_assassinshadow at left
    with move
    "???" "This won't end well..."
    "???" "But still, I cannot afford to fail this mission."
    scene black with vpunch
    stop music fadeout 2.5
    pause 1.0
    centered "Meanwhile\nExactly where we are..."
    scene bg academy with Dissolve(0.5)
    play music MUSIC_PROLOGUE02.id() fadein 1.0

    "Signet Academy\nGraduation Ceremony"
    show dialog_mentor at center with Dissolve(0.5)
    "Professor" "And with this, I declare graduate the fifteenth group of knights and captains."

    "{color=#0f0}*cheers*{/color}"

    "You" "The day has finally arrived. The day I graduate as Captain."
    "You" "All my hard work is finally paying off..."

    "Professor" "And with this, the final test shall take place, before you can truly declare yourselves Captains and Knights."

    "{color=#0f0}*silence falls over the crowds*{/color}"

    "Professor" "You all should travel to the Capital and met Marshall Luhmer."
    "Professor" "This task sounds simple, but many lose their lives at it. Lack of care will be your death!"
    "Professor" "As long that you report to him in one piece, you'll have passed the trial, and will be able to start working."

    "Professor" "{color=#0f0}*cough cough*{/color} With this, you are all dismissed."

    scene bg forest_sunset with fade#Dissolve(0.5)

    "As a Captain, I can use summons, but I'm lacking in fight skills."
    "I could try to have a summon fighting for me, but could I survive long enough to finish the chant...?"

    play music MUSIC_PROLOGUE03.id() fadein 0.6
    "{color=#0f0}As you think on the best route to use, a newly appointed knight approaches you.{/color}"

    "Giulio" "Hey, you're a new Captain, right? I was thinking, a top grade knight like me should not risk myself needlessly."
    "Giulio" "So, perhaps we should travel together. It's not against the rules, right?"
    "You" "No..."
    "Giulio" "So, it's decided then! haha, those monsters are no match for me, even if they get annoying! Let's go!"

    # Giulio joins you!
    window hide
    python:
        txt=allunits[10000000]["name"]
        rar=allunits[10000000]["rare"]
        star=star_write(rar)
        show_img("unit_10000000", at_list=[truecenter])
        renpy.pause(0.1)
        renpy.call_screen("msgbox", "%s\n\nRecruited %d★ %s" % (star, rar, txt))
        renpy.hide("unit_10000000")
        _window_show(None)

    scene bg forest_sunset with fade#Dissolve(0.5)
    pause 0.2
    show dialog_archmage at center with Dissolve(0.5)
    "Arch mage" "Oho, I see at least some students were smart enough to join forces!"
    "Arch mage" "No doubts you have a chance at arriving to the Capital."
    show dialog_rebel at offscreenright with None
    show dialog_rebel at right
    show dialog_archmage at left
    with move

    "Female Rebel" "Why don't we have a friendly spar, though? If you are impressive enough, others may want to travel with you."

    "Giulio" "Hahah, you would never be able to defeat a top-tier knight like me!"
    "Giulio" "{color=#0f0}*psst*{/color} Well, you're a Captain, so I'll leave this strategy thing to you."

    "Giulio" "In case you forgot, in the battle screen, you can swipe cards down to use Spheres, or up to use skills."
    "Giulio" "Click on End turn at the upper right corner to advance the wave. As time passes, you'll eventually be able to use the summon!"

    show dialog_rebel at center with move
    "Female Rebel" "Let's do it!"
    return

####################################################
label SQ00005_post:
    $ show_img("bg castle", False, ext=".jpg")
    scene bg castle with Dissolve(1.0)
    "You" "We did it! We reached the Capital!"
    "Giulio" "What are you standing there for? We gotta a Marshall to met."
    # TODO: bg desk
    scene bg castle with Dissolve(1.0)
    $ show_img("dialog_marshall", at_list=[center])
    "Marshall" "Congratulations in making to the Capital in one piece."
    "Marshall" "If you both don't mind, I would like to officially assign your first task now."
    "Giulio" "This task better be suitable for a top knight like myself."
    "Marshall" "A task is a task, no matter how tedious or boring it is!"
    "Marshall" "Either way, I want you to heed in Forest Of Fay and kill some bandits which decided to live there."
    "Marshall" "If you don't like this task, I can have you both cleaning the restroom instead, if you prefer...?"
    "You" "Uhm, thanks but no thanks."
    "Marshall" "...What, you guys are still here? Get going!"
    "You & Giulio" "Sir! Yessir!"
    scene bg castle with Dissolve(1.0)
    "Giulio" "Pft, they want me to kill mere bandits! Unbelievable."
    "You" "If we finish this quickly, the marshal might be sightly impressed with us and assign something more epic."
    "Giulio" "Let's get going, a top-tier knight like me should not be wasting time here in first place."
    return

####################################################
label SQ00006_pre:
    $ show_img("bg wilderness", False, ext=".jpg")
    scene bg wilderness with Dissolve(1.0)
    $ show_img("dialog_milleue")
    "Milleue" "Are you the ones assigned to the Forest of Fae bandits? Am I right?"
    "Giulio" "And you would be...?"
    "Milleue" "So I'm right! Forest of Fae is sacred. We the Empire won't let you go there idly."
    "Milleue" "If you can, however, defeat my unit, then I'll reconsider your worthiness."
    "Milleue" "Perhaps I might even join you. Now, to arms! I'll judge you myself!"
    return

####################################################
label SQ00006_post:
    $ show_img("bg wilderness", False, ext=".jpg")
    scene bg wilderness with Dissolve(1.0)
    $ show_img("dialog_milleue", at_list=[center])
    "Milleue" "Alright, I surrender! I admit defeat."
    "Milleue" "I'm afraid the path to the Forest of Fae won't be a walk in the park."
    "Milleue" "I'll go with you. But the other Imperial Soldiers will still try to stop you as you go."
    "You" "Wait. I always thought the Marshall served the empire...?"
    "Milleue" "Politics."
    "You" "Oh right. I guess I won't ask more, then."
    return

####################################################
label SQ00011_post:
    scene bg forest_sunset with Dissolve(0.5)
    "Giulio" "Mother Nature's sent us wolves... How much I hate it."
    "Giulio" "Mother Nature, please, GIVE ME A DECENT CHALLENGE!"
    $ show_img("dialog_milleue", at_list=[center])
    "Milleue" "Be careful with what you wish for."
    "Giulio" "Oh, please. My sword will get rusty at this small fry. These wolves aren't qualified for a top knight like myself."
    return

####################################################
label SQ00013_pre:
    scene bg forest_sunset with Dissolve(0.5)
    "Giulio" "I hear battle sounds up ahead."
    "You" "It'll be quite a detour, but we should check."
    $ show_img("dialog_bandit", at_list=[left], tag="l")
    $ show_img("dialog_princess", at_list=[right], tag="r")
    "{b}.:: CONTINUES ::.{/b}"
    return

####################################################
label SQ00014_post:
    scene bg forest_sunset with Dissolve(0.5)
    $ show_img("dialog_princess", at_list=[center])
    "{b}.:: CONTINUES ::.{/b}"
    return